WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

GeoGridUnitArea[proj,loc]

位置 loc の周囲の小さい地理領域の境界で評価された，投影法 proj で入手された地理格子上の単位面積に対応する実際の地理面積を与える．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
オプション  
GeoModel  
UnitSystem  
アプリケーション  
特性と関係  
考えられる問題  
関連項目
テクニカルノート
関連するガイド
履歴
引用書式

GeoGridUnitArea

GeoGridUnitArea[proj,loc]

位置 loc の周囲の小さい地理領域の境界で評価された，投影法 proj で入手された地理格子上の単位面積に対応する実際の地理面積を与える．

詳細とオプション

  • GeoGridUnitAreaは，与えられた場所の周りの地理投影による局所的な面積の歪みを説明する．
  • GeoGridUnitAreaは，大域的名義スケール（地理モデルと地図の基準モデルの縮小係数，伝統的に1:125000およびこれに類似したもの）と地理投影から導かれる面積の局所的歪みを組み合せる．
  • GeoGridUnitArea[…]の結果は，（地球あるいはその他の天体の）地理モデル上の地理領域のQuantityと投影された地理格子の無次元領域の比に対応する．
  • 地理投影は，デフォルトのパラメータを持った名前付きの投影法"proj"として，あるいは{"proj",params}として与えることができる．ただし，"proj"はGeoProjectionDataの任意の実体，params は"StandardParallels"->{33,60}のようなパラメータの規則である．GeoProjectionData["proj"]は，投影法"proj"のパラメータのデフォルト値を与える．
  • 位置 loc は，度を単位とした座標のペア{lat,lon}，GeoPosition[…]あるいはGeoGridPosition[…]のような地理位置オブジェクト，あるいは地理実体Entity[…]として与えることができる．
  • GeoGridUnitAreaはその位置と方向の引数に縫い込まれる．
  • 次は，GeoGridUnitAreaの使用可能なオプションである．
  • GeoModel Automatic地球あるいは天体のモデル
    UnitSystem $UnitSystem結果に使う単位系

例題

すべて開く すべて閉じる

例  (1)

エッフェル塔の位置におけるメルカトル図法による地理格子の単位面積を計算する：

Wolfram Language code: scale = GeoGridUnitArea["Mercator", Entity["Building", "EiffelTower::5h9w8"]]

投影座標における辺の長さが0.01の小さい正方形の面積は以下のようになる：

Wolfram Language code: 0.01 ^ 2scale

正方形を描く：

Wolfram Language code: xy = GeoGridPosition[Entity["Building", "EiffelTower::5h9w8"], "Mercator"]["GridXY"]
Wolfram Language code: GeoGraphics[{Opacity[0.2], Rectangle[xy - {0.005, 0.005}, xy + {0.005, 0.005}]}, GeoProjection -> "Mercator", Frame -> True, PlotRangePadding -> 0.003]

スコープ  (5)

"VanDerGrinten"投影法によるユーザの地理位置の地理格子の単位面積を計算する：

Wolfram Language code: GeoGridUnitArea["VanDerGrinten", Here]

次は"VanDerGrinten"投影法のパラメータのデフォルト値である：

Wolfram Language code: GeoProjectionData["VanDerGrinten"]

投影法のパラメータについて他の値を指定する：

Wolfram Language code: GeoGridUnitArea[{"VanDerGrinten", "ReferenceModel" -> 1000}, Here]
Wolfram Language code: GeoGridUnitArea[{"VanDerGrinten", "Centering" -> {-40, 150}}, Here]

{lat,lon}の度を単位とするペアを使って位置を指定する：

Wolfram Language code: GeoGridUnitArea["Orthographic", {-80.5, 30.32}]

地理位置の頭部を持つ位置を使う：

Wolfram Language code: GeoGridUnitArea["Orthographic", GeoPosition[{-80.5, 30.32}]]
Wolfram Language code: GeoGridUnitArea["Orthographic", GeoPositionXYZ[{911681, 533170, -6268998}]]
Wolfram Language code: GeoGridUnitArea["Orthographic", GeoGridPosition[{0.714285, -0.753047}, "Albers"]]

地理Entityオブジェクトを使って位置を指定する：

Wolfram Language code: GeoGridUnitArea["Albers", Entity["City", {"Toronto", "Ontario", "Canada"}]]

位置のリストについて，地理格子単位面積を計算する：

Wolfram Language code: GeoGridUnitArea["Mollweide", {GeoPosition[{10, 40}], GeoGridPosition[{-30.3, 20}, "Mercator"], {85, 178}}]

QuantityArray出力を正規形に変換する：

Wolfram Language code: %//Normal

GeoGridUnitAreaは，多数の場所についての値を有効に処理する：

Wolfram Language code: locs = RandomGeoPosition["World", 10 ^ 6];
Wolfram Language code: GeoGridUnitArea["Mollweide", locs]//AbsoluteTiming

オプション  (2)

GeoModel  (1)

デフォルトで，GeoGridUnitAreaは地球についての値を返す：

Wolfram Language code: GeoGridUnitArea["Bonne", {50, -100}]

月の対応する点について同じ計算を行うと，より小さいスケールが返される：

Wolfram Language code: GeoGridUnitArea["Bonne", {50, -100}, GeoModel -> "Moon"]

特定の半径の球モデルを選ぶ：

Wolfram Language code: GeoGridUnitArea["Bonne", {50, -100}, GeoModel -> Quantity[2000, "Kilometers"]]

UnitSystem  (1)

距離スケールを返すのに使われる単位系を選択する：

Wolfram Language code: GeoGridUnitArea["Wiechel", GeoPosition[{10, 120}], UnitSystem -> "Metric"]
Wolfram Language code: GeoGridUnitArea["Wiechel", GeoPosition[{10, 120}], UnitSystem -> "Imperial"]

値は等しいが単位は異なる：

Wolfram Language code: % == %%

アプリケーション  (3)

円筒図法では，投影される単位面積は緯度のみに依存する：

Wolfram Language code: Plot3D[GeoGridUnitArea["Mercator", {lat, lon}], {lat, -89, 89}, {lon, -180, 180}]

GeoGridUnitAreaを使って，地図上に投影された狭い領域の地理領域を近似する：

Wolfram Language code: geopol = EntityValue[Entity["City", {"SanFrancisco", "California", "UnitedStates"}], "Polygon"]

アルベルス図法を使って投影し，平らな地図の面積を計算する：

Wolfram Language code: pol = GeoGridPosition[geopol, "Albers"]
Wolfram Language code: Area[pol /. GeoGridPosition[expr_, proj_] :> expr]

領域の中心的な位置における地理格子の単位面積を結果に掛ける：

Wolfram Language code: % GeoGridUnitArea["Albers", Entity["City", {"SanFrancisco", "California", "UnitedStates"}]]

地理領域の正しい値と比較する：

Wolfram Language code: geopol//GeoArea

投影された地図上に定義された領域の地理面積を計算する：

Wolfram Language code: GeoGraphics[{Opacity[0.5], Disk[{0, 0}, 1]}, GeoRange -> "World", GeoProjection -> "ConicEquidistant", Frame -> True, Axes -> True]
Wolfram Language code: area[x_Real, y_Real] := QuantityMagnitude[GeoGridUnitArea["ConicEquidistant", GeoGridPosition[{x, y}, "ConicEquidistant"], GeoModel -> "ITRF00"], "Kilometers" ^ 2];
Wolfram Language code: Quantity[NIntegrate[area[x, y], {x, y}∈Disk[{0, 0}, 1]], "Kilometers" ^ 2]

円板の多角形近似に基づいた計算と比較する：

Wolfram Language code: GeoGridPosition[N@CirclePoints[10000], "ConicEquidistant"]
Wolfram Language code: GeoArea[Polygon[GeoPosition[%]], UnitSystem -> "Metric"]

特性と関係  (3)

場所と投影法を取る：

Wolfram Language code: loc = Entity["Lake", "LakeVictoria::b8795"];
Wolfram Language code: proj = "WagnerI";

ある位置に収束する，投影された徐々に小さくなる正方形族を構築する：

Wolfram Language code: {x, y} = GeoGridPosition[loc, proj]["GridXY"]
Wolfram Language code: square[s_] := Polygon[{{x - s, y + s}, {x + s, y + s}, {x + s, y - s}, {x - s, y - s}}]
Wolfram Language code: squares = square /@ PowerRange[1, 1 / 2000, 1 / 2];
Wolfram Language code: GeoGraphics[{EdgeForm[Black], FaceForm[], squares}, GeoRange -> "World", GeoProjection -> proj, Frame -> True]

これらの正方形について，投影されていない面積と投影された面積の比を計算する：

Wolfram Language code: ratio[pol_] := GeoArea[GeoPosition[GeoGridPosition[#, proj]& /@ pol]] / Area[pol]
Wolfram Language code: ratio /@ squares

これらの値は，その位置における投影についてのGeoGridUnitAreaで与えられた値に収束する：

Wolfram Language code: GeoGridUnitArea[proj, loc, GeoModel -> "ITRF00"]

投影された単位面積は地理モデルサイズの正方形によって異なる：

Wolfram Language code: proj = GeoProjectionData["Mollweide"]
Wolfram Language code: GeoGridUnitArea["Mollweide", GeoPosition[{10, 20}], GeoModel -> #]& /@ Quantity[{10, 100, 1000}, "Kilometers"]

投影された単位面積は基準モデルの逆二乗または中心スケール因子につれて変化する：

Wolfram Language code: GeoGridUnitArea[{"Mollweide", "ReferenceModel" -> #}, GeoPosition[{10, 20}]]& /@ {10, 100, 1000}
Wolfram Language code: GeoGridUnitArea[{"Mollweide", "CentralScaleFactor" -> #}, GeoPosition[{10, 20}]]& /@ {10, 100, 1000}

等面積図法は地球上に一定の地理格子単位面積を持つ：

Wolfram Language code: equalarea = GeoProjectionData["EqualArea"]

世界中のランダムな位置の集合について，投影された単位面積区分の幅が0であることを確かめる：

Wolfram Language code: points = RandomGeoPosition["World", 1000];
Wolfram Language code: MinMax /@ QuantityMagnitude[GeoGridUnitArea[{#, "ReferenceModel" -> 1}, points, GeoModel -> Quantity[1, "Meters"]]& /@ equalarea, "Meters" ^ 2]

考えられる問題  (1)

地理位置が投影できなければ，その位置についての投影された単位面積も計算できない：

Wolfram Language code: GeoGridPosition[GeoPosition[{20, 120}], "Orthographic"]
Wolfram Language code: GeoGridUnitArea["Orthographic", GeoPosition[{20, 120}]]

この位置は，デフォルトの中心を使った"Orthographic"図法による地球の半分には含まれない：

Wolfram Language code: GeoGraphics[GeoRange -> "World", GeoProjection -> "Orthographic", GeoGridLines -> Automatic]
Wolfram Research (2019), GeoGridUnitArea, Wolfram言語関数， https://reference.wolfram.com/language/ref/GeoGridUnitArea.html.

テキスト

Wolfram Research (2019), GeoGridUnitArea, Wolfram言語関数， https://reference.wolfram.com/language/ref/GeoGridUnitArea.html.

CMS

Wolfram Language. 2019. "GeoGridUnitArea." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/GeoGridUnitArea.html.

APA

Wolfram Language. (2019). GeoGridUnitArea. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/GeoGridUnitArea.html

BibTeX

@misc{reference.wolfram_2026_geogridunitarea, author="Wolfram Research", title="{GeoGridUnitArea}", year="2019", howpublished="\url{https://reference.wolfram.com/language/ref/GeoGridUnitArea.html}", note=[Accessed: 09-July-2026]}

BibLaTeX

@online{reference.wolfram_2026_geogridunitarea, organization={Wolfram Research}, title={GeoGridUnitArea}, year={2019}, url={https://reference.wolfram.com/language/ref/GeoGridUnitArea.html}, note=[Accessed: 09-July-2026]}