WOLFRAM

Wolfram 语言与系统参考资料中心

EventSeriesLookup[eseries,time]

给出 EventSeries 对象 eseries 中距离 time 最近的事件.

EventSeriesLookup[eseries,time,ptype]

给出 eseries 中在类型 ptype 下与 time 邻近的事件.

EventSeriesLookup[eseries,time,ptypeprop]

给出与 time 邻近的事件的属性 prop.

EventSeriesLookup[eseries,time,ptype,n]

给出最多 n 个近端事件.

EventSeriesLookup[eseries,time,ptype,{n,r}]

返回最多 n 个与 time 时间间隔不超过 r 的事件.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
属性和关系  
参见
相关指南
历史
按以下格式引用：

EventSeriesLookup

EventSeriesLookup[eseries,time]

给出 EventSeries 对象 eseries 中距离 time 最近的事件.

EventSeriesLookup[eseries,time,ptype]

给出 eseries 中在类型 ptype 下与 time 邻近的事件.

EventSeriesLookup[eseries,time,ptypeprop]

给出与 time 邻近的事件的属性 prop.

EventSeriesLookup[eseries,time,ptype,n]

给出最多 n 个近端事件.

EventSeriesLookup[eseries,time,ptype,{n,r}]

返回最多 n 个与 time 时间间隔不超过 r 的事件.

更多信息

  • EventSeriesLookup 通常用于提取在时间上接近某个特定时刻的事件.
  • EventSeriesLookup 函数返回给定事件序列的 {timestamp,value} 对列表. 输出列表可以为空.
  • time 的可能取值可以是数字，也可以是 DateObject 表达式.
  • 可能的邻近类型 ptype 包括：
  • "Nearest"时间戳最接近 time 的事件
    "Previous"在 time 之前最接近的事件
    "Next"在 time 之后最接近的事件
  • EventSeriesLookup[eseries,time] 等价于 EventSeriesLookup[eseries,time,"Nearest"].
  • 可能的属性 prop 包括：
  • "Element"近端事件 {{t1,v1},…}
    "Index"近端事件的索引
    "Timestamps"时间戳 {t1,..}
    "Values"值 {v1,…}
    "Distance"距离 {t1-time,…}
    "EventSeries"近端事件的 EventSeries
  • EventSeriesLookup[eseries,time,ptype] 等价于 EventSeriesLookup[eseries,time,ptype"Element"].
  • 半径 r 应为一个数值，或一个带有时间单位的 Quantity.

范例

打开所有单元 关闭所有单元

基本范例  (2)

查找最接近给定日期的事件：

Wolfram Language code: eseries = EventSeries[Range[19], { DateObject[{2026, 2, 1}, "Day"], DateObject[{2026, 2, 28}, "Day"], "BusinessDay"}]
Wolfram Language code: EventSeriesLookup[eseries, DateObject[{2026, 2, 15}, "Day"]]

查找下一个事件：

Wolfram Language code: EventSeriesLookup[eseries, DateObject[{2026, 2, 15}, "Day"], "Next"]

查找先前的事件：

Wolfram Language code: EventSeriesLookup[eseries, DateObject[{2026, 2, 15}, "Day"], "Previous"]

查找最接近时间 2 的事件：

Wolfram Language code: eseries = EventSeries[<||>, {{0, 1.2, 1.7, 2.1, 2.7, 3.5}}];
Wolfram Language code: EventSeriesLookup[eseries, 2, "Nearest"]

找出距离时间 2 最近的四个事件的时间戳：

Wolfram Language code: EventSeriesLookup[eseries, 2, "Nearest" -> "Timestamp", 4]//Normal

范围  (10)

使用 EventSeriesLookup 并采用不同的邻近类型：

Wolfram Language code: eseries = EventSeries[{a, b, c, d}, {{0, 1, 2, 3}}]
Wolfram Language code: EventSeriesLookup[eseries, 1 / 2, "Previous"]
Wolfram Language code: EventSeriesLookup[eseries, 1 / 2, "Next"]
Wolfram Language code: EventSeriesLookup[eseries, 1 / 2, "Nearest"]

"Nearest" 是默认值：

Wolfram Language code: EventSeriesLookup[eseries, 1 / 2]

当两个时间戳与输入时间的接近程度相同时，这两个时间戳都会被包含在内：

Wolfram Language code: eseries = EventSeries[{a, b, c, d, e}, {{0, 1, 2, 3, 4}}]
Wolfram Language code: EventSeriesLookup[eseries, 1.5]

EventSeriesLookup 可以返回任意数量的事件：

Wolfram Language code: eseries = EventSeries[{a, b, c, d, e, f}, {{0, 0, 1, 1, 1, 2}}]
Wolfram Language code: EventSeriesLookup[eseries, 1 / 3]
Wolfram Language code: EventSeriesLookup[eseries, 2 / 3]
Wolfram Language code: EventSeriesLookup[eseries, 1 / 2]

当 EventSeries 具有重复的时间戳时，默认情况下会包含这些时间戳对应的所有值：

Wolfram Language code: eseries = EventSeries[{a, b, c, d, e}, {{0, 0, 1, 1, 1}}]
Wolfram Language code: EventSeriesLookup[eseries, 2 / 3, "Next"]

指定要返回的时间戳的最大数量：

Wolfram Language code: EventSeriesLookup[eseries, 2 / 3, "Next", 2]

EventSeriesLookup 在计数为 n 时，最多返回 n 个结果：

Wolfram Language code: eseries = EventSeries[Range[10], {RandomReal[1, 10]}]
Wolfram Language code: EventSeriesLookup[eseries, .3, "Previous", 15]

将 EventSeriesLookup 与不同属性一起使用：

Wolfram Language code: eseries = EventSeries[{a, b, c, d, e, f}, {{0, 0.1, 0.1, 0.3, 0.5, 0.5}}]
Wolfram Language code: EventSeriesLookup[eseries, .4, "Nearest" -> "Element"]
Wolfram Language code: EventSeriesLookup[eseries, .4, "Nearest" -> "Index"]
Wolfram Language code: EventSeriesLookup[eseries, .4, "Nearest" -> "Timestamp"]//Normal
Wolfram Language code: EventSeriesLookup[eseries, .4, "Nearest" -> "Value"]//Normal
Wolfram Language code: EventSeriesLookup[eseries, .4, "Nearest" -> "Distance"]//Normal
Wolfram Language code: EventSeriesLookup[eseries, .4, "Nearest" -> "EventSeries"]

获取近端事件的索引：

Wolfram Language code: eseries = EventSeries[{a, b, c, d, e}, {{0, 0, 1, 1, 1}}]
Wolfram Language code: inds = EventSeriesLookup[eseries, .618, "Nearest" -> "Index"]

该结果可与 Part 一起使用，以获取新的 EventSeries：

Wolfram Language code: eseries[[inds]]
Wolfram Language code: Normal[%]

这等同于 EventSeriesLookup 的默认结果：

Wolfram Language code: EventSeriesLookup[eseries, .618, "Nearest"]

取一个时间戳粒度为 "Day" 的事件序列：

Wolfram Language code: BlockRandom[dates = RandomDate[100], RandomSeeding -> 1234]; es = EventSeries[Range[100], {dates}, DateGranularity -> "Day"]

查找某个时间点的所有事件，其粒度比事件序列的粒度更粗：

Wolfram Language code: june = DateObject[{2026, 6}, "Month"]; EventSeriesLookup[es, june]

查找紧接着六月份之前发生的所有事件：

Wolfram Language code: EventSeriesLookup[es, june, "Previous"]

以 EventSeries 的形式返回六月之后的所有事件：

Wolfram Language code: EventSeriesLookup[es, june, "Next" -> "EventSeries", Infinity]

取一个包含 250 个元素的事件序列：

Wolfram Language code: BlockRandom[dates = RandomDate[250], RandomSeeding -> 1234]; eseries = EventSeries[Range[250], {dates}, DateGranularity -> "Day"]

查找从三月十五日（Ides of March）到最近事件的所有距离：

Wolfram Language code: day = DateObject[{2026, 3, 15}]; dist = EventSeriesLookup[eseries, day, "Nearest" -> "Distance"]

结果中距离 0 被重复列出，因为在原始事件序列中有多个“三月十五日”实例：

Wolfram Language code: Normal[dist]

当计数更大时，可以明显看出，近端事件是按距离递增的顺序给出的：

Wolfram Language code: EventSeriesLookup[eseries, day, "Nearest" -> "Distance", 6] //Normal

距离对应于这些时间戳：

Wolfram Language code: EventSeriesLookup[eseries, day, "Nearest" -> "Timestamp", 6] //Normal

查找在给定日期一周内的所有事件：

Wolfram Language code: BlockRandom[dates = RandomDate[100], RandomSeeding -> 1234]; es = EventSeries[Range[100], {dates}, DateGranularity -> "Day"]
Wolfram Language code: day = DateObject[{2026, 3, 15}];
Wolfram Language code: EventSeriesLookup[es, day, "Nearest", {Infinity, Quantity[1, "Weeks"]}]

仅查找三月十五日之后一周内的事件：

Wolfram Language code: EventSeriesLookup[es, day, "Next", {Infinity, Quantity[1, "Weeks"]}]

属性和关系  (2)

EventSeriesLookup 使用默认的 ptype 时，等价于对时间戳使用 Nearest：

Wolfram Language code: eseries = EventSeries[{Subscript[x, 1], Subscript[x, 2], Subscript[x, 3], Subscript[x, 4], Subscript[x, 5], Subscript[x, 6], Subscript[x, 7]}, {{1, 2, 2, 3, 3, 3, 4}}]
Wolfram Language code: EventSeriesLookup[eseries, 2.5, "Nearest" -> "Timestamp"]//Normal
Wolfram Language code: Nearest[eseries["Timestamps"], 2.5]

EventSeriesLookup 更快，因为它利用了时间戳已排序这一事实：

Wolfram Language code: BlockRandom[times = RandomInteger[10 ^ 6, 10 ^ 6], RandomSeeding -> 1234]; es = EventSeries[<||>, {times}];
Wolfram Language code: RepeatedTiming[EventSeriesLookup[es, 5 10 ^ 5, "Nearest" -> "Index"]]
Wolfram Language code: RepeatedTiming[Nearest[times -> "Index", 5 10 ^ 5]]

要获得相同的结果，必须对时间进行排序：

Wolfram Language code: RepeatedTiming[Nearest[Sort[times] -> "Index", 5 10 ^ 5]]

EventSeriesLookup 和 TimeSeriesWindow 都可用于提取一个子序列：

Wolfram Language code: es = EventSeries[Range[20], {DateObject[{2026, 3, 25}]}]
Wolfram Language code: EventSeriesLookup[es, DateObject[{2026, 3, 31}], "Next" -> "EventSeries", Infinity]
Wolfram Language code: % === TimeSeriesWindow[es, {DateObject[{2026, 4, 1}], Automatic}]
Wolfram Research (2026)，EventSeriesLookup，Wolfram 语言函数，https://reference.wolfram.com/language/ref/EventSeriesLookup.html.

文本

Wolfram Research (2026)，EventSeriesLookup，Wolfram 语言函数，https://reference.wolfram.com/language/ref/EventSeriesLookup.html.

CMS

Wolfram 语言. 2026. "EventSeriesLookup." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/EventSeriesLookup.html.

APA

Wolfram 语言. (2026). EventSeriesLookup. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/EventSeriesLookup.html 年

BibTeX

@misc{reference.wolfram_2026_eventserieslookup, author="Wolfram Research", title="{EventSeriesLookup}", year="2026", howpublished="\url{https://reference.wolfram.com/language/ref/EventSeriesLookup.html}", note=[Accessed: 07-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_eventserieslookup, organization={Wolfram Research}, title={EventSeriesLookup}, year={2026}, url={https://reference.wolfram.com/language/ref/EventSeriesLookup.html}, note=[Accessed: 07-September-2026]}