WOLFRAM

Wolfram 语言与系统参考资料中心

Expand[expr]

用来展开 expr 中的乘积和正整数幂.

Expand[expr,patt]

用来使得不具有模式 patt 的 expr 任意部分不被展开. »

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
基本用法  
高级用法  
选项  
Modulus  
Trig  
应用  
属性和关系  
巧妙范例  
参见
技术笔记
相关指南
相关链接
历史
按以下格式引用：

Expand

Expand[expr]

用来展开 expr 中的乘积和正整数幂.

Expand[expr,patt]

用来使得不具有模式 patt 的 expr 任意部分不被展开. »

更多信息和选项

  • Expand 只对正整数幂起作用.
  • Expand 只应用到 expr 的顶级.
  • Expand[expr,Modulus->p] 展开 expr 并以 p 为模简化结果. »
  • Expand 将 expr 自动线性作用于列表，以及方程、不等式和逻辑函数.
  • Expand 接受以下选项：
  • Modulus 0假定的整数的模数
    Trig False是否进行三角和代数变换

范例

打开所有单元 关闭所有单元

基本范例  (3)

将多项式展开为各项的和：

Wolfram Language code: Expand[(x + 3)(x + 2)]

展开多项式的积：

Wolfram Language code: Expand[(1 + x) ^ 3(5x ^ 2 + 1)(x ^ 5 + 1)]

展开含有多个变量的多项式：

Wolfram Language code: Expand[(x + y) ^ 5 - (x ^ 5 + y ^ 5)]

范围  (16)

基本用法  (9)

展开多项式：

Wolfram Language code: Expand[(x + y) ^ 2(x - y) ^ 2]

展开有理函数：

Wolfram Language code: Expand[(x + y) ^ 2 / (x - y) ^ 2]

展开含有三角函数的表达式：

Wolfram Language code: Expand[(Sin[x] + Cos[x]) ^ 2]

展开含有超越函数的表达式：

Wolfram Language code: Expand[(x ^ s + 2E ^ -x) ^ 3]

展开含有任意函数的表达式：

Wolfram Language code: Expand[(f[Subscript[x, 1]] + f[Subscript[x, 2]]) ^ 3]

Expand 不能进入子表达式：

Wolfram Language code: Expand[Sqrt[(1 + x) ^ 2]]

但 ExpandAll 可以：

Wolfram Language code: ExpandAll[Sqrt[(1 + x) ^ 2]]

Expand 只应用于分子：

Wolfram Language code: Expand[(x + y) ^ 2 / (z + y) ^ 2]

ExpandAll 则同时应用于分子和分母：

Wolfram Language code: ExpandAll[(x + y) ^ 2 / (z + y) ^ 2]

验证展开的多项式与其因子形式的相等性：

Wolfram Language code: 1 + 5 x + 10 x^2 + 10 x^3 + 5 x^4 + x^5 == Expand[(x + 1) ^ 5]

Expand 可接受含有实数或复数系数的多项式作为输入：

Wolfram Language code: Expand[(x + I)(x - I)]

Expand 逐项作用于列表的各个元素：

Wolfram Language code: Expand[Table[(x + 1) ^ n, {n, 3}]]

Expand 逐项作用于等式和不等式的各个元素：

Wolfram Language code: Expand[1 < (x + y) ^ 2 < 2]

高级用法  (7)

整数模数 上对多项式应用 Expand：

Wolfram Language code: Expand[(2y + 3x) ^ 6, Modulus -> 4]

在有限域上展开多项式：

Wolfram Language code: ℱ = FiniteField[17, 3];
Wolfram Language code: Expand[(ℱ[123]x - ℱ[345])(ℱ[567]x - ℱ[789])]

对三角函数表达式应用 Expand：

Wolfram Language code: Expand[(Sin[2x] + x) ^ 2, Trig -> True]

对含有高次幂的多项式高效应用 Expand：

Wolfram Language code: Expand[(x + y + z) ^ 1000]//Length

不包含 x 的部分未展开：

Wolfram Language code: Expand[(a + b) ^ 2(1 + x) ^ 2, x]

不包含 1+x 的部分未展开：

Wolfram Language code: Expand[(1 + x) ^ 2 + (2 + x) ^ 2, 1 + x]

不匹配 x[_] 的部分未展开：

Wolfram Language code: Expand[(a[1] + a[2])(x[1] + x[2]) ^ 2, x[_]]

选项  (3)

Modulus  (2)

在 GF(2) 域内作用：

Wolfram Language code: Expand[(1 + x) ^ 10, Modulus -> 2]

模数不一定是素数：

Wolfram Language code: Expand[(1 + x) ^ 10, Modulus -> 4]

Trig  (1)

展开一个三角表达式：

Wolfram Language code: Expand[Sin[x + y], Trig -> True]

应用  (3)

计算对角矩阵的特征多项式：

Wolfram Language code: (matrix = DiagonalMatrix[{1, -1, 1, -1}])//MatrixForm

特征多项式是以下矩阵的行列式：

Wolfram Language code: matrix - x * IdentityMatrix[4]//MatrixForm

展开对角线元素的乘积以获得特征多项式：

Wolfram Language code: Expand[(1 - x)(-1 - x)(1 - x)(-1 - x)]

可用 CharacteristicPolynomial 函数直接进行计算：

Wolfram Language code: CharacteristicPolynomial[matrix , x]

Cyclotomic 多项式是首一多项式，系数为整数，并且在有理数上不可约.

Wolfram Language code: cyclo[n_] := Times@@Table[If[GCD[k, n] == 1, (x - (-1) ^ (2k / n)), 1], {k, 1, n}]

下面给出了 16 次分圆多项式：

Wolfram Language code: cyclo[16]

用 Expand 证明它的系数是整数：

Wolfram Language code: Expand[%]

可用 Cyclotomic 函数直接计算这些多项式：

Wolfram Language code: Cyclotomic[16, x]

Expand 可用于验证两个表达式是否相等：

Wolfram Language code: Cos[3x] == 4Cos[x] ^ 3 - 3Cos[x]
Wolfram Language code: Expand[%, Trig -> True]

属性和关系  (4)

许多函数给出未展开的结果：

Wolfram Language code: Product[x + i, {i, 6}]

应用 Expand：

Wolfram Language code: Expand[Product[x + i, {i, 6}]]

对多项式应用 Expand：

Wolfram Language code: Expand[(1 + x + y)(2 - x) ^ 3]

Factor 本质上与 Expand 相反：

Wolfram Language code: Factor[%]

当不涉及幂，Distribute 给出与 Expand 相同的结果：

Wolfram Language code: Distribute[(1 + x)(2 + x)(3 + x)] === Expand[(1 + x)(2 + x)(3 + x)]

直接应用分配率通常会产生比需要还多的项：

Wolfram Language code: Distribute[Factor[x ^ 6 - 1], Plus, Times, List, Times]

将所有项加起来：

Wolfram Language code: Total[%]

用 NonCommutativeExpand 展开非交换多项式：

Wolfram Language code: NonCommutativeExpand[(a + 2b)**(3a + 4b)]

指定加法和乘法运算的名称：

Wolfram Language code: alg = NonCommutativeAlgebra[<|"Multiplication" -> mult, "Addition" -> add|>];
Wolfram Language code: NonCommutativeExpand[mult[add[a, 2b], add[3a, 4b]], alg]

巧妙范例  (3)

对含有两个表情符号的二项式展开进行样式化：

Wolfram Language code: Style[Expand[(☺ + ☹) ^ 5], 20]

展开幂次很高的二项式：

Wolfram Language code: Expand[(1 + x) ^ 100]

创建一个嵌套的模式，对应于加法元胞自动机（规则 60）：

Wolfram Language code: Column[Table[CoefficientList[Expand[(1 + x) ^ t, Modulus -> 2], x], {t, 0, 31}]]
Wolfram Research (1988)，Expand，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Expand.html （更新于 2023 年）.

文本

Wolfram Research (1988)，Expand，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Expand.html （更新于 2023 年）.

CMS

Wolfram 语言. 1988. "Expand." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2023. https://reference.wolfram.com/language/ref/Expand.html.

APA

Wolfram 语言. (1988). Expand. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/Expand.html 年

BibTeX

@misc{reference.wolfram_2026_expand, author="Wolfram Research", title="{Expand}", year="2023", howpublished="\url{https://reference.wolfram.com/language/ref/Expand.html}", note=[Accessed: 08-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_expand, organization={Wolfram Research}, title={Expand}, year={2023}, url={https://reference.wolfram.com/language/ref/Expand.html}, note=[Accessed: 08-September-2026]}