WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

FiniteFieldElementPrimitiveQ[a]

a がその周辺体の原始元かどうかを調べる．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
アプリケーション  
特性と関係  
関連項目
関連するガイド
履歴
引用書式

FiniteFieldElementPrimitiveQ

FiniteFieldElementPrimitiveQ[a]

a がその周辺体の原始元かどうかを調べる．

詳細

  • a の最小多項式が原始的でその次数が上の の拡大次数と等しければ　a は有限体 の原始元である．
  • q 元の有限体はEulerPhi[q-1]の原始元を含む．

例題

すべて開く すべて閉じる

例  (1)

有限体の元がその周辺体の原始元かどうかを調べる：

Wolfram Language code: ℱ = FiniteField[17, 3];
Wolfram Language code: FiniteFieldElementPrimitiveQ[ℱ[123]]
Wolfram Language code: FiniteFieldElementPrimitiveQ[ℱ[125]]

スコープ  (3)

多項式表現の有限体の元を調べる：

Wolfram Language code: ℱ = FiniteField[179, 2];
Wolfram Language code: FiniteFieldElementPrimitiveQ[ℱ[123]]
Wolfram Language code: FiniteFieldElementPrimitiveQ[ℱ[234]]

指数表現の有限体の元を調べる：

Wolfram Language code: ℱ = FiniteField[2, 10, "Exponential"];
Wolfram Language code: FiniteFieldElementPrimitiveQ[ℱ[2]]
Wolfram Language code: FiniteFieldElementPrimitiveQ[ℱ[4]]

FiniteFieldElementオブジェクトではない引数はFalseを与える：

Wolfram Language code: FiniteFieldElementPrimitiveQ[17]
Wolfram Language code: FiniteFieldElementPrimitiveQ[x]

アプリケーション  (1)

指定された底の元の離散対数関数を実装する：

Wolfram Language code: ℱ = FiniteField[3, 10]; b = ℱ[123]

基底元は素数でなければならない：

Wolfram Language code: FiniteFieldElementPrimitiveQ[b]

b の最小多項式を使って指数元表現で体を構築する：

Wolfram Language code: 𝒢 = FiniteField[3, MinimalPolynomial[b], "Exponential"]

b を の生成元に写像する体の同型を構築する：

Wolfram Language code: ℐ = FiniteFieldEmbedding[b -> 𝒢[2]]

離散対数関数を定義する：

Wolfram Language code: dlog[a_] := ℐ[a]["Index"] - 1

ℱ の非零の元についての離散対数を計算する：

Wolfram Language code: dlog[ℱ[456]]
Wolfram Language code: b ^ %

特性と関係  (4)

体のすべての非零の元が a の整数ベキなら，a はその周辺体の原始元である：

Wolfram Language code: ℱ = FiniteField[5, 3]; a = ℱ[123]; FiniteFieldElementPrimitiveQ[a]
Wolfram Language code: Information[ℱ, "FieldSize"]
Wolfram Language code: Length[Union[a ^ Range[124]]]

a が iの生成元でその最小多項式が原始的なら，a は iの原始元である：

Wolfram Language code: ℱ = FiniteField[59, 6]; a = ℱ[123456]; FiniteFieldElementPrimitiveQ[a]

MinimalPolynomialを使って a の最小多項式を求める：

Wolfram Language code: f = MinimalPolynomial[a, x]

以下は，a が の生成元であることを示している：

Wolfram Language code: Exponent[f, x] == Information[ℱ, "ExtensionDegree"]

PrimitivePolynomialQを使って f が原始的であることを示す：

Wolfram Language code: PrimitivePolynomialQ[f, 59]

原始元の乗法的位数はその周辺体のサイズより1小さい：

Wolfram Language code: ℱ = FiniteField[1009, 2]; a = ℱ[1017]; FiniteFieldElementPrimitiveQ[a]
Wolfram Language code: Information[ℱ, "FieldSize"]

MultiplicativeOrderを使って a の乗法的位数を計算する：

Wolfram Language code: MultiplicativeOrder[a]

q 元の有限体はEulerPhi[q-1]の原始元を含む：

Wolfram Language code: ℱ = FiniteField[11, 5]; Count[FiniteFieldElementPrimitiveQ[ℱ[#]]& /@ Range[0, Information[ℱ, "FieldSize"] - 1], True]
Wolfram Language code: EulerPhi[Information[ℱ, "FieldSize"] - 1]
Wolfram Research (2023), FiniteFieldElementPrimitiveQ, Wolfram言語関数， https://reference.wolfram.com/language/ref/FiniteFieldElementPrimitiveQ.html.

テキスト

Wolfram Research (2023), FiniteFieldElementPrimitiveQ, Wolfram言語関数， https://reference.wolfram.com/language/ref/FiniteFieldElementPrimitiveQ.html.

CMS

Wolfram Language. 2023. "FiniteFieldElementPrimitiveQ." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/FiniteFieldElementPrimitiveQ.html.

APA

Wolfram Language. (2023). FiniteFieldElementPrimitiveQ. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/FiniteFieldElementPrimitiveQ.html

BibTeX

@misc{reference.wolfram_2026_finitefieldelementprimitiveq, author="Wolfram Research", title="{FiniteFieldElementPrimitiveQ}", year="2023", howpublished="\url{https://reference.wolfram.com/language/ref/FiniteFieldElementPrimitiveQ.html}", note=[Accessed: 07-October-2026]}

BibLaTeX

@online{reference.wolfram_2026_finitefieldelementprimitiveq, organization={Wolfram Research}, title={FiniteFieldElementPrimitiveQ}, year={2023}, url={https://reference.wolfram.com/language/ref/FiniteFieldElementPrimitiveQ.html}, note=[Accessed: 07-October-2026]}