FunctionPoles

変数 x を持つ有理型関数 f の極を求める．

x が制約条件 cons で制限されている際の f の極を与える．

詳細とオプション

関数の極は極特異点としても知られている．
関数の極は，複素解析における関数の留数の計算やベキ級数の収束半径の計算にしばしば使われる．
関数は，の形の級数表現を持つのであれば，に多重度の極特異点を持つ．関数が極特異点しか持たないなら，その関数は有理型である．

FunctionPolesは{pole,multiplicity}ペアのリストを返す．
関数 f は制約条件 cons を満足する x について有理型でなければならない．
cons は，等式，不等式，これらの論理結合を含むことができる．
次は，使用可能なオプションである．

Assumptions	$Assumptions	パラメータについての仮定
GeneratedParameters	C	生成されたパラメータの命名方法
PerformanceGoal	$PerformanceGoal	スピードと品質のどちらを優先するか

FunctionPolesが多重度の特定に失敗した場合は，返された極の中に多重度がIndeterminateのものがあるかもしれない．

例題

すべて開くすべて閉じる

例 (2)

有理関数の極を求める：

Wolfram Language code: FunctionPoles[(x ^ 3 - 2) / ((x - 1)(x ^ 2 - 1)), x]

極の集合は無限かもしれない：

Wolfram Language code: FunctionPoles[Tan[x] + 1, x]

スコープ (6)

有理関数：

Wolfram Language code: FunctionPoles[(x ^ 2 - 3) / (x ^ 3 - 2) + x / (x - 1) ^ 3, x]

無限に多くの極がある関数：

Wolfram Language code: FunctionPoles[Gamma[x ^ 2 + 1], x]

のときの極を求める：

Wolfram Language code: FunctionPoles[{Gamma[x ^ 2 + 1], Abs[x] <= 2}, x]

解析関数には極がない：

Wolfram Language code: FunctionPoles[Sin[x ^ 2 + Cosh[x]] + E ^ x, x]

はに加除特異点を持つ：

Wolfram Language code: FunctionPoles[(1 - Cos[x]) / x ^ 2, x]

FunctionPolesの入力関数は有理型でなければならない：

Wolfram Language code: FunctionPoles[Log[x] + 1 / (x - 1), x]

この関数はのとき有理型である：

Wolfram Language code: FunctionPoles[{Log[x] + 1 / (x - 1), Re[x] > 0}, x]

多重度の決定に失敗した場合，返された極の中にはIndeterminateの多重度を持つものがあるかもしれない：

Wolfram Language code: FunctionPoles[Gamma[a x] Gamma[Sqrt[a ^ 2] x], x, Assumptions -> Element[a, Reals]][[1]]

オプション (3)

Assumptions (1)

パラメータについての条件を指定する：

Wolfram Language code: FunctionPoles[{1 / (x - a), Re[x] > 0}, x, Assumptions -> Re[a] > 0]

Wolfram Language code: FunctionPoles[{1 / (x - a), Re[x] > 0}, x, Assumptions -> Re[a] <= 0]

GeneratedParameters (1)

FunctionPolesは，解を表すために新たなパラメータを導入することがある：

Wolfram Language code: FunctionPoles[Tan[x ^ 2], x]

GeneratedParametersを使ってパラメータの命名方法を制御する：

Wolfram Language code: FunctionPoles[Tan[x ^ 2], x, GeneratedParameters -> (Subscript[k, #]&)]

PerformanceGoal (1)

極の多重度の計算には時間がかかるかもしれない：

Wolfram Language code: (p1 = FunctionPoles[Gamma[a x ^ 2 + x + 1], x, Assumptions -> Element[a, Reals]]);//AbsoluteTiming

PerformanceGoal"Speed"とすると多重度の計算にかける時間が制限される：

Wolfram Language code:

(p2 = FunctionPoles[Gamma[a x ^ 2 + x + 1], x, Assumptions -> Element[a, Reals], PerformanceGoal -> "Speed"]);//AbsoluteTiming

どちらの場合も返される極は同じである：

Wolfram Language code: (First /@ p1) === (First /@ p2)

最初の場合は，すべての多重度の計算に成功している：

Wolfram Language code: #[[2]]& /@ p1

2番目の場合は計算されていない多重度もある：

Wolfram Language code: #[[2]]& /@ p2

アプリケーション (3)

有理型関数の特異点を分類する：

Wolfram Language code: f = (E ^ x - 1 - x) / x ^ 2 + Sin[x - 1] / (x ^ 2 - 1) ^ 2;

FunctionSingularitiesは極と加除特異点の場所を与える：

Wolfram Language code: FunctionSingularities[f, x]

はに二重極を，に単一の極を，に加除特異点を持つ：

Wolfram Language code: FunctionPoles[f, x]

単位円に沿って $TemplateBox[{{{x, ^, 3}, -, {x, /, 3}}}, Gamma]$ を積分する：

Wolfram Language code: f = Gamma[x ^ 3 - x / 3];

単位円板上での極を計算する：

Wolfram Language code: pp = FunctionPoles[{f, Abs[x] <= 1}, x]

留数定理を使って積分を計算する：

Wolfram Language code: 2Pi I Total[Residue[f, {x, #[[1]]}]& /@ pp]//RootReduce

数値積分の結果と比較する：

Wolfram Language code: NIntegrate[(f /. x -> Exp[I t])D[Exp[I t], t], {t, 0, 2Pi}] - %//Chop

におけるのテイラー(Taylor)級数の収束半径を求める：

Wolfram Language code: f = Tanh[x];

収束半径は最も近い極までの距離に等しい：

Wolfram Language code: FunctionPoles[{f, Abs[x] < 3}, x]

Wolfram Language code: r = Min[Abs[First[#] - 0]& /@ %]

たとえ極が複素数でも，実数上の収束に影響する：

Wolfram Language code: s = Series[f, {x, 0, 15}]//Normal

Wolfram Language code: Plot[{f, s}, {x, -3, 3}, Rule[...]]

はより極から遠いので，における収束半径の方が大きい：

Wolfram Language code: FunctionPoles[{f, Abs[x - 3] < 5}, x]

Wolfram Language code: r = Min[Abs[First[#] - 3]& /@ %]

Wolfram Language code: s = Series[f, {x, 3, 15}]//Normal;

Wolfram Language code: Plot[{f, s}, {x, -3, 9}, Rule[...]]

特性と関係 (4)

極における関数の絶対値の極限はである：

Wolfram Language code: FunctionPoles[{1 / (E ^ x - 2), Abs[x] < 2}, x]

Limitを使って極限を計算する：

Wolfram Language code: Limit[Abs[1 / (E ^ x - 2)], x -> Log[2]]

多重度の極における関数のベキ級数の最初の項の指数はである：

Wolfram Language code: FunctionPoles[{Tan[x] ^ 3 + x, Abs[x] < 2}, x]

Seriesを使って級数を計算する：

Wolfram Language code: Series[Tan[x] ^ 3 + x, {x, Pi / 2, 1}]

Residueを使って指数がの級数項における係数を求める：

Wolfram Language code: Residue[Tan[x] ^ 3 + x, {x, Pi / 2}]

有理型関数が持ち得る唯一の特異点は極と加除特異点である：

Wolfram Language code: FunctionMeromorphic[Sin[x] / (x ^ 3 - x), x]

FunctionSingularitiesを使ってすべての特異点によって満足される条件を求める：

Wolfram Language code: FunctionSingularities[Sin[x] / (x ^ 3 - x), x]

SolveValuesを使って特異点を求める：

Wolfram Language code: SolveValues[%, x]

この関数はとに極を持ち，に加除特異点を持つ：

Wolfram Language code: FunctionPoles[Sin[x] / (x ^ 3 - x), x]

FunctionPolesを使って関数の極を求める：

Wolfram Language code: FunctionPoles[x ^ 3 / (x ^ 4 - 2), x]

Residueを使って極における留数を求める：

Wolfram Language code: Residue[x ^ 3 / (x ^ 4 - 2), {x, #[[1]]}]& /@ %

ResidueSumはすべての極における留数の和を与える：

Wolfram Language code: ResidueSum[x ^ 3 / (x ^ 4 - 2), x]

考えられる問題 (2)

多重度の判定に失敗した場合は，返された極の中にIndeterminateの多重度を持つものがあるかもしれない：

Wolfram Language code: FunctionPoles[Gamma[a x] Gamma[Sqrt[a ^ 2] x], x, Assumptions -> Element[a, Reals]][[1]]

FunctionPolesは非厳密入力を有理化し，結果を入力精度に近似する：

Wolfram Language code: FunctionPoles[1 / (x - 1) ^ (2. + 10 ^ -13), x]

結果はどの有理数が選ばれたかに依存する：

Wolfram Language code: FunctionPoles[1 / (x - 1) ^ (2. + 10 ^ -12), x]

最初の例では有理化された指数は整数だが2番目の例はそうではない：

Wolfram Language code: Rationalize[Rationalize[#], 0]& /@ {2. + 10 ^ -13, 2. + 10 ^ -12}

Top

その他のラーニングリソース

テクニカルサポート

データサイエンス，金融，ビジネス

工学

科学とテクノロジー

教育のためのテクノロジー

教育イニシアチブ

使い始める

Grow Your Skills

Wolframと繋がる

大人用の教育プログラム

若者のための教育プログラム

読む

FunctionPoles

詳細とオプション

例題

例 (2)

スコープ (6)