WOLFRAM

Wolfram 语言与系统参考资料中心
FitRegularization

FitRegularization

是 Fit 和 FindFit 的一个选项，指定用于拟合模型的正则化.

更多信息
Details and Options Details and Options
范例  
基本范例  
应用  
参见
历史
按以下格式引用：

FitRegularization

FitRegularization

是 Fit 和 FindFit 的一个选项，指定用于拟合模型的正则化.

更多信息

  • Fit 和 FindFit 通常寻找最小化 norm(res) 的参数 pars，其中 res 是残差向量，被定义为数据坐标点处的模型和数据响应之间的差. 当 FitRegularization->rfun 时，最小化的目标是 norm(residuals)+rfun(pars).
  • Fit 和 FindFit 求能范数最小化 的参数 ，其中 是残差向量，其分量由 给出，其中 是数据的坐标， 是数据的值，model 取决于参数.
  • 可能的设置包括：
  • None没有正则化
    rfun用 rfun[a] 正则化
    {"Tikhonov", λ}用 正则化
    {"LASSO",λ}用 正则化
    {"Variation",λ}用 lambda||TemplateBox[{Differences, paclet:ref/Differences}, RefLink, BaseStyle -> {2ColumnTableMod}][a]||^2 正则化
    {"TotalVariation",λ}用 lambda||TemplateBox[{Differences, paclet:ref/Differences}, RefLink, BaseStyle -> {2ColumnTableMod}][a]||_1 正则化
    {"Curvature",λ}用 lambda||TemplateBox[{Differences, paclet:ref/Differences}, RefLink, BaseStyle -> {2ColumnTableMod}][a,2]||^2 正则化
    {r1,r2,…}用 r1,… 中各项的和正则化

范例

打开所有单元 关闭所有单元

基本范例  (2)

Tikhonov 正则化控制最佳拟合参数的大小：

Wolfram Language code: data = {{0., 0.}, {0.001, 1}, {0.01, 1}};
Wolfram Language code: Fit[data, {1, x, x ^ 2}, x, FitRegularization -> {"Tikhonov", 1}]

如果不使用正则化，系数会非常大：

Wolfram Language code: Fit[data, {1, x, x ^ 2}, x]

可用 LASSO 正则化选择最有效的基元素：

Wolfram Language code: data = {{-5, -16.15}, {-4, -10.46}, {-3, -6.91}, {-2, -4.26}, {-1, -1.91}, {0, -0.1}, {1, 2.09}, {2, 3.94}, {3, 5.29}, {4, 5.34}, {5, 3.65}};
Wolfram Language code: Fit[data, {1, x, x ^ 2, x ^ 3, x ^ 4}, x, FitRegularization -> {"LASSO", 2}]

应用  (5)

用正则化将数值解 稳定到 ，其中 受到扰动：

Wolfram Language code: a = N[HilbertMatrix[47]]; xexact = Table[t * (1 - t), {t, 0., 1., 1 / 46}]; b = a.xexact + 10^ - 8 RandomReal[{-1, 1}, 47];

LinearSolve 求出的解含有非常大的项：

Wolfram Language code: ListPlot[LinearSolve[a, b]]

正则化后的解更加接近于未被扰动的问题的解：

Wolfram Language code: xreg = Table[Fit[{a, b}, FitRegularization -> {"Tikhonov", 10 ^ -ll}], {ll, 0, 3, 2}];
Wolfram Language code: ListPlot[Prepend[xreg, xexact], PlotStyle -> PointSize[0.025]]

使用各种正则化求输入信号的平滑近似：

Wolfram Language code: n = 201; m = 201; times = Range[m];

目标输出是阶跃函数：

Wolfram Language code: m1 = Round[m / 5]; m2 = Round[m / 4]; m3 = Round[m / 4];output = ConstantArray[0, m]; output[[m1 + Range[m2]]] = 1; output[[m1 + m2 + Range[m3]]] = -1; op = ListLinePlot[output]

通过输出与 的卷积确定输入：

Wolfram Language code: h = (1/9)(1 - .4Cos[2 times]) * .9 ^ times;hmat = ToeplitzMatrix[h, Prepend[ConstantArray[0, n - 1], h[[1]]]];

如果不使用正则化，预测的响应与信号非常接近，但是算出的输入有很多振荡：

Wolfram Language code: {input, predicted} = Fit[{hmat, output}, {"BestFitParameters", "PredictedResponse"}]; Row[{ListLinePlot[input], ListLinePlot[{predicted, output}]}]

如果使用 variation 正则化，可求出更加平滑的近似结果：

Wolfram Language code: {input, predicted} = Fit[{hmat, output}, {"BestFitParameters", "PredictedResponse"}, FitRegularization -> {"Variation", .3}]; Row[{ListLinePlot[input], ListLinePlot[{predicted, output}]}]

也可以包括输入大小的正则化：

Wolfram Language code: {input, predicted} = Fit[{hmat, output}, {"BestFitParameters", "PredictedResponse"}, FitRegularization -> {{"Variation", .3}, {"Tikhonov", .01}}]; Row[{ListLinePlot[input], ListLinePlot[{predicted, output}]}]

用 variation 正则化平滑损坏的数据：

Wolfram Language code: n = 4000; times = N[Range[0, n - 1]]; original = .5 Sin[2 Pi times / n] * Sin[.01 times]; corrupted = original + RandomReal[{-.05, .05}, n]; ListLinePlot[corrupted]

绘制残差的模和 variation 的模之间的权衡：

Wolfram Language code: id = IdentityMatrix[n, SparseArray];
Wolfram Language code: tradeoff = Table[{smoothed, residual} = Fit[{id, corrupted}, {"BestFitParameters", "FitResiduals"}, FitRegularization -> {"Variation", 2 ^ logλ}];Tooltip[{Norm[Differences[smoothed]], Norm[residual]}, 2. ^ logλ], {logλ, -10, 20}];
Wolfram Language code: ListPlot[tradeoff, Joined -> True, Mesh -> All]

在曲线急剧弯曲处选择 的值：

Wolfram Language code: smoothed = Fit[{id, corrupted}, "BestFitParameters", FitRegularization -> {"Variation", 100}];
Wolfram Language code: ListLinePlot[{corrupted, smoothed}]

使用 total variation 正则化平滑带有跳变的损坏信号：

Wolfram Language code: n = 2000; id = IdentityMatrix[n, SparseArray]; times = Range[0, n - 1]; temp = ConstantArray[1, n / 4]; original = Join[temp, -temp, temp, -temp] + .5 Sin[2 Pi times / n]; corrupted = original + RandomReal[{-.1, .1}, n]; ListLinePlot[{corrupted, original}]

使用参数 进行正则化：

Wolfram Language code: smoothed = Fit[{id, corrupted}, "BestFitParameters", FitRegularization -> {"TotalVariation", 2.}];
Wolfram Language code: ListLinePlot[{smoothed, original}]

更小的 值的平滑效果变差，但残差的模变得更小了：

Wolfram Language code: lesssmoothed = Fit[{id, corrupted}, "BestFitParameters", FitRegularization -> {"TotalVariation", .1}];
Wolfram Language code: ListLinePlot[{lesssmoothed, original}]
Wolfram Language code: {Norm[original - smoothed], Norm[original - lesssmoothed]}

使用 LASSO (L1) 正则化求稀疏拟合（基追踪）：

Wolfram Language code: σ = 0.05; nτ = 500; times = Subdivide[0., 1., nτ]; nω = 30;

这里有一个信号：

Wolfram Language code: signal = (1 + .5 Sin[11 times])Sin[30 Sin[5 times]]; sdata = Transpose[{times, signal}]; ListLinePlot[sdata]

目标是使用数千个 Gabor 基函数中的几个来近似信号：

Wolfram Language code: Length[basis = Flatten[ Table[Exp[-(((t - τ)/σ))^2] {1, Table[{Cos[ω t], Sin[ω t]}, {ω, Drop[Subdivide[0., 150., nω], 1]}]}, {τ, Subdivide[0., 1., nτ]}]]]

设 ，只用了 41 个基元素即算出了拟合：

Wolfram Language code: AbsoluteTiming[sparseFit = Fit[sdata, basis, t, "BestFitParameters", FitRegularization -> {"LASSO", 1.}]]

误差很小：

Wolfram Language code: fitt = basis.sparseFit /. t -> times; ListLinePlot[Transpose[{times, signal - fitt}]]

找出重要的基元素后，可以通过求这些元素的最小二乘拟合来减少误差：

Wolfram Language code: bpos = Flatten[sparseFit["NonzeroPositions"]]; sbasis = basis[[bpos]]; sbfit = Fit[sdata, sbasis, t]; ListLinePlot[Transpose[{times, signal - (sbfit /. t -> times)}], PlotRange -> All]

如果设 ，则需要更多的基元素来求出拟合：

Wolfram Language code: AbsoluteTiming[sparseFit = Fit[sdata, basis, t, "BestFitParameters", FitRegularization -> {"LASSO", 0.1}]]

误差则变得更小：

Wolfram Language code: fitt = basis.sparseFit /. t -> times; ListLinePlot[Transpose[{times, signal - fitt}]]
Wolfram Research (2019)，FitRegularization，Wolfram 语言函数，https://reference.wolfram.com/language/ref/FitRegularization.html.

文本

Wolfram Research (2019)，FitRegularization，Wolfram 语言函数，https://reference.wolfram.com/language/ref/FitRegularization.html.

CMS

Wolfram 语言. 2019. "FitRegularization." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/FitRegularization.html.

APA

Wolfram 语言. (2019). FitRegularization. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/FitRegularization.html 年

BibTeX

@misc{reference.wolfram_2026_fitregularization, author="Wolfram Research", title="{FitRegularization}", year="2019", howpublished="\url{https://reference.wolfram.com/language/ref/FitRegularization.html}", note=[Accessed: 15-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_fitregularization, organization={Wolfram Research}, title={FitRegularization}, year={2019}, url={https://reference.wolfram.com/language/ref/FitRegularization.html}, note=[Accessed: 15-September-2026]}