WOLFRAM

Wolfram 语言与系统参考资料中心

FindMaximum[f,x]

求出 f 的局部极大值，从一个自动选定的点开始.

FindMaximum[f,{x,x0}]

求出 f 的局部极大值，从点 x=x0 开始.

FindMaximum[f,{{x,x0},{y,y0},…}]

求出多变量的函数中局部极大值.

FindMaximum[{f,cons},{{x,x0},{y,y0},…}]

求出满足 cons 约束条件的局部极大值.

FindMaximum[{f,cons},{x,y,…}]

从约束条件定义区域内的点开始.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
选项  
AccuracyGoal 和 PrecisionGoal  
EvaluationMonitor  
Gradient  
Method  
StepMonitor  
WorkingPrecision  
属性和关系  
可能存在的问题  
参见
技术笔记
相关指南
历史
按以下格式引用：

FindMaximum

FindMaximum[f,x]

求出 f 的局部极大值，从一个自动选定的点开始.

FindMaximum[f,{x,x0}]

求出 f 的局部极大值，从点 x=x0 开始.

FindMaximum[f,{{x,x0},{y,y0},…}]

求出多变量的函数中局部极大值.

FindMaximum[{f,cons},{{x,x0},{y,y0},…}]

求出满足 cons 约束条件的局部极大值.

FindMaximum[{f,cons},{x,y,…}]

从约束条件定义区域内的点开始.

更多信息和选项

  • FindMaximum 返回形式为 {fmax,{x->xmax}} 的列表，当 fmax 是 f 里的最大值时，则 xmax 是 x 里的值.
  • 若起始点是给定列表里的变量，则变量的值与列表的维数相同.
  • cons 约束包括方程、不等式或这些逻辑组合.
  • 约束 cons 可以是下列的逻辑组合：
  • lhs==rhs方程
    lhs>rhs 或者 lhs>=rhs 不等式
    {x,y,…}∈reg区域指定
  • FindMaximum 首先局部化所有变量值，然后求 f 里变量的符号值，最后求结果的数字值.
  • FindMaximum 具有 HoldAll 属性，并且使用 Block 局部化变量.
  • FindMaximum[f,{x,x0,x1}] 查寻 f 里的局部极大值，其中 f 使用 x0 和 x1 作为 x 的前两个值，从而避免使用导数.
  • FindMaximum[f,{x,x0,xmin,xmax}] 查寻一个局部极大值，若 x 的范围在 xmin 到 xmax 之外，则停止查寻.
  • 除了 f 和 cons 都线性化，否则 FindMaximum 的结果只能作为局部量，不能作为全局量或最大量.
  • 默认的情况下，所有变量假定是实数.
  • 若 f 和 cons 是线性的，x∈Integers 只指定是整数型的变量.
  • 给出以下选项：
  • AccuracyGoalAutomatic精确查询
    EvaluationMonitor None当计算 f 值时，运行的表达式
    Gradient Automatic梯度函数列表 {D[f,x],D[f,y],…}
    MaxIterationsAutomatic使用迭代的最大数
    Method Automatic使用的方法
    PrecisionGoalAutomatic查询的精度
    StepMonitor None对表达式求值时采取的步长
    WorkingPrecision MachinePrecision内部计算中的精度
  • AccuracyGoal 和 PrecisionGoal 的设置指定在最大坐标值和最大函数值处查询的位数.
  • FindMaximum 将继续运行，直到 AccuracyGoal 或 PrecisionGoal 指定的目标达到.
  • 在默认 Automatic 的情况下，Method 的设置包括 "ConjugateGradient"、 "PrincipalAxis"、 "LevenbergMarquardt"、"Newton" 和 "QuasiNewton".

范例

打开所有单元 关闭所有单元

基本范例  (4)

从 开始，查找一个局部极大值：

Wolfram Language code: FindMaximum[x Cos[x], {x, 2}]
Wolfram Language code: Plot[x Cos[x], {x, 0, 14}]

提取的 x 的局部极大值：

Wolfram Language code: x /. Last[FindMaximum[x Cos[x], {x, 2}]]

在 的范围内，查找从 开始的局部极大值：

Wolfram Language code: FindMaximum[{x Cos[x], 1 ≤ x ≤ 15}, {x, 7}]

按照线性和整数的约束条件，找到一个线性函数的局部极大值：

Wolfram Language code: FindMaximum[{-x - y, x + 2y ≥ 3 && x ≥ 0 && y ≥ 0 && y∈Integers}, {x, y}]

求几何区域上函数的最大值：

Wolfram Language code: FindMaximum[{x + y, {x, y}∈Disk[]}, {x, y}]

绘制图线：

Wolfram Language code: Show[ContourPlot[x + y, {x, y}∈Disk[]], Graphics[{Red, PointSize[Large], Point[{x, y} /. Last[%]]}]]

范围  (12)

不同的起始点得到不同的局部极大值：

Wolfram Language code: FindMaximum[x Cos[x], {x, 5}]
Wolfram Language code: FindMaximum[x Cos[x], {x, 10}]

从 ， 开始，一个二元变量函数的局部极大值：

Wolfram Language code: FindMaximum[Sin[x]Sin[2y], {{x, 2}, {y, 2}}]

一个圆内的局部极大值：

Wolfram Language code: FindMaximum[{Sin[x]Sin[2y], x ^ 2 + y ^ 2 < 3}, {{x, 2}, {y, 2}}]

没有提供起始点：

Wolfram Language code: FindMaximum[{Sin[x]Sin[2y], x ^ 2 + y ^ 2 < 3}, {x, y}]

对于线性对象和约束条件，可以限制整数：

Wolfram Language code: FindMaximum[{-x - y, 3x + 2y ≥ 7 && x ≥ 0 && y ≥ 0}, {x, y}]
Wolfram Language code: FindMaximum[{-x - y, 3x + 2y ≥ 7 && x ≥ 0 && y ≥ 0 && x∈Integers}, {x, y}]

使用 Or：

Wolfram Language code: FindMaximum[{x + y, x ^ 2 + y ^ 2 ≤ 1 || (x + 2) ^ 2 + (y + 2) ^ 2 ≤ 1}, {x, y}]

求区域上的最大值：

Wolfram Language code: ℛ = Cylinder[{{-1, 0, 1}, {1, 0, -1}}, 1];
Wolfram Language code: FindMaximum[{z, {x, y, z}∈ℛ}, {x, y, z}]

绘制图线：

Wolfram Language code: Graphics3D[{{Opacity[0.5], Green, ℛ}, {Red, PointSize[Large], Point[{x, y, z} /. Last[%]]}}]

求两个区域中的点之间的最大距离：

Wolfram Language code: Subscript[ℛ, 1] = Disk[]; Subscript[ℛ, 2] = Line[{{-(1/2), -(1/2)}, {-(1/2), (1/2)}, {(1/2), (1/2)}, {(1/2), -(1/2)}, {-(1/2), -(1/2)}}];
Wolfram Language code: FindMaximum[{(x - u)^2 + (y - v)^2, {{x, y}∈Subscript[ℛ, 1], {u, v}∈Subscript[ℛ, 2]}}, {x, y, u, v}]

绘制图线：

Wolfram Language code: Graphics[{{LightBlue, Subscript[ℛ, 1]}, {Green, Subscript[ℛ, 2]}, {Red, Point[{{x, y}, {u, v}} /. Last[%]]}}]

求 的最大值，以使得矩形和椭圆仍然相交：

Wolfram Language code: Subscript[ℛ, 1] = Rectangle[]; Subscript[ℛ, 2] = Circle[{(1/3), (1/3)}, {2 r, r}];
Wolfram Language code: FindMaximum[{r, {x, y}∈Subscript[ℛ, 1] && {x, y}∈Subscript[ℛ, 2]}, {r, x, y}]

绘制图线：

Wolfram Language code: Graphics[{{LightBlue, Subscript[ℛ, 1]}, {Green, Subscript[ℛ, 2]}, {Red, Point[{x, y}]}} /. Last[%]]

求 的最大值，以使得 包含给定的三个点：

Wolfram Language code: Subscript[ℛ, 3] = Disk[{a, b}, {r, 2 - r}];
Wolfram Language code: FindMaximum[{r, ({0, 0} | {1, 0} | {0, 1})∈Subscript[ℛ, 3]}, {a, b, r}]

绘制图线：

Wolfram Language code: Graphics[{{LightBlue, Subscript[ℛ, 3]} /. Last[%], {Red, Point[{{0, 0}, {1, 0}, {0, 1}}]}}]

使用 指定 是 中的向量：

Wolfram Language code: ℛ = Sphere[];
Wolfram Language code: FindMaximum[{x.{1, 2, 3}, x∈ℛ}, x]

求两个区域中点之间的最大距离：

Wolfram Language code: Subscript[ℛ, 1] = Triangle[{{0, 0}, {1, 0}, {0, 1}}]; Subscript[ℛ, 2] = Disk[{2, 2}, 1];
Wolfram Language code: FindMaximum[{EuclideanDistance[x, y], {x∈Subscript[ℛ, 1], y∈Subscript[ℛ, 2]}}, {x, y}]

绘制图线：

Wolfram Language code: Graphics[{{LightBlue, Subscript[ℛ, 1], Subscript[ℛ, 2]}, {Red, Point[{x, y}]}} /. Last[%]]

选项  (7)

AccuracyGoal 和 PrecisionGoal  (2)

收敛标准 和 ：

Wolfram Language code: FindMaximum[Sin[x / 2], {x, 1}, AccuracyGoal -> 9, PrecisionGoal -> 8]

没有达到机器的缺省精确度时，执行收敛标准 和 ：

Wolfram Language code: FindMaximum[Sin[x / 2], {x, 1}, AccuracyGoal -> 20, PrecisionGoal -> 18]

设置较高的 WorkingPrecision 使过程收敛：

Wolfram Language code: FindMaximum[Sin[x / 2], {x, 1}, AccuracyGoal -> 20, PrecisionGoal -> 18, WorkingPrecision -> 40]

EvaluationMonitor  (1)

绘制局部最大值处的收敛：

Wolfram Language code: ListPlot[Last[Reap[FindMaximum[x Cos[x], {x, 5}, EvaluationMonitor :> Sow[x]]]]]

Gradient  (1)

用给定梯度和用有限的梯度差分计算的赫赛 （Hessian）函数：

Wolfram Language code: FindMaximum[Sin[x]Sin[2 y], {x, y}, Gradient -> {Cos[x] Sin[2 y], 2 Cos[2 y] Sin[x]}, Method -> "Newton"]

使用梯度和赫赛 （Hessian）函数：

Wolfram Language code: FindMaximum[Sin[x]Sin[2y], {x, y}, Gradient -> {Cos[x] Sin[2 y], 2 Cos[2 y] Sin[x]}, Method -> {"Newton", Hessian -> {{-Sin[x] Sin[2 y], 2 Cos[x] Cos[2 y]}, {2 Cos[x] Cos[2 y], -4 Sin[x] Sin[2 y]}}}]

Method  (1)

此例中，默认导数法有一定困难：

Wolfram Language code: FindMaximum[-Abs[x + 1] - Abs[x + 1.01] - Abs[y + 1], {x, y}]
Wolfram Language code: FindMaximum[-Abs[x + 1] - Abs[x + 1.01] - Abs[y + 1], {x, y}, Method -> "ConjugateGradient"]

在此例中，可以使用不需要求导数的直接查询法：

Wolfram Language code: FindMaximum[-Abs[x + 1] - Abs[x + 1.01] - Abs[y + 1], {x, y}, Method -> "PrincipalAxis"]

NMaximize 也可以使用一定范围的直接查询法：

Wolfram Language code: NMaximize[{-Abs[x + 1] - Abs[x + 1.01] - Abs[y + 1]}, {x, y}]

StepMonitor  (1)

FindMaximum 是查找函数最大值的步长：

Wolfram Language code: pts = Reap[FindMaximum[-(1 - x) ^ 2 - 100(-x ^ 2 - y) ^ 2 - 1, {{x, -1.2}, {y, 1}}, StepMonitor :> Sow[{x, y}]]][[2, 1]]; pts = Join[{{-1.2, 1}}, pts];
Wolfram Language code: ContourPlot[-(1 - x) ^ 2 - 100(-x ^ 2 - y) ^ 2 - 1//Minus//Log, {x, -1.3, 1.5}, {y, -1.5, 1.4}, Epilog -> {Red, Line[pts], Point[pts]}]

WorkingPrecision  (1)

设置工作精度 ，在默认的情况下，准AccuracyGoal和PrecisionGoal设为 ：

Wolfram Language code: FindMaximum[Cos[x ^ 2 - 3 y] + Sin[x ^ 2 + y ^ 2], {x, y}, Method -> "Newton", WorkingPrecision -> 20]

属性和关系  (2)

FindMaximum 尽可能找到一个局部极大值， NMaximize 尽可能找到一个全局最大值：

Wolfram Language code: FindMaximum[{100 / ((x - 1)^2 + (y - 1)^2 + 1) + 200 / ((x + 1)^2 + (y + 2)^2 + 1), x^2 + y^2 > 3 }, {{x, 2}, y}]
Wolfram Language code: NMaximize[{ 100 / ((x - 1)^2 + (y - 1)^2 + 1) + 200 / ((x + 1)^2 + (y + 2)^2 + 1), x^2 + y^2 > 3 }, {x, y}]
Wolfram Language code: ContourPlot[100 / (((x - 1)) ^ 2 + ((y - 1)) ^ 2 + 1) + 200 / (((x + 1)) ^ 2 + ((y + 2)) ^ 2 + 1), {x, -3, 2}, {y, -3, 2}, RegionFunction -> (#1 ^ 2 + #2 ^ 2 > 3&), Contours -> 10, Epilog -> ({Red, PointSize[.02], Text["global maximum", {-.995, -2.092}], Point[{-.995, -1.992}], Text["local maximum", {0.5304, 1.2191}], Point[{1.2304, 1.2191}]}), ContourLabels -> True]

Maximize 找到全局最大值并在有限精度内运行：

Wolfram Language code: Maximize[{ 100 / ((x - 1)^2 + (y - 1)^2 + 1) + 200 / ((x + 1)^2 + (y + 2)^2 + 1), x^2 + y^2 > 3 }, {x, y}]
Wolfram Language code: N[%]

FindMaximum 给出最大值和产生最大值的点：

Wolfram Language code: FindMaximum[{x - 2y, x ^ 2 + y ^ 2 ≤ 1}, {x, y}]

FindArgMax 给出最大值的位置：

Wolfram Language code: FindArgMax[{x - 2y, x ^ 2 + y ^ 2 ≤ 1}, {x, y}]

FindMaxValue 给出最大值：

Wolfram Language code: FindMaxValue[{x - 2y, x ^ 2 + y ^ 2 ≤ 1}, {x, y}]

可能存在的问题  (6)

对于机器精度的算法，平滑的函数极大值也会显示有些起伏：

Wolfram Language code: x /. Last[FindMaximum[x Cos[x], {x, -1}]]
Wolfram Language code: Plot[x Cos[x], {x, % - 1.*^-7, % + 1.*^-7}, PlotRange -> All]

超过机器精度通常避免这样的错误：

Wolfram Language code: FindMinimum[x Cos[x], {x, -1}, WorkingPrecision -> 30]

如果限制区域为空，则算法不收敛：

Wolfram Language code: FindMaximum[{x + y, x ^ 2 + y ^ 2 ≥ 2 && x ^ 2 + y ^ 2 ≤ 1}, {x, y}]

如果最大值不确定，则算法不收敛：

Wolfram Language code: FindMaximum[Tan[x], {x, 2}]
Wolfram Language code: FindMaximum[{x ^ 2 + y ^ 2, x ^ 2 + y ^ 2 > 10}, {x, y}]

整数线性算法仅适用于机器数问题：

Wolfram Language code: FindMaximum[{-x - y, x + 2y ≥ 3 && x > 1 && y > 1 && x∈Integers}, {x, y}, WorkingPrecision -> 20]

某些时候提供一个适当的起点可以使算法收敛：

Wolfram Language code: FindMaximum[{-Cos[x] + Exp[(x - 0.5) y], x ^ 2 + y ^ 2 < 1}, {x, y}]
Wolfram Language code: FindMaximum[{-Cos[x] + Exp[(x - 0.5) y], x ^ 2 + y ^ 2 < 1}, {{x, -1}, {y, -1}}]

符号计算函数可能很耗时：

Wolfram Language code: f[x_] := Nest[Sin[# + Sin[2#]]&, x, 15]
Wolfram Language code: FindMaximum[f[x], {x, 0}]//Timing

限制函数定义可防止符号计算：

Wolfram Language code: g[x_ ? NumericQ] := Nest[Sin[# + Sin[2#]]&, x, 15]
Wolfram Language code: FindMaximum[g[x], {x, 0}]//Timing
Wolfram Research (2003)，FindMaximum，Wolfram 语言函数，https://reference.wolfram.com/language/ref/FindMaximum.html （更新于 2014 年）.

文本

Wolfram Research (2003)，FindMaximum，Wolfram 语言函数，https://reference.wolfram.com/language/ref/FindMaximum.html （更新于 2014 年）.

CMS

Wolfram 语言. 2003. "FindMaximum." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2014. https://reference.wolfram.com/language/ref/FindMaximum.html.

APA

Wolfram 语言. (2003). FindMaximum. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/FindMaximum.html 年

BibTeX

@misc{reference.wolfram_2026_findmaximum, author="Wolfram Research", title="{FindMaximum}", year="2014", howpublished="\url{https://reference.wolfram.com/language/ref/FindMaximum.html}", note=[Accessed: 10-October-2026]}

BibLaTeX

@online{reference.wolfram_2026_findmaximum, organization={Wolfram Research}, title={FindMaximum}, year={2014}, url={https://reference.wolfram.com/language/ref/FindMaximum.html}, note=[Accessed: 10-October-2026]}