Wolfram 语言与系统参考资料中心

Extract

Extract[expr,pos]

在 pos 指定的位置提取 expr 的部分.

Extract[expr,{pos₁,pos₂,…}]

提取 expr 各部分的列表.

Extract[expr,pos,h]

提取 expr 的各部分，在求值前用标头 h 封装每个部分.

Extract[pos]

表示 Extract 的操作符，可用于表达式.

范例

打开所有单元关闭所有单元

基本范例 (5)

从一个表达式中提取第二部分：

Wolfram Language code: Extract[{1, 2, 3, 4}, {2}]

使用运算符形式执行此操作：

Wolfram Language code: Extract[{2}][{a, b, c, d}]

提取嵌套在一个表达式中的部分：

Wolfram Language code: Extract[f[g[1, 2], h[3]], {1, 2}]

从表达式中提取多个嵌套部分：

Wolfram Language code: Extract[f[g[1, 2], h[x ^ 2]], {{1, 2}, {2, 1, 1}}]

提取矩阵的第二列：

Wolfram Language code:

Extract[(|   |   |   |
| - | - | - |
| a | b | c |
| d | e | f |
| g | h | i |), {All, 2}]

提取 Position 给定的部分：

Wolfram Language code: e = f[g[1, 2], {h[3]}];

Wolfram Language code: p = Position[e, _Integer]

Wolfram Language code: Extract[e, p]

范围 (25)

比较单一位置和多个位置 (5)

从列表中提取单个元素：

Wolfram Language code: Extract[{a, b, c, d, e}, {3}]

从列表中提取几个元素：

Wolfram Language code: Extract[{a, b, c, d, e}, {{1}, {4}, {3}}]

提取矩阵中 {1,3} 部分：

Wolfram Language code: mat = Array[a, {3, 3}];

Wolfram Language code: Extract[mat, {1, 3}]

提取矩阵的第一部分和第三部分（行）：

Wolfram Language code: Extract[mat, {{1}, {3}}]

从矩阵中提取一个长度为一的位置列表：

Wolfram Language code: Extract[mat, {{1, 3}}]

提取矩阵的多个元素：

Wolfram Language code: Extract[mat, {{1, 2}, {3, 3}, {2, 1}}]

提取规则的右侧并将结果封装在 Hold 中以阻止计算：

Wolfram Language code: Extract[x :> 1 + 1, {2}, Hold]

从列表中提取多个部分，并将每个部分包装在 Hold 中：

Wolfram Language code: Extract[{a, b, c, d, e}, {{1}, {2}, {5}}, Hold]

包括所有的格式 (5)

提取矩阵的第二行：

Wolfram Language code:

m = (|   |   |   |
| - | - | - |
| 1 | 2 | 3 |
| 4 | 5 | 6 |
| 7 | 8 | 9 |);

Wolfram Language code: Extract[m, {2}]

等价于：

Wolfram Language code: Extract[m, {2, All}]

提取矩阵的第二列：

Wolfram Language code: Extract[m, {All, 2}]

将第一列和第三列提取为子矩阵：

Wolfram Language code: Extract[m, {All, {1, 3}}]

Wolfram Language code: %//MatrixForm

分别提取第一列和第三列，有效创建一个矩阵：

Wolfram Language code: Extract[m, {{All, 1}, {All, 3}}]

Wolfram Language code: %//MatrixForm

从规则列表中的每个列表中提取第一条规则：

Wolfram Language code: rules = {{a -> 1, b -> 2}, {c -> 3, d -> 4, e -> 5}, {f -> 6}};

Wolfram Language code: Extract[rules, {All, 1}]

从第二个列表中的所有规则中提取右侧：

Wolfram Language code: Extract[rules, {2, All, 2}]

从一列列表的所有规则中提取左侧：

Wolfram Language code: Extract[rules, {All, All, 1}]

使用 All 提取保留该层的头部：

Wolfram Language code: Extract[e[f[1, 2, 3], g[4, 5, 6], h[7, 8, 9]], {All, 1}]

提取列表的所有右侧规则，避免使用 Hold 求值：:

Wolfram Language code: Extract[{a :> (1/0), b :> ArcTan[0, 0], c :> Print[5]}, {All, 2}, Hold]

没有 Hold 的情况下，该表达式将进行计算并产生其他反应：

Wolfram Language code: Extract[{a :> (1/0), b :> ArcTan[0, 0], c :> Print[5]}, {All, 2}]

分别提取规则列表中的两侧，将两个结果封装在 HoldComplete 中：

Wolfram Language code: Extract[{a :> (1/0), b :> ArcTan[0, 0], c :> Print[5]}, {{All, 1}, {All, 2}}, HoldComplete]

关联关系 (6)

通过键提取关联中的部分：

Wolfram Language code: Extract[<|expr -> 1, "str" -> 2|>, {Key[expr]}]

若键为字符串，则 Key 封装器为可选：

Wolfram Language code: Extract[<|expr -> 1, "str" -> 2|>, {"str"}]

通过键提取关联中的部分：

Wolfram Language code: Extract[<|2 -> 1 + x ^ 2, 3 -> y ^ 2 - 1, 1 -> x + y + z|>, {Key[1]}]

根据位置提取关联中的部分：

Wolfram Language code: Extract[<|2 -> 1 + x ^ 2, 3 -> y ^ 2 - 1, 1 -> x + y + z|>, {1}]

通过键提取关联中的多个部分：

Wolfram Language code: Extract[<|2 -> 1 + x ^ 2, 3 -> y ^ 2 - 1, 1 -> x + y + z|>, {{1}, {Key[1]}}]

提取关联中的嵌套部分：

Wolfram Language code: Extract[<|2 -> 1 + x ^ 2, 3 -> -1 + y ^ 2, 1 -> x + y + z|>, {Key[3], 1}]

提取关联中的多个嵌套部分：

Wolfram Language code: Extract[<|2 -> 1 + x ^ 2, 3 -> -1 + y ^ 2, 1 -> x + y + z|>, {{Key[3], 1}, {3, 1}}]

在不进行计算的情况下提取关联中的多个值：

Wolfram Language code: Extract[<|"a" :> 1 / 0, "b" :> Log[0]|>, {{"a"}, {"b"}}, Hold]

在没有 Hold 的情况下，关联中的值将进行计算并生成消息：

Wolfram Language code: Extract[<|"a" :> 1 / 0, "b" :> Log[0]|>, {{"a"}, {"b"}}]

特殊数组类型 (3)

若 expr 为稀疏数组，则 Extract[expr,…] 提取相应普通数组中的部分：

Wolfram Language code: sparse = SparseArray[{{1, 3} -> 1, {2, 2} -> 2, {3, 1} -> 3}, {3, 3}]

Wolfram Language code: Extract[sparse, {2, 2}]

子数组作为 SparseArray 对象返回：

Wolfram Language code: Extract[sparse, {All, 2}]

将第一列和第三列提取为单个稀疏数组：

Wolfram Language code: sparse = SparseArray[{{1, 3} -> 1, {2, 2} -> 2, {3, 1} -> 3}, {3, 3}]

Wolfram Language code: Extract[sparse, {All, {1, 3}}]

转换为普通数组：

Wolfram Language code: %//Normal

提取为两个单独的列会返回一个稀疏数组列表：

Wolfram Language code: Extract[sparse, {{All, 1}, {All, 3}}]

转换为普通数组显示结果是第一次提取的转置：

Wolfram Language code: %//Normal

从结构化数组中提取相应普通数组中的部分：

Wolfram Language code: QuantityArray[{{1, 2}, {3, 4}, {5, 6}}, {"Meters", "Seconds"}]

Wolfram Language code: Extract[%, {1, 1}]

如果可能的话，另一个结构化数组作为结果返回：

Wolfram Language code: SymmetrizedArray[{{1, 1} -> 3, {2, 2} -> 1, {3, 1} -> -5}, {3, 3}, Symmetric[All]]

Wolfram Language code: Extract[%, {1}]

空间和子列表 (6)

提取列表的第三个到第五个元素：

Wolfram Language code: Extract[Range[10], {3 ;; 5}]

提取奇数位置的元素：

Wolfram Language code: Extract[{a, b, c, d, e, f}, {1 ;; -1 ;; 2}]

从一个保留头部的一般表达式中提取空间跨度：

Wolfram Language code: Extract[f[1, 2, 3, 4, 5, 6, 7, 8, 9, 10], {-1 ;; 1 ;; -3}]

从每个列表中提取前两个元素：

Wolfram Language code: Extract[{{1, 2}, {3, 4, 5}}, {All, 1 ;; 2}]

从每个列表中提取第一个和最后一个元素：

Wolfram Language code: Extract[{{1, 2}, {3, 4, 5}}, {All, {1, -1}}]

提取第二行到第四行的第一个元素：

Wolfram Language code: m = Array[a, {5, 5}];

Wolfram Language code: Extract[m, {2 ;; 4, 1}]

提取第一、三、四行的第二个元素：

Wolfram Language code: Extract[m, {{1, 3, 4}, 2}]

提取最后两行的第一个、第二个和第五个元素：

Wolfram Language code: Extract[m, {-2 ;; -1, {1, 2, 5}}]

提取第一列和第五列：

Wolfram Language code: Extract[m, {All, {1, 5}}]

提取列表中前两条规则的右侧并停止计算：

Wolfram Language code: Extract[{a :> 1 ^ 2, b :> 2 ^ 2, c :> 3 ^ 3}, {1 ;; 2, 2}, Hold]

属性和关系 (6)

若 pos 不是列表，则 pos 和 {pos} 为等价规约：

Wolfram Language code: Extract[Range[10], 3] == Extract[Range[10], {3}]

Wolfram Language code: Extract[Range[10], 3 ;; 5] == Extract[Range[10], {3 ;; 5}]

对于一列整数 {i,j,…}，Extract[expr,{i,j,…}] 等价于 Part[expr,i,j,…]：

Wolfram Language code: Extract[{ArcTan[f[x], g[y]]}, {1, 2, 1}] === Part[{ArcTan[f[x], g[y]]}, 1, 2, 1]

Extract[expr,{{i₁,i₂,…},{j₁,j₂,…},…}] 等价于 {Part[expr,i₁,i₂,…],Part[expr,j₁,j₂,…],…}：

Wolfram Language code:

m = RandomReal[1, {3, 3}];
Extract[m, {{1 ;; 2, 1}, {2 ;; 3, 2}}] === {Part[m, 1 ;; 2, 1], Part[m, 2 ;; 3, 2]}

可扩展到空列表：

Wolfram Language code: Extract[m, {}] === {}

Extract 为 Position 的逆：

Wolfram Language code: expr = {{a, b, c}, {c, {a}, d}, {{e}, a, f}};

Wolfram Language code: Position[expr, a]

Wolfram Language code: Extract[expr, %]

在 Extract[expr,{pos₁,pos₂,…},h] 中，h 封装每个 pos_i 的提取结果：

Wolfram Language code: expr = Partition[Range[9], 3]

Wolfram Language code: Extract[expr, {{1, 1}, {All, 3}}, h]

如果只给出一个位置规约，h 将是最外层的头部：

Wolfram Language code: Extract[expr, {All, 1}, h]

在一层提取多个部分的规约会将头部保留在该层：

Wolfram Language code: expr = f[{1, 2}, {3, 4, 5}, {6}, {7, 8, 9, 10}];

Wolfram Language code: Extract[expr, {All, 1}]

Wolfram Language code: Extract[expr, {1 ;; 3, 1}]

Wolfram Language code: Extract[expr, {{2, 4}, 1}]

可能存在的问题 (2)

Extract[expr,{}] 返回子表达式的空字符串，因为位置列表是空的：

Wolfram Language code: Extract[h[a, b], {}]

Extract[expr,{{}}] 提取位置 {} 处的子表达式，为整个表达式：

Wolfram Language code: Extract[h[a, b], {{}}]

第二个参数中的一列列表始终解释为位置规约列表：

Wolfram Language code: arr = Array[a, {2, 4}];

Wolfram Language code: Extract[arr, {{1, 2}}]

因此，在 Part 中等效的规范可能会被 Extract 区别对待：

Wolfram Language code: Part[arr, {1, 2}] === Part[arr, 1 ;; 2]

Wolfram Language code: Extract[arr, {{1, 2}}] === Extract[arr, {1 ;; 2}]

如果需要 Part 和 Extract 保持一致，请使用一列列表并在末尾删除额外的列表：

Wolfram Language code: First@Extract[arr, {{{1, 2}}}] === First@Extract[arr, {{1 ;; 2}}]

Top

更多学习资源

技术支持

数据科学、金融与商业

工程

科学与技术

教育科技

教育举措

开始

提高你的技能

与我们合作

成人教育计划

青少年教育计划

欢迎阅读

Extract

更多信息

范例

基本范例 (5)

范围 (25)

比较单一位置和多个位置 (5)

包括所有的格式 (5)

关联关系 (6)

特殊数组类型 (3)

空间和子列表 (6)

属性和关系 (6)

可能存在的问题 (2)

文本

CMS

APA

BibTeX

BibLaTeX

Extract

更多信息

范例

基本范例 (5)

范围 (25)

比较单一位置和多个位置 (5)

包括所有的格式 (5)

关联关系 (6)

特殊数组类型 (3)

空间和子列表 (6)

属性和关系 (6)

可能存在的问题 (2)

参见

技术笔记

相关指南

历史

文本

CMS

APA

BibTeX

BibLaTeX