WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

EulerPhi[n]

オイラー関数 を与える．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
数値評価  
記号演算  
アプリケーション  
基本的なアプリケーション  
整数論  
特性と関係  
考えられる問題  
おもしろい例題  
関連項目
テクニカルノート
関連するガイド
関連リンク
履歴
引用書式

EulerPhi

EulerPhi[n]

オイラー関数 を与える．

詳細

  • EulerPhiはオイラーのトーシェント関数あるいはファイ関数としても知られている．
  • 記号操作・数値操作の両方に適した数学的整数関数である．
  • 暗号学や初等整数論の多くのアプリケーションでよく使われる．
  • EulerPhi[n]は n と互いに素な n までの正の整数を数える．
  • 数 （ は単数で は素数）について，EulerPhi[n]は を与える．

例題

すべて開く すべて閉じる

例  (2)

10のオイラーのトーシェント関数を計算する：

Wolfram Language code: EulerPhi[10]

数列をプロットする：

Wolfram Language code: DiscretePlot[EulerPhi[n], {n, 100}]

スコープ  (9)

数値評価  (4)

整数を使って計算する：

Wolfram Language code: EulerPhi[10]
Wolfram Language code: EulerPhi[-10]

大きい引数について計算する：

Wolfram Language code: EulerPhi[50!]

EulerPhiはリストに縫い込まれる：

Wolfram Language code: EulerPhi[{2, 4, 6}]

TraditionalFormによる表示：

Wolfram Language code: EulerPhi[n]//TraditionalForm

記号演算  (5)

EulerPhiを含む方程式を解く：

Wolfram Language code: FindInstance[EulerPhi[m]EulerPhi[n] == EulerPhi[m n] && 0 < m < n < 10, {n, m}, Integers, 3]
Wolfram Language code: Solve[EulerPhi[m] == 10, m, Integers]

FullSimplifyをEulerPhiと一緒に使う：

Wolfram Language code: FullSimplify[EulerPhi[n] >= Sqrt[n], n∈Integers && n > 6]
Wolfram Language code: FullSimplify[DivisorSigma[0, n] < EulerPhi[n], n∈Integers && n > 30]

FunctionExpandをEulerPhiと一緒に使う：

Wolfram Language code: FunctionExpand[EulerPhi[p], p∈Primes]

FindSequenceFunctionはEulerPhi数列が認識できる：

Wolfram Language code: Table[EulerPhi[n], {n, 10}]
Wolfram Language code: FindSequenceFunction[%, n]

DirichletTransform：

Wolfram Language code: DirichletTransform[EulerPhi[n], n, s]

アプリケーション  (9)

基本的なアプリケーション  (4)

となるような整数 n を求める：

Wolfram Language code: Cases[Range[100], n_ /; EulerPhi[CarmichaelLambda[n]] == CarmichaelLambda[EulerPhi[n]]]

n 次のFareySequenceの長さはEulerPhiで表すことができる：

Wolfram Language code: Table[Length[FareySequence[n]], {n, 15}]
Wolfram Language code: Table[1 + Sum[EulerPhi[n], {n, k}], {k, 1, 15}]

GCDについての母関数のベキ級数：

Wolfram Language code: Series[Total[EulerPhi[#]x ^ # / (1 - x ^ #)& /@ Divisors[10]], {x, 0, 20}]
Wolfram Language code: Sum[GCD[k, 10]x ^ k, {k, 1, 20}]

EulerPhiを使って素数の数を数える：

Wolfram Language code: Plot[{Underoverscript[∑, n = 2, Floor[x]]Floor[(EulerPhi[n]/n - 1)], PrimePi[x]}, {x, 0, 50}, PlotStyle -> {Thick, Directive[Yellow, Thick, Dashed]}]

整数論  (5)

Fleckのトーシェント関数をモデル化する：

Wolfram Language code: FleckPhi[k_, n_] := Times@@(Sum[(-1)^jBinomial[k, j]EulerPhi[#1^#2 - j], {j, 0, #2}]&@@@FactorInteger[n])
Wolfram Language code: Table[FleckPhi[0, n], {n, 12}]

はオイラーのトーシェント関数を再現する：

Wolfram Language code: Table[EulerPhi[n], {n, 12}]

一般化と閉じた形：

Wolfram Language code: Table[FleckPhi[-1, n] - n, {n, 12}]
Wolfram Language code: Table[FleckPhi[-2, n] - DivisorSigma[1, n], {n, 12}]

EulerPhiの累積和をプロットする：

Wolfram Language code: ListPlot[Accumulate[Table[EulerPhi[n], {n, 50}]]]

漸近近似と比較する：

Wolfram Language code: Show[%, Plot[3 / Pi ^ 2n ^ 2, {n, 0, 50}, PlotStyle -> Red]]

差 sum_(n=1)^kTemplateBox[{n}, EulerPhi]-3 k^2/pi^2が負である最初のいくつかの ：

Wolfram Language code: Position[NonPositive[Accumulate[EulerPhi[Range[10 ^ 4]]] - 3(Range[10 ^ 4] / Pi) ^ 2], True]//Flatten
Wolfram Language code: Table[Sum[EulerPhi[n], {n, 1, k}] - 3k ^ 2 / Pi ^ 2, {k, %}]//N

ランダムに選択した x 未満の2つの正の整数が互いに素である確率：

Wolfram Language code: ListLinePlot[Table[(1/x^2)(-1 + 2Underoverscript[∑, n = 1, ⌊x⌋]EulerPhi[n]), {x, 1, 100}]]

漸近極限と比較する：

Wolfram Language code: N[1 / Zeta[2]]

RSAのような暗号化スキームを構築する．モジュラスから始める：

Wolfram Language code: {p, q} = Prime[RandomInteger[{10 ^ 4, 10 ^ 5}, {2}]]; n = p q

n を法とする乗法群の普遍指数を求める：

Wolfram Language code: ϕ = EulerPhi[n]

秘密鍵：

Wolfram Language code: d = NestWhile[#1 + 1&, Round[n / 3], GCD[ϕ, #1] =!= 1&]

公開鍵：

Wolfram Language code: e = PowerMod[d, -1, ϕ]

メッセージを暗号化する：

Wolfram Language code: PowerMod[ToCharacterCode["RSA in Mathematica"], e, n]

それを解読する：

Wolfram Language code: FromCharacterCode[PowerMod[%, d, n]]

b 種類のビーズで作ることができる長さ n の環状ネックレスの数：

Wolfram Language code: c[n_, b_] := Total[EulerPhi[#]b^(n/#)&[Divisors[n]]] / n
Wolfram Language code: c[6, 2]

特性と関係  (11)

EulerPhiは非負である：

Wolfram Language code: EulerPhi[0]

EulerPhiは乗法的関数である：

Wolfram Language code: m = 12; n = 8; EulerPhi[m]EulerPhi[n] == EulerPhi[m n](EulerPhi[GCD[n, m]]/GCD[n, m])

任意の素数 p と自然数 r について ϕ(pr)=pr-pr-1である：

Wolfram Language code: Assuming[p∈Primes && r∈Integers && r > 0, FunctionExpand[EulerPhi[p ^ r]]]

同様に，p が素数のときEulerPhi[n]==n∏p|n(1-1/p)：

Wolfram Language code: 100Product[1 - 1 / k, {k, Select[Divisors[100], PrimeQ]}]
Wolfram Language code: EulerPhi[100]

あるいはEulerPhi[n]==n∑k|nMoebiusMu[k]/k：

Wolfram Language code: 35Sum[MoebiusMu[k] / k, {k, Divisors[35]}]
Wolfram Language code: EulerPhi[35]

CarmichaelLambdaはEulerPhiを割る：

Wolfram Language code: Divisible[EulerPhi[8], CarmichaelLambda[8]]

n が素数ベキのとき，両者は等しい：

Wolfram Language code: PrimePowerQ[25]
Wolfram Language code: {EulerPhi[25], CarmichaelLambda[25]}

ϕ(d)=n であることを示す：

Wolfram Language code: DivisorSum[15, EulerPhi] == 15

Cyclotomic体について，NumberFieldDiscriminantはEulerPhiを使って求めることができる：

Wolfram Language code: n = 7;
Wolfram Language code: NumberFieldDiscriminant[x /. Solve[Cyclotomic[n, x] == 0][[1]]] ((-1) ^ (EulerPhi[n] / 2)n ^ EulerPhi[n]) / Product[p ^ (EulerPhi[n] / (p - 1)), {p, Divisors[n][[2 ;; All]]}]

が原始根を持つなら，CarmichaelLambdaとEulerPhiは等しい：

Wolfram Language code: Cases[Range[2, 20], n_ /; IntegerQ[PrimitiveRoot[n]]]
Wolfram Language code: CarmichaelLambda[%]
Wolfram Language code: EulerPhi[%%]

素因数分解を通してEulerPhiを決定する：

Wolfram Language code: ϕ[n_] := n Times@@(1 - (1/First /@ FactorInteger[n]))
Wolfram Language code: Table[ϕ[n], {n, 12}]
Wolfram Language code: Table[EulerPhi[n], {n, 12}]

任意の無平方数 n について，n のトーシェントは n の各因数のトーシェントの積に等しい：

Wolfram Language code: SquareFreeQ[1023]
Wolfram Language code: FactorInteger[1023]
Wolfram Language code: EulerPhi[1023] == EulerPhi[3] * EulerPhi[11] * EulerPhi[31]

考えられる問題  (1)

0における値：

Wolfram Language code: EulerPhi[0]

おもしろい例題  (4)

次の数列の極限としての絶対的に不自然な数を作る：

Wolfram Language code: d[j_] := If[j == 2, 2, j ^ EulerPhi[d[j - 1]]] α[k_] := Product[1 - 1 / d[j], {j, 2, k}]
Wolfram Language code: Table[α[k], {k, 5}]

いろいろな底における6番目の近似の桁：

Wolfram Language code: Table[BaseForm[N[α[6], 50], b], {b, 2, 24}]//TableForm

写像 を反復させ，その結果を を法として表示する：

Wolfram Language code: With[{a = 1.537, b = -.5, m = 3}, ArrayPlot[Mod[FixedPointList[EulerPhi[Floor[a# + b]]&, Range[150], 100], m]]]

TemplateBox[{x}, PrimePi]=TemplateBox[{x}, EulerPhi]のたった8つの解：

Wolfram Language code: Cases[Range[100], n_ /; PrimePi[n] == EulerPhi[n]]
Wolfram Language code: DiscretePlot[{PrimePi[n], EulerPhi[n]}, {n, 1, 22}, Epilog -> {Red, PointSize[0.03], Point[{#, EulerPhi[#]}& /@ %]}]

EulerPhiの値に基づいて数が彩色されたウラム(Ulam)螺線をプロットする：

Wolfram Language code: ulam[n_] := Partition[Permute[Range[n ^ 2], Accumulate[Take[Flatten[{{n ^ 2 + 1} / 2, Table[(-1) ^ j i, {j, n}, {i, {-1, n}}, {j}]}], n ^ 2]]], n] ArrayPlot[EulerPhi[ulam[141]], ColorFunction -> Hue]
Wolfram Research (1988), EulerPhi, Wolfram言語関数， https://reference.wolfram.com/language/ref/EulerPhi.html （2007年に更新）.

テキスト

Wolfram Research (1988), EulerPhi, Wolfram言語関数， https://reference.wolfram.com/language/ref/EulerPhi.html （2007年に更新）.

CMS

Wolfram Language. 1988. "EulerPhi." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2007. https://reference.wolfram.com/language/ref/EulerPhi.html.

APA

Wolfram Language. (1988). EulerPhi. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/EulerPhi.html

BibTeX

@misc{reference.wolfram_2026_eulerphi, author="Wolfram Research", title="{EulerPhi}", year="2007", howpublished="\url{https://reference.wolfram.com/language/ref/EulerPhi.html}", note=[Accessed: 13-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_eulerphi, organization={Wolfram Research}, title={EulerPhi}, year={2007}, url={https://reference.wolfram.com/language/ref/EulerPhi.html}, note=[Accessed: 13-September-2026]}