WOLFRAM

Wolfram 语言与系统参考资料中心

FunctionSurjective[f,x]

测试对于每一个 y∈Reals， 是否至少有一个解 x in TemplateBox[{}, Reals].

FunctionSurjective[f,x,dom]

测试对于每一个 y∈dom， 是否至少有一个解 x∈dom.

FunctionSurjective[{f1,f2,…},{x1,x2,…},dom]

测试对于每一个 y1,y2,…∈dom， 是否至少有一个解 x1,x2,…∈dom.

FunctionSurjective[{funs,xcons,ycons},xvars,yvars,dom]

测试对于每一个受约束条件 ycons 限制的 yvars∈dom， 是否至少有一个受约束条件 xcons 限制的解 xvars∈dom.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
选项  
Assumptions  
GenerateConditions  
PerformanceGoal  
应用  
基本应用  
解方程与不等式  
概率与统计  
属性和关系  
可能存在的问题  
参见
相关指南
历史
按以下格式引用：

FunctionSurjective

FunctionSurjective[f,x]

测试对于每一个 y∈Reals， 是否至少有一个解 x in TemplateBox[{}, Reals].

FunctionSurjective[f,x,dom]

测试对于每一个 y∈dom， 是否至少有一个解 x∈dom.

FunctionSurjective[{f1,f2,…},{x1,x2,…},dom]

测试对于每一个 y1,y2,…∈dom， 是否至少有一个解 x1,x2,…∈dom.

FunctionSurjective[{funs,xcons,ycons},xvars,yvars,dom]

测试对于每一个受约束条件 ycons 限制的 yvars∈dom， 是否至少有一个受约束条件 xcons 限制的解 xvars∈dom.

更多信息和选项

  • 满射函数亦称为 onto 或 onto 映射.
  • 如果对于每个 ，至少存在一个 ，使得 ，则函数 是满射的.
  • 如果 funs 含有除 xvars 之外的参数，则结果通常为 ConditionalExpression.
  • dom 的可能的值为 Reals 和 Complexes. 如果 dom 是 Reals，则所有变量、参数、常数和函数值都必须为实数.
  • funs 的定义域受 FunctionDomain 给定的条件限制.
  • xcons 和 ycons 可含有等式、不等式或它们的逻辑组合.
  • 如果映射 是满射，则 FunctionSurjective[{funs,xcons,ycons},xvars,yvars,dom] 返回 True，其中 是 xcons 的解集， 是 ycons 的解集.
  • 可给出以下选项：
  • Assumptions $Assumptions对参数的设定
    GenerateConditions True是否生成关于参数的条件
    PerformanceGoal $PerformanceGoal优先考虑速度还是质量
  • GenerateConditions 的可能的设置包括：
  • Automatic只给出非通用条件
    True给出所有条件
    False不给出条件
    None如果需要条件则不经计算直接返回
  • PerformanceGoal 的可能设置为 "Speed" 和 "Quality".

范例

打开所有单元 关闭所有单元

基本范例  (4)

在实数上测试单变量函数的满射性：

Wolfram Language code: FunctionSurjective[Tan[x], x]

在复数上测试满射性：

Wolfram Language code: FunctionSurjective[Tan[x], x, Complexes]

在实数上测试多项式映射的满射性：

Wolfram Language code: FunctionSurjective[{x + y ^ 3, y - x ^ 5}, {x, y}]

测试含有符号系数的多项式的满射性：

Wolfram Language code: FunctionSurjective[a x ^ 2 + b x y + c y ^ 2, {x, y}]

范围  (12)

实数上的满射性：

Wolfram Language code: FunctionSurjective[x ^ 3 - x, x]

每个值至少被取了一次：

Wolfram Language code: Plot[{x ^ 3 - x, 1 / 4}, {x, -2, 2}]

实数子集上的满射性：

Wolfram Language code: FunctionSurjective[{x ^ 3 - x, x > 0}, x]

对于正的 ，有些值没有被取到：

Wolfram Language code: Plot[{x ^ 3 - x, -1}, {x, 0, 2}]

到实数子集上的满射性：

Wolfram Language code: FunctionSurjective[{x ^ 3 - x, x > 0, y > 0}, x, y]

每个正的 对应于某些正的 ：

Wolfram Language code: Plot[{x ^ 3 - x, 1}, {x, 0, 2}]

复数上的满射性：

Wolfram Language code: FunctionSurjective[E ^ x, x, Complexes]

没有取零值：

Wolfram Language code: Reduce[E ^ x == 0, x]

复数子集上的满射性：

Wolfram Language code: FunctionSurjective[{E ^ x, True, y ≠ 0}, x, y, Complexes]

整数上的满射性：

Wolfram Language code: FunctionSurjective[{x / 2 + 1, Element[x, Integers], Element[y, Integers]}, x, y]

线性映射的满射性：

Wolfram Language code: A = {{1, 2, 3}, {4, 5, 6}, {7, 8, 9}};
Wolfram Language code: FunctionSurjective[A.{x, y, z}, {x, y, z}]
Wolfram Language code: B = {{1, 2, 3}, {4, 5, 6}, {7, 8, 0}};
Wolfram Language code: FunctionSurjective[B.{x, y, z}, {x, y, z}]

当且仅当线性映射的矩阵的秩等于其陪域的维数，线性映射才是满射的：

Wolfram Language code: {MatrixRank[A], MatrixRank[B]}

多项式映射 的满射性：

Wolfram Language code: FunctionSurjective[x ^ 2 + x y - y ^ 2, {x, y}]

每个值至少被取了一次：

Wolfram Language code: Plot3D[{x ^ 2 + x y - y ^ 2, -1}, {x, -3, 3}, {y, -3, 3}]

下面的映射不是满射的：

Wolfram Language code: FunctionSurjective[x ^ 2 + x y + y ^ 2, {x, y}]

有些值没有被取到：

Wolfram Language code: Plot3D[{x ^ 2 + x y + y ^ 2, -1}, {x, -3, 3}, {y, -3, 3}]

多项式映射 的满射性：

Wolfram Language code: FunctionSurjective[{x + y ^ 2, y - x ^ 2}, {x, y}]

多项式映射 的满射性：

Wolfram Language code: FunctionSurjective[{x + y ^ 2, y - x ^ 2}, {x, y}, Complexes]

含有符号参数的实多项式的满射性：

Wolfram Language code: FunctionSurjective[a x ^ 2 + b x + c, x]

含有符号参数的实多项式映射的满射性：

Wolfram Language code: FunctionSurjective[{x ^ 2 + 2 x y, y ^ 2 + a x y}, {x, y}]

选项  (4)

Assumptions  (1)

此处，FunctionSurjective 给出有条件的答案：

Wolfram Language code: FunctionSurjective[{x ^ 2 + 2 x y, y ^ 2 + a x y}, {x, y}]

下面检查 取其他实值时的满射性：

Wolfram Language code: FunctionSurjective[{x ^ 2 + 2 x y, y ^ 2 + a x y}, {x, y}, Assumptions -> a ≤ 1 / 2]

GenerateConditions  (2)

默认情况下，FunctionSurjective 可能会对符号参数生成条件：

Wolfram Language code: FunctionSurjective[a x ^ 2 + b x y + c y ^ 2, {x, y}]

如果设置 GenerateConditionsNone，FunctionSurjective 会失败，而不是给出有条件的结果：

Wolfram Language code: FunctionSurjective[a x ^ 2 + b x y + c y ^ 2, {x, y}, GenerateConditions -> None]

下面返回有条件的有效结果，但没有给出条件：

Wolfram Language code: FunctionSurjective[a x ^ 2 + b x y + c y ^ 2, {x, y}, GenerateConditions -> False]

默认情况下，报告所有的条件：

Wolfram Language code: FunctionSurjective[a x ^ 2 + b x + c, x]

如果设置 GenerateConditionsAutomatic，不报告通常为真的条件：

Wolfram Language code: FunctionSurjective[a x ^ 2 + b x + c, x, GenerateConditions -> Automatic]

PerformanceGoal  (1)

用 PerformanceGoal 避免潜在费时的计算：

Wolfram Language code: FunctionSurjective[x ^ 2 + y ^ 2 + a x y, {x, y}, PerformanceGoal -> "Speed"]

默认设置则尝试利用所有可用的技术来给出结果：

Wolfram Language code: FunctionSurjective[x ^ 2 + y ^ 2 + a x y, {x, y}]

应用  (11)

基本应用  (7)

查看 的满射性：

Wolfram Language code: FunctionSurjective[Log[x ^ 2], x]

是满射的，因为每个值至少被取了一次：

Wolfram Language code: Plot[{Log[x ^ 2], -1, 1}, {x, -3, 3}]

查看 的满射性：

Wolfram Language code: FunctionSurjective[Csch[x], x]

不是满射的，因为没有取过 值：

Wolfram Language code: Plot[{Csch[x], 0}, {x, -2, 2}]

不是满射的，因为没有取过负值：

Wolfram Language code: FunctionSurjective[Sqrt[x], x]

没有取过 ：

Wolfram Language code: Plot[{Sqrt[x], -1}, {x, -2, 2}]

是从 TemplateBox[{}, NonNegativeReals] 到 TemplateBox[{}, NonNegativeReals] 的满射函数：

Wolfram Language code: FunctionSurjective[{Sqrt[x], x ≥ 0, y ≥ 0}, x, y]

每个非负值都被取过：

Wolfram Language code: Plot[{Sqrt[x], 1}, {x, 0, 4}, PlotRange -> All]

是满射的：

Wolfram Language code: FunctionSurjective[CatalanNumber[x], x]

每个值至少被取了一次：

Wolfram Language code: Plot[{CatalanNumber[x], -1, 1 / 2, 2}, {x, -2.5, 2.5}]

TemplateBox[{x}, CosIntegral] 不是满射的：

Wolfram Language code: FunctionSurjective[CosIntegral[x], x]

有些值（如 ）没有被取过：

Wolfram Language code: Plot[{CosIntegral[x], 3 / 4}, {x, -1, 10}]

如果任何一条水平线与曲线至少相交一次，则该函数是满射的：

Wolfram Language code: FunctionSurjective[RiemannSiegelTheta[x], x]
Wolfram Language code: Manipulate[Plot[{RiemannSiegelTheta[x], a}, ...], {{a, 2}, -5, 5}]

如果水平线不与曲线相交，则该函数是不满射的：

Wolfram Language code: FunctionSurjective[FresnelS[x], x]
Wolfram Language code: Manipulate[Plot[{FresnelS[x], a}, ...], {{a, 0.8}, -1, 1}]

有界：

Wolfram Language code: MaxValue[Abs[Sin[x]], x]

有界函数不是满射的：

Wolfram Language code: FunctionSurjective[Sin[x], x]

如果 在 上连续，且 ，则 是到 的满射函数：

Wolfram Language code: f[x_] := x ^ 4 - 2x ^ 2 + x / 2 + 1
Wolfram Language code: f[-3 / 2] < f[3 / 2]

用 FunctionContinuous 查看 是否在 上连续：

Wolfram Language code: FunctionContinuous[{f[x], -3 / 2 ≤ x ≤ 3 / 2}, x]

根据中值定理，被限制于 的 是到 的满射函数：

Wolfram Language code: FunctionSurjective[{f[x], -3 / 2 ≤ x ≤ 3 / 2, f[-3 / 2] ≤ y ≤ f[3 / 2]}, x, y]
Wolfram Language code: Plot[{f[x], f[-3 / 2], f[3 / 2]}, {x, -3 / 2, 3 / 2}, Rule[...]]

如果 的秩等于 的行数，则仿射映射 是满射的：

Wolfram Language code: Subscript[A, 1] = {{1, 2, 3}, {4, 5, 6}};
Wolfram Language code: MatrixRank[Subscript[A, 1]]
Wolfram Language code: FunctionSurjective[Subscript[A, 1].{x, y, z} + {7, 8}, {x, y, z}]
Wolfram Language code: Subscript[A, 2] = {{1, 2, 3}, {2, 4, 6}};
Wolfram Language code: MatrixRank[Subscript[A, 2]]
Wolfram Language code: FunctionSurjective[Subscript[A, 2].{x, y, z} + {7, 8}, {x, y, z}]

解方程与不等式  (1)

如果对于任意 值，方程 至少有一个解，则函数 是满射的：

Wolfram Language code: f[x_] := x / (x ^ 2 - 1)
Wolfram Language code: FunctionSurjective[f[x], x]

对于每个实的 值，至少有一个 实数解：

Wolfram Language code: Reduce[f[x] == y, x, Reals]

用 Resolve 查看用 quantifier 表示的条件：

Wolfram Language code: Resolve[ForAll[y, Exists[x, f[x] == y]], Reals]
Wolfram Language code: Plot[f[x], {x, -3, 3}]

概率与统计  (3)

在定义域上，连续分布的 CDF 是到概率区间 (0,1) 的满射函数：

Wolfram Language code: cdf = CDF[NormalDistribution[0, 1], x]
Wolfram Language code: Plot[cdf, {x, -3, 3}]
Wolfram Language code: FunctionSurjective[{cdf, True, 0 < y < 1}, x, y]

在定义域上，连续分布的 SurvivalFunction 是到概率区间 (0,1) 的满射函数：

Wolfram Language code: sf = SurvivalFunction[NormalDistribution[0, 1], x]
Wolfram Language code: Plot[sf, {x, -3, 3}]
Wolfram Language code: FunctionSurjective[{sf, True, 0 < y < 1}, x, y]

一个分布的分位数函数 Quantile 是到分布的域上的满射函数：

Wolfram Language code: qf = Quantile[NormalDistribution[0, 1], q]
Wolfram Language code: Plot[qf, {q, 0, 1}]
Wolfram Language code: FunctionSurjective[{qf, 0 < q < 1}, q]

属性和关系  (3)

当且仅当方程 对于每个 至少有一个解， 才是满射的：

Wolfram Language code: FunctionSurjective[x ^ 2 + x + 1, x]
Wolfram Language code: FunctionSurjective[x ^ 3 + x + 1, x]

用 Solve 求出解：

Wolfram Language code: Solve[x ^ 2 + x + 1 == y, x, Reals]
Wolfram Language code: Solve[x ^ 3 + x + 1 == y, x, Reals]

一个在区间上连续的实函数是满射的，当且仅当它在端点处的极限是 和 ：

Wolfram Language code: FunctionSurjective[{Sec[x], -Pi / 2 < x < Pi / 2}, x]
Wolfram Language code: FunctionSurjective[{Tan[x], -Pi / 2 < x < Pi / 2}, x]
Wolfram Language code: Plot[{Sec[x], Tan[x]}, {x, -Pi / 2, Pi / 2}]

用 Limit 计算极限：

Wolfram Language code: Limit[{Sec[x], Tan[x]}, x -> -Pi / 2, Direction -> "FromAbove"]
Wolfram Language code: Limit[{Sec[x], Tan[x]}, x -> Pi / 2, Direction -> "FromBelow"]

如果函数的 FunctionRange 为 True 则函数是满射的：

Wolfram Language code: FunctionRange[x Sin[x], x, y]
Wolfram Language code: FunctionSurjective[x Sin[x], x]

可能存在的问题  (1)

FunctionSurjective 用 FunctionDomain 确定函数的实定义域：

Wolfram Language code: FunctionSurjective[{Cosh[Sqrt[x]], True, y ≥ 0}, x, y]

在 FunctionDomain 给出的实定义域上， 不是到 的满射函数：

Wolfram Language code: FunctionDomain[Cosh[Sqrt[x]], x]
Wolfram Language code: Plot[{Cosh[Sqrt[x]], 1 / 2}, {x, 0, 10}]

在所有实数上是实值函数，是到 的满射函数：

Wolfram Language code: Plot[{Cosh[Sqrt[x]], 1 / 2}, {x, -10, 10}]

的所有子表达式需为实值，该点才属于 的实定义域：

Wolfram Language code: Refine[Element[Sqrt[x], Reals], x < 0]
Wolfram Research (2020)，FunctionSurjective，Wolfram 语言函数，https://reference.wolfram.com/language/ref/FunctionSurjective.html.

文本

Wolfram Research (2020)，FunctionSurjective，Wolfram 语言函数，https://reference.wolfram.com/language/ref/FunctionSurjective.html.

CMS

Wolfram 语言. 2020. "FunctionSurjective." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/FunctionSurjective.html.

APA

Wolfram 语言. (2020). FunctionSurjective. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/FunctionSurjective.html 年

BibTeX

@misc{reference.wolfram_2026_functionsurjective, author="Wolfram Research", title="{FunctionSurjective}", year="2020", howpublished="\url{https://reference.wolfram.com/language/ref/FunctionSurjective.html}", note=[Accessed: 18-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_functionsurjective, organization={Wolfram Research}, title={FunctionSurjective}, year={2020}, url={https://reference.wolfram.com/language/ref/FunctionSurjective.html}, note=[Accessed: 18-June-2026]}