Expand

Expand[expr]

式 expr における積と正の整数ベキを展開する．

Expand[expr,patt]

パターン patt にマッチする項を含まない式 expr の要素の展開を避ける． »

詳細とオプション

Expandは，正の整数ベキについてのみ機能する．
Expandは，式 expr の最上レベルに限り適用される．
Expand[expr,Modulus->p]は，式 expr を p を法として展開する． »
Expandは，方程式，不等式，論理関数と同様 expr 中のリストにも自動的に縫い込まれる．
Expandは次のオプションを取る．
Modulus 0 整数に仮定する法

Trig False 代数変換だけでなく三角変換も行うかどうか

例題

すべて開くすべて閉じる

例 (3)

多項式を項の単純な和として展開する：

Wolfram Language code: Expand[(x + 3)(x + 2)]

多項式の積を展開する：

Wolfram Language code: Expand[(1 + x) ^ 3(5x ^ 2 + 1)(x ^ 5 + 1)]

複数の変数を持つ多項式を展開する：

Wolfram Language code: Expand[(x + y) ^ 5 - (x ^ 5 + y ^ 5)]

スコープ (16)

基本的な用法 (9)

多項式を展開する：

Wolfram Language code: Expand[(x + y) ^ 2(x - y) ^ 2]

有理関数を展開する：

Wolfram Language code: Expand[(x + y) ^ 2 / (x - y) ^ 2]

三角関数を含む式を展開する：

Wolfram Language code: Expand[(Sin[x] + Cos[x]) ^ 2]

超越関数を含む式を展開する：

Wolfram Language code: Expand[(x ^ s + 2E ^ -x) ^ 3]

任意の関数を含む式を展開する：

Wolfram Language code: Expand[(f[Subscript[x, 1]] + f[Subscript[x, 2]]) ^ 3]

Expandは部分式までは展開しない：

Wolfram Language code: Expand[Sqrt[(1 + x) ^ 2]]

対照的に，ExpandAllは部分式も展開する：

Wolfram Language code: ExpandAll[Sqrt[(1 + x) ^ 2]]

Expandは分子のみに適用される：

Wolfram Language code: Expand[(x + y) ^ 2 / (z + y) ^ 2]

ExpandAllは分子と分母の両方に適用される：

Wolfram Language code: ExpandAll[(x + y) ^ 2 / (z + y) ^ 2]

展開された多項式とその因数分解した形が等しいことを確かめる：

Wolfram Language code: 1 + 5 x + 10 x^2 + 10 x^3 + 5 x^4 + x^5 == Expand[(x + 1) ^ 5]

Expandは実数または複素数の係数を持つ多項式を入力として取る：

Wolfram Language code: Expand[(x + I)(x - I)]

Expandはリストに縫い込まれる：

Wolfram Language code: Expand[Table[(x + 1) ^ n, {n, 3}]]

Expandは等式と不等式に縫い込まれる：

Wolfram Language code: Expand[1 < (x + y) ^ 2 < 2]

高度な用法 (7)

Expandをを法とした整数上で多項式に適用する：

Wolfram Language code: Expand[(2y + 3x) ^ 6, Modulus -> 4]

有限体上で多項式を展開する：

Wolfram Language code: ℱ = FiniteField[17, 3];

Wolfram Language code: Expand[(ℱ[123]x - ℱ[345])(ℱ[567]x - ℱ[789])]

Expandを三角関数の式に適用する：

Wolfram Language code: Expand[(Sin[2x] + x) ^ 2, Trig -> True]

高次ベキを持つ多項式は効率的に展開される：

Wolfram Language code: Expand[(x + y + z) ^ 1000]//Length

xを含まない部分は展開しないでおく：

Wolfram Language code: Expand[(a + b) ^ 2(1 + x) ^ 2, x]

1+xを含まない部分は展開しないでおく：

Wolfram Language code: Expand[(1 + x) ^ 2 + (2 + x) ^ 2, 1 + x]

x[_]にマッチしない部分は展開しないでおく：

Wolfram Language code: Expand[(a[1] + a[2])(x[1] + x[2]) ^ 2, x[_]]

オプション (3)

Modulus (2)

場GF(2)における働き：

Wolfram Language code: Expand[(1 + x) ^ 10, Modulus -> 2]

モジュラスは素数ではなくてもよい：

Wolfram Language code: Expand[(1 + x) ^ 10, Modulus -> 4]

Trig (1)

三角方程式を展開する：

Wolfram Language code: Expand[Sin[x + y], Trig -> True]

アプリケーション (3)

対角行列の特性多項式を計算する：

Wolfram Language code: (matrix = DiagonalMatrix[{1, -1, 1, -1}])//MatrixForm

特性多項式は以下の行列の行列式である：

Wolfram Language code: matrix - x * IdentityMatrix[4]//MatrixForm

対角要素の積を展開して特性多項式を得る：

Wolfram Language code: Expand[(1 - x)(-1 - x)(1 - x)(-1 - x)]

これは，CharacteristicPolynomial関数を使って直接計算できる：

Wolfram Language code: CharacteristicPolynomial[matrix , x]

Cyclotomic多項式は最高次の係数（整数）が1次で，有理数上で既約である：

Wolfram Language code: cyclo[n_] := Times@@Table[If[GCD[k, n] == 1, (x - (-1) ^ (2k / n)), 1], {k, 1, n}]

16番目の円分多項式は以下で与えられる：

Wolfram Language code: cyclo[16]

Expandを使って係数が整数であることを示す：

Wolfram Language code: Expand[%]

これらの多項式はCyclotomic関数を使って直接計算できる：

Wolfram Language code: Cyclotomic[16, x]

Expandを使って2つの式が等しいことが確かめられる：

Wolfram Language code: Cos[3x] == 4Cos[x] ^ 3 - 3Cos[x]

Wolfram Language code: Expand[%, Trig -> True]

特性と関係 (4)

展開されない形式で結果を与える関数がたくさんある：

Wolfram Language code: prod = Product[x + i, {i, 6}]

Expandを適用する：

Wolfram Language code: Expand[prod]

Expandを多項式に適用する：

Wolfram Language code: Expand[(1 + x + y)(2 - x) ^ 3]

Factorは，基本的に，Expandの逆関数である：

Wolfram Language code: Factor[%]

ベキが含まれなければ，DistributeはExpandと同じ結果を返す：

Wolfram Language code: Distribute[(1 + x)(2 + x)(3 + x)] === Expand[(1 + x)(2 + x)(3 + x)]

分配法則を直接適用すると，必要範囲をはるかに超える数の項が生成されることがよくある：

Wolfram Language code: Distribute[Factor[x ^ 6 - 1], Plus, Times, List, Times]

上記を合計する：

Wolfram Language code: Total[%]

NonCommutativeExpandを使って非可換多項式を展開する：

Wolfram Language code: NonCommutativeExpand[(a + 2b)**(3a + 4b)]

加算演算と乗算演算の名前を指定する：

Wolfram Language code: alg = NonCommutativeAlgebra[<|"Multiplication" -> mult, "Addition" -> add|>];

Wolfram Language code: NonCommutativeExpand[mult[add[a, 2b], add[3a, 4b]], alg]

おもしろい例題 (3)

2つの絵文字を含む二項展開をスタイル化する：

Wolfram Language code: Style[Expand[(☺ + ☹) ^ 5], 20]

二項式の大きなベキ乗を展開する：

Wolfram Language code: Expand[(1 + x) ^ 100]

追加的なセルオートマトン（ルール60）に対応するネストしたパターンを作る：

Wolfram Language code: Column[Table[CoefficientList[Expand[(1 + x) ^ t, Modulus -> 2], x], {t, 0, 31}]]

Top

その他のラーニングリソース

テクニカルサポート

データサイエンス，金融，ビジネス

工学

科学とテクノロジー

教育のためのテクノロジー

教育イニシアチブ

使い始める

Grow Your Skills

Wolframと繋がる

大人用の教育プログラム

若者のための教育プログラム

読む

Expand

詳細とオプション

例題

例 (3)