WOLFRAM

Wolfram 语言与系统参考资料中心

GatherBy[list,f]

当应用 f，将 list 中每个集合中给出相同值的元素收集到子列表中.

GatherBy[list,{f1,f2,…}]

在层 i 应用 fi 后，将 list 收集到嵌套列表中.

更多信息
Details and Options Details and Options
范例  
基本范例  
应用  
属性和关系  
参见
相关指南
相关链接
历史
按以下格式引用：

GatherBy

GatherBy[list,f]

当应用 f，将 list 中每个集合中给出相同值的元素收集到子列表中.

GatherBy[list,{f1,f2,…}]

在层 i 应用 fi 后，将 list 收集到嵌套列表中.

更多信息

  • GatherBy[{e1,e2,e3,…},f] 计算 f[ei] ，对于每个 i 确定如何收集 ei.
  • GatherBy[list,…] 按照 list 中元素的顺序给出结果.
  • 在 GatherBy[list,…] 生成的每个子列表中， 元素的顺序和 list 中相同；对完整的子列表排序，这样第一个元素出现的顺序和 list 相同.
  • GatherBy 实际上产生一个等价的划分.
  • GatherBy[list,{f1,f2}] 等价于 Map[GatherBy[#,f2]&,GatherBy[list,f1]].

范例

打开所有单元 关闭所有单元

基本范例  (2)

按奇数和偶数收集数据：

Wolfram Language code: GatherBy[{1, 2, 3, 4, 5}, OddQ]

按第一个部分收集：

Wolfram Language code: GatherBy[{{a, 1}, {b, 1}, {a, 2}, {d, 1}, {b, 3}}, First]

应用  (6)

排序，然后按第一个字母收集字符串：

Wolfram Language code: words = RandomChoice[WordData[], {1000}];
Wolfram Language code: f = StringTake[#, {1}]&;
Wolfram Language code: GatherBy[SortBy[words, f], f]//Short

按第一个元素收集，子列表中按最后一个元素收集：

Wolfram Language code: Tuples[{{a, b}, {1, 2}, {x, y}}]
Wolfram Language code: GatherBy[%, {First, Last}]

用 Framed 显示分组：

Wolfram Language code: Map[Framed, %, {1, 2}]

按余数收集：

Wolfram Language code: GatherBy[Range[10], Mod[#, 3]&]

按向量中的第一个元素收集：

Wolfram Language code: Transpose@{RandomChoice[{a, b}, 5], RandomInteger[10, 5]}
Wolfram Language code: GatherBy[%, First]

按年收集日期：

Wolfram Language code: Flatten@Table[DateString[{y, m}, {"Month", "/", "YearShort"}], {y, RandomChoice[Range[2000, 2010], 5]}, {m, RandomChoice[Range[12], 3]}]
Wolfram Language code: GatherBy[%, DateList[{#, {"Month", "/", "YearShort"}}][[1]]&]

模拟某些数据：

Wolfram Language code: data = Transpose[{RandomReal[5, 10], RandomChoice[{a, b, c}, 10], RandomReal[10, 10]}]

基于第二个元素的组元素：

Wolfram Language code: gathered = GatherBy[data, #[[2]]&]

统计每列的数据点的数量：

Wolfram Language code: Map[{#[[1, 2]], Length[#[[All, -1]]]}&, gathered]

按组计算第三个元素的均值：

Wolfram Language code: Map[{#[[1, 2]], Mean[#[[All, -1]]]}&, gathered]

对于机器数，按照基于舍入的最后的 tol 数位的等价类分组：

Wolfram Language code: tol = 7; f[x_] := Module[{re = Round[RealExponent[x, 2]], e}, e = (53 - tol - re); m = 2 ^ e; N[Round[x m] / m]];

产生接近 1 的不同机器数的无序样本：

Wolfram Language code: ϵ = $MachineEpsilon; r = RandomSample[Table[1 + k ϵ, {k, 100}]]

按等价类收集：

Wolfram Language code: g = GatherBy[r, f]

查看 中因子 的分组：

Wolfram Language code: Round[(g - 1) / ϵ]

这里是等价表示 和值 ，以满足 ：

Wolfram Language code: Table[{InputForm[r = f[x]], (r - 1) / ϵ}, {x, g[[All, 1]]}]

属性和关系  (1)

GatherBy[list,f] 等价于 Gather[list,(f[#1]===f[#2])&]：

Wolfram Language code: MatrixForm[m = RandomInteger[1, {10, 10}]]

按 Norm 收集行，按每个组的普通规范显示：

Wolfram Language code: Grid[Map[{MatrixForm[#], Norm[First[#]]}&, gb = GatherBy[m, Norm]]]

和 Gather 的结果比较：

Wolfram Language code: Gather[m, (Norm[#1] === Norm[#2])&] === gb
Wolfram Research (2008)，GatherBy，Wolfram 语言函数，https://reference.wolfram.com/language/ref/GatherBy.html.

文本

Wolfram Research (2008)，GatherBy，Wolfram 语言函数，https://reference.wolfram.com/language/ref/GatherBy.html.

CMS

Wolfram 语言. 2008. "GatherBy." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/GatherBy.html.

APA

Wolfram 语言. (2008). GatherBy. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/GatherBy.html 年

BibTeX

@misc{reference.wolfram_2026_gatherby, author="Wolfram Research", title="{GatherBy}", year="2008", howpublished="\url{https://reference.wolfram.com/language/ref/GatherBy.html}", note=[Accessed: 03-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_gatherby, organization={Wolfram Research}, title={GatherBy}, year={2008}, url={https://reference.wolfram.com/language/ref/GatherBy.html}, note=[Accessed: 03-November-2026]}