WOLFRAM

Wolfram 语言与系统参考资料中心

GeoGridUnitArea[proj,loc]

给出与通过投影 proj 获得的地理网格上的单位面积相对应的实际地理面积，在位置 loc 周围的小地理区域范围内进行计算.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
选项  
GeoModel  
UnitSystem  
应用  
属性和关系  
可能存在的问题  
参见
技术笔记
相关指南
历史
按以下格式引用：

GeoGridUnitArea

GeoGridUnitArea[proj,loc]

给出与通过投影 proj 获得的地理网格上的单位面积相对应的实际地理面积，在位置 loc 周围的小地理区域范围内进行计算.

更多信息和选项

  • GeoGridUnitArea 描述了由给定位置周围的地理投影引起的区域局部变形.
  • GeoGridUnitArea 将全球名义比例尺（地理模型相对于地图参考模型的缩小因子，传统上用 1：125000 及类似值表示）和地理投影引起的区域局部变形相结合.
  • GeoGridUnitArea[…] 的结果对应于（地球或其他天体的）地理模型上 Quantity 地理面积与投影地理网格的无单位面积的比.
  • 可用具有默认参数的已命名投影 "proj" 或 {"proj",params} 给出地理投影，其中 "proj" 为 GeoProjectionData 的任一实体，params 为参数规则，如 "StandardParallels"->{33,60}. GeoProjectionData["proj"] 给出投影 "proj" 的默认参数值.
  • 可用单位为度的坐标对 {lat,lon}、如 GeoPosition[…] 的地理位置对象、 GeoGridPosition[…] 或地理实体Entity[…] 给出位置 loc.
  • GeoGridUnitArea 逐项作用于位置和方向参数.
  • GeoGridUnitArea 的可能的选项包括：
  • GeoModel Automatic地球模型或天体
    UnitSystem $UnitSystem结果中使用的单位系统

范例

打开所有单元 关闭所有单元

基本范例  (1)

计算埃菲尔铁塔所在位置处的墨卡托投影的地理网格单位面积：

Wolfram Language code: scale = GeoGridUnitArea["Mercator", Entity["Building", "EiffelTower::5h9w8"]]

投影坐标中边长为 0.01 的小正方形的面积为：

Wolfram Language code: 0.01 ^ 2scale

绘制正方形：

Wolfram Language code: xy = GeoGridPosition[Entity["Building", "EiffelTower::5h9w8"], "Mercator"]["GridXY"]
Wolfram Language code: GeoGraphics[{Opacity[0.2], Rectangle[xy - {0.005, 0.005}, xy + {0.005, 0.005}]}, GeoProjection -> "Mercator", Frame -> True, PlotRangePadding -> 0.003]

范围  (5)

计算你所在位置处 "VanDerGrinten" 投影的地理网格单位面积：

Wolfram Language code: GeoGridUnitArea["VanDerGrinten", Here]

下面是 "VanDerGrinten" 投影参数的默认值：

Wolfram Language code: GeoProjectionData["VanDerGrinten"]

为投影参数指定其他值：

Wolfram Language code: GeoGridUnitArea[{"VanDerGrinten", "ReferenceModel" -> 1000}, Here]
Wolfram Language code: GeoGridUnitArea[{"VanDerGrinten", "Centering" -> {-40, 150}}, Here]

用单位为度的数据对 {lat,lon} 指定位置：

Wolfram Language code: GeoGridUnitArea["Orthographic", {-80.5, 30.32}]

使用带有地理位置标头的位置：

Wolfram Language code: GeoGridUnitArea["Orthographic", GeoPosition[{-80.5, 30.32}]]
Wolfram Language code: GeoGridUnitArea["Orthographic", GeoPositionXYZ[{911681, 533170, -6268998}]]
Wolfram Language code: GeoGridUnitArea["Orthographic", GeoGridPosition[{0.714285, -0.753047}, "Albers"]]

用地理 Entity 对象指定位置：

Wolfram Language code: GeoGridUnitArea["Albers", Entity["City", {"Toronto", "Ontario", "Canada"}]]

计算一组位置的地理网格单位面积：

Wolfram Language code: GeoGridUnitArea["Mollweide", {GeoPosition[{10, 40}], GeoGridPosition[{-30.3, 20}, "Mercator"], {85, 178}}]

将 QuantityArray 输出转换为普通形式：

Wolfram Language code: %//Normal

GeoGridUnitArea 可有效处理大量位置：

Wolfram Language code: locs = RandomGeoPosition["World", 10 ^ 6];
Wolfram Language code: GeoGridUnitArea["Mollweide", locs]//AbsoluteTiming

选项  (2)

GeoModel  (1)

默认情况下，GeoGridUnitArea 返回地球的值：

Wolfram Language code: GeoGridUnitArea["Bonne", {50, -100}]

在月球的相应点上执行相同的计算会返回较小的值：

Wolfram Language code: GeoGridUnitArea["Bonne", {50, -100}, GeoModel -> "Moon"]

选择特定半径的球状模型：

Wolfram Language code: GeoGridUnitArea["Bonne", {50, -100}, GeoModel -> Quantity[2000, "Kilometers"]]

UnitSystem  (1)

选择返回面积时使用的单位系统：

Wolfram Language code: GeoGridUnitArea["Wiechel", GeoPosition[{10, 120}], UnitSystem -> "Metric"]
Wolfram Language code: GeoGridUnitArea["Wiechel", GeoPosition[{10, 120}], UnitSystem -> "Imperial"]

值相同，单位不同：

Wolfram Language code: % == %%

应用  (3)

对于圆柱投影，投影单位面积只取决于纬度：

Wolfram Language code: Plot3D[GeoGridUnitArea["Mercator", {lat, lon}], {lat, -89, 89}, {lon, -180, 180}]

通过 GeoGridUnitArea 用地图中的投影面积来求小区域的近似地理面积：

Wolfram Language code: geopol = EntityValue[Entity["City", {"SanFrancisco", "California", "UnitedStates"}], "Polygon"]

用 Albers 投影法进行投影并计算平面地图的面积：

Wolfram Language code: pol = GeoGridPosition[geopol, "Albers"]
Wolfram Language code: Area[pol /. GeoGridPosition[expr_, proj_] :> expr]

将结果与区域中心位置的地理网格单位面积相乘：

Wolfram Language code: % GeoGridUnitArea["Albers", Entity["City", {"SanFrancisco", "California", "UnitedStates"}]]

与正确的地理面积相比较：

Wolfram Language code: geopol//GeoArea

计算在投影地图上定义的区域的地理区积：

Wolfram Language code: GeoGraphics[{Opacity[0.5], Disk[{0, 0}, 1]}, GeoRange -> "World", GeoProjection -> "ConicEquidistant", Frame -> True, Axes -> True]
Wolfram Language code: area[x_Real, y_Real] := QuantityMagnitude[GeoGridUnitArea["ConicEquidistant", GeoGridPosition[{x, y}, "ConicEquidistant"], GeoModel -> "ITRF00"], "Kilometers" ^ 2];
Wolfram Language code: Quantity[NIntegrate[area[x, y], {x, y}∈Disk[{0, 0}, 1]], "Kilometers" ^ 2]

与基于圆盘的多边形近似的计算结果进行比较：

Wolfram Language code: GeoGridPosition[N@CirclePoints[10000], "ConicEquidistant"]
Wolfram Language code: GeoArea[Polygon[GeoPosition[%]], UnitSystem -> "Metric"]

属性和关系  (3)

取一个位置和一个投影：

Wolfram Language code: loc = Entity["Lake", "LakeVictoria::b8795"];
Wolfram Language code: proj = "WagnerI";

构建一系列尺寸依次减小的投影正方形，汇聚到该位置：

Wolfram Language code: {x, y} = GeoGridPosition[loc, proj]["GridXY"]
Wolfram Language code: square[s_] := Polygon[{{x - s, y + s}, {x + s, y + s}, {x + s, y - s}, {x - s, y - s}}]
Wolfram Language code: squares = square /@ PowerRange[1, 1 / 2000, 1 / 2];
Wolfram Language code: GeoGraphics[{EdgeForm[Black], FaceForm[], squares}, GeoRange -> "World", GeoProjection -> proj, Frame -> True]

计算这些方块的未投影区域与投影区域的比率：

Wolfram Language code: ratio[pol_] := GeoArea[GeoPosition[GeoGridPosition[#, proj]& /@ pol]] / Area[pol]
Wolfram Language code: ratio /@ squares

结果收敛到 GeoGridUnitArea 为在该位置处的投影给出的值：

Wolfram Language code: GeoGridUnitArea[proj, loc, GeoModel -> "ITRF00"]

投影单位面积随地理模型大小的平方而变化：

Wolfram Language code: proj = GeoProjectionData["Mollweide"]
Wolfram Language code: GeoGridUnitArea["Mollweide", GeoPosition[{10, 20}], GeoModel -> #]& /@ Quantity[{10, 100, 1000}, "Kilometers"]

投影单位面积随参考模型的倒数的平方或中心比例因子而变化：

Wolfram Language code: GeoGridUnitArea[{"Mollweide", "ReferenceModel" -> #}, GeoPosition[{10, 20}]]& /@ {10, 100, 1000}
Wolfram Language code: GeoGridUnitArea[{"Mollweide", "CentralScaleFactor" -> #}, GeoPosition[{10, 20}]]& /@ {10, 100, 1000}

等面积投影在全球范围内的地理网格单位面积不变：

Wolfram Language code: equalarea = GeoProjectionData["EqualArea"]

对于世界各地的随机位置集合，请检查投影单位面积的范围是否为零宽度：

Wolfram Language code: points = RandomGeoPosition["World", 1000];
Wolfram Language code: MinMax /@ QuantityMagnitude[GeoGridUnitArea[{#, "ReferenceModel" -> 1}, points, GeoModel -> Quantity[1, "Meters"]]& /@ equalarea, "Meters" ^ 2]

可能存在的问题  (1)

如果无法对地理位置进行投影，则无法计算该位置的投影单位面积：

Wolfram Language code: GeoGridPosition[GeoPosition[{20, 120}], "Orthographic"]
Wolfram Language code: GeoGridUnitArea["Orthographic", GeoPosition[{20, 120}]]

此位置不在具有默认中心的 "Orthographic" 投影覆盖的半个地球上：

Wolfram Language code: GeoGraphics[GeoRange -> "World", GeoProjection -> "Orthographic", GeoGridLines -> Automatic]
Wolfram Research (2019)，GeoGridUnitArea，Wolfram 语言函数，https://reference.wolfram.com/language/ref/GeoGridUnitArea.html.

文本

Wolfram Research (2019)，GeoGridUnitArea，Wolfram 语言函数，https://reference.wolfram.com/language/ref/GeoGridUnitArea.html.

CMS

Wolfram 语言. 2019. "GeoGridUnitArea." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/GeoGridUnitArea.html.

APA

Wolfram 语言. (2019). GeoGridUnitArea. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/GeoGridUnitArea.html 年

BibTeX

@misc{reference.wolfram_2026_geogridunitarea, author="Wolfram Research", title="{GeoGridUnitArea}", year="2019", howpublished="\url{https://reference.wolfram.com/language/ref/GeoGridUnitArea.html}", note=[Accessed: 04-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_geogridunitarea, organization={Wolfram Research}, title={GeoGridUnitArea}, year={2019}, url={https://reference.wolfram.com/language/ref/GeoGridUnitArea.html}, note=[Accessed: 04-November-2026]}