WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

FittedModel[…]

LinearModelFit等の関数から得られた記号フィットされたモデルを表す．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
一般化と拡張  
関連項目
テクニカルノート
関連するガイド
履歴
引用書式

FittedModel

FittedModel[…]

LinearModelFit等の関数から得られた記号フィットされたモデルを表す．

詳細

  • フィットされたモデルの特性はFittedModel[…]["property"]で得ることができる．
  • FittedModel[…][{prop1,prop2,…}] はいくつかの特性を与える．
  • FittedModel[…][x1,…]は，特定の点 x1, … で最もよくフィットした関数の値を与える．
  • NormalはFittedModelの最もよくフィットした関数の式を与える．
  • FittedModelオブジェクトは，LinearModelFit，NonlinearModelFit，GeneralizedLinearModelFit等のフィット関数によって返される．
  • FittedModel[…][prop,ann]は特性 prop と関連する注釈 ann を与える．
  • 指定のフィットされたモデルに使用可能な特性は，モデルを生成するLinearModelFit等の関数ページに記されている．

例題

すべて開く すべて閉じる

例  (2)

非線形フィットからFittedModelを得る：

Wolfram Language code: data = {{0, 1}, {1, 0}, {3, 2}, {5, 4}};
Wolfram Language code: nlm = NonlinearModelFit[data, Log[a + b x ^ 2], {a, b}, x]

FittedModelオブジェクトからその関数形を得る：

Wolfram Language code: Normal[nlm]

1点でモデルを評価する：

Wolfram Language code: nlm[2.3]

フィットされた関数をデータとともに可視化する：

Wolfram Language code: Show[ListPlot[data], Plot[nlm[x], {x, 0, 5}], Frame -> True]

フィットに関する情報を抽出する：

Wolfram Language code: nlm["FitResiduals"]

同じモデルのノイズのあるデータを生成する：

Wolfram Language code: data = Table[{x, Log[2 + 3 x ^ 2] + RandomReal[{0, 0.5}]}, {x, RandomReal[{-10, 10}, 200]}];

データをプロットする：

Wolfram Language code: ListLinePlot[Sort@data]

モデルをフィットする：

Wolfram Language code: m = NonlinearModelFit[data, Log[a + b x ^ 2], {a, b}, x]

フィットを視覚的にチェックする：

Wolfram Language code: Show[ListPlot[data], Plot[m[x], {x, -10, 10}]]

残差を視覚的に検証する：

Wolfram Language code: ListPlot[m["FitResiduals"]]

スコープ  (4)

特性の短い説明を抽出する：

Wolfram Language code: lm = LinearModelFit[Range[10], x ^ 2, x]
Wolfram Language code: lm["ParameterErrors", "Description"]

長めの説明：

Wolfram Language code: lm["ParameterErrors", "LongDescription"]

複数の特性を一度に入手する：

Wolfram Language code: lm = LinearModelFit[Range[10], {x ^ 2, Sin[x]}, x]
Wolfram Language code: lm[{"Response", "PredictedResponse"}]

実際の応答値と予測される応答値をプロットする：

Wolfram Language code: ListPlot[%]

線形フィット用のFittedModelオブジェクトを得る：

Wolfram Language code: LinearModelFit[Table[{i, RandomReal[{i - 1, i}]}, {i, 10}], x ^ 2, x]

非線形フィット用：

Wolfram Language code: NonlinearModelFit[Table[{i, RandomReal[{i - 1, i}]}, {i, 10}], Exp[a x], a, x]

一般化された線形フィット用：

Wolfram Language code: GeneralizedLinearModelFit[Table[{i, 1 / RandomReal[{i - 1, i}]}, {i, 10}], x, x, ExponentialFamily -> "Gamma"]

対数フィット用：

Wolfram Language code: LogitModelFit[Table[{i, RandomReal[{i - 1, i}] / 10}, {i, 10}], x, x]

プロビットフィット用：

Wolfram Language code: ProbitModelFit[Table[{i, RandomReal[{i - 1, i}] / 10}, {i, 10}], x, x]

線形モデルで使用可能な特性のリストを入手する：

Wolfram Language code: lm = LinearModelFit[Range[10], x ^ 2, x]
Wolfram Language code: lm["Properties"]

特性はモデルのタイプによって異なる：

Wolfram Language code: nlm = NonlinearModelFit[Range[10], Exp[a x], a, x]
Wolfram Language code: nlm["Properties"]//Length
Wolfram Language code: glm = GeneralizedLinearModelFit[Range[10], x ^ 2, x]
Wolfram Language code: glm["Properties"]//Length

一般化と拡張  (1)

フィットされたモデルの関数形に他の数学的操作を行う：

Wolfram Language code: nlm = NonlinearModelFit[Exp[Range[10]] + RandomReal[1, 10], Exp[a + b x], {a, b}, x]

記号的および数値的に積分する：

Wolfram Language code: Integrate[nlm[x], x]
Wolfram Language code: NIntegrate[nlm[x], {x, 1, 5}]

モデルの特定の値を与える予測値を求める：

Wolfram Language code: FindRoot[nlm[x] == 10, {x, 1}]
Wolfram Research (2008), FittedModel, Wolfram言語関数， https://reference.wolfram.com/language/ref/FittedModel.html.

テキスト

Wolfram Research (2008), FittedModel, Wolfram言語関数， https://reference.wolfram.com/language/ref/FittedModel.html.

CMS

Wolfram Language. 2008. "FittedModel." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/FittedModel.html.

APA

Wolfram Language. (2008). FittedModel. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/FittedModel.html

BibTeX

@misc{reference.wolfram_2026_fittedmodel, author="Wolfram Research", title="{FittedModel}", year="2008", howpublished="\url{https://reference.wolfram.com/language/ref/FittedModel.html}", note=[Accessed: 16-July-2026]}

BibLaTeX

@online{reference.wolfram_2026_fittedmodel, organization={Wolfram Research}, title={FittedModel}, year={2008}, url={https://reference.wolfram.com/language/ref/FittedModel.html}, note=[Accessed: 16-July-2026]}