WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

GeoPolygon[{loc1,…,locn}]

境界が位置 lociから loci+1までの測地線分によって形成された，塗り潰された多角形を表すGeoGraphicsプリミティブである．

GeoPolygon[{loc1,…,locn}{{q1,…,qm},…}]

穴{q1,…,qm}, …がある地理多角形を表す．

GeoPolygon[{poly1,poly2,…}]

多角形 polyiの集合を表す．

GeoPolygon[{poly1,poly2,…},sideness]

polyiの各境界の2つの面のどちらが地理多角形の内側になるかを指定する．

GeoPolygon[polys,sideness,pathtype]

境界がタイプ pathtype の地理経路で形成された地理多角形を表す．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
データ指定  
側指定  
地理経路のタイプ  
特性と関係  
関連項目
テクニカルノート
関連するガイド
関連リンク
履歴
引用書式

GeoPolygon

GeoPolygon[{loc1,…,locn}]

境界が位置 lociから loci+1までの測地線分によって形成された，塗り潰された多角形を表すGeoGraphicsプリミティブである．

GeoPolygon[{loc1,…,locn}{{q1,…,qm},…}]

穴{q1,…,qm}, …がある地理多角形を表す．

GeoPolygon[{poly1,poly2,…}]

多角形 polyiの集合を表す．

GeoPolygon[{poly1,poly2,…},sideness]

polyiの各境界の2つの面のどちらが地理多角形の内側になるかを指定する．

GeoPolygon[polys,sideness,pathtype]

境界がタイプ pathtype の地理経路で形成された地理多角形を表す．

詳細

  • GeoPolygon[…]は2Dの地理領域を地球あるいはその他の地理モデル上に表し，GeoGraphicsのような地理可視化関数，あるいはGeoAreaのような地理計算関数で使うことができる．
  • GeoPolygon[{loc1,…,locn}]の境界{loc1,…,locn}は世界を補完的な2つの領域に分割する．デフォルトで，GeoPolygon[{loc1,…,locn}]とGeoPolygon[{loc1,…,locn},Automatic]は小さい方を参照する．以下は領域の可能な指定方法である．
  • GeoPolygon[locs{intloc}]intloc は地理多角形の内側の位置である
    GeoPolygon[locs,extloc]extloc は地理多角形の外側の位置である
    GeoPolygon[locs,"SmallerArea"]地理多角形の内側は領域の小さい方である
    GeoPolygon[locs,"LargerArea"]地理多角形の内側は領域の大きい方である
    GeoPolygon[locs,"LeftArea"]locs を辿る際，内側は左側である
    GeoPolygon[locs,"RightArea"]locs を辿る際，内側は右側である
  • 位置 lociは，度を単位とした経緯度座標{lat,lon}として，GeoPosition[{lat,lon}]として，あるいは名前付きの実体Entity[…]として指定できる．
  • 実体はその"Position"特性で決定される位置として解釈される．
  • GeoPolygonは，次のタイプの地理経路をサポートする．
  • "Geodesic"点と点の間の測地経路
    "Rhumb","RhumbLine","Loxodrome"点と点の間の一定方位の経路
    "GreatEllipse","GreatCircle"地心を通る平面上の経路

例題

すべて開く すべて閉じる

例  (3)

測地長方形を地表に描画する：

Wolfram Language code: GeoGraphics[GeoPolygon[{{-30, -60}, {-30, 60}, {30, 60}, {30, -60}}]]

測地長方形の補完領域を地表に描画する：

Wolfram Language code: GeoGraphics[GeoPolygon[{{-30, -60}, {-30, 60}, {30, 60}, {30, -60}}, "LargerArea"]]

穴がある測地長方形を描画する：

Wolfram Language code: GeoGraphics[GeoPolygon[{{-30, -60}, {-30, 60}, {30, 60}, {30, -60}} -> {{{-15, -30}, {-15, 30}, {15, 30}, {15, -30}}}]]

スコープ  (8)

データ指定  (3)

地理多角形の頂点を度を単位とした経緯度ペアで指定する：

Wolfram Language code: GeoPolygon[{{10, -50.6}, {70, 0.2}, {20, 30}, {-30, 0}}]

地理多角形の頂点をGeoPositionオブジェクトとして与える：

Wolfram Language code: GeoGraphics[GeoPolygon[GeoPosition[{{10, -50.6}, {70, 0.2}, {20, 30}, {-30, 0}}]]]

代りに個々のGeoPositionオブジェクトのリストを使う：

Wolfram Language code: GeoGraphics[GeoPolygon[{GeoPosition[{10, -50.6}], GeoPosition[{70, 0.2}], GeoPosition[{20, 30}], GeoPosition[{-30, 0}]}]]

地理実体を使って領域を指定する：

Wolfram Language code: GeoGraphics[GeoPolygon[Entity["Country", "UnitedStates"]]]

地理領域の中の穴を別の地理実体を使って指定する：

Wolfram Language code: GeoGraphics[{EdgeForm[Directive[Thick, Red]], GeoPolygon[Entity["Country", "UnitedStates"] -> {Entity["AdministrativeDivision", {"Illinois", "UnitedStates"}], Entity["AdministrativeDivision", {"Kansas", "UnitedStates"}], Entity["AdministrativeDivision", {"California", "UnitedStates"}]}]}]

側指定  (4)

極のような内部点を与えることで赤道の両側の一方を指定する：

Wolfram Language code: GeoPolygon[{{0, 0}, {0, 90}, {0, 180}, {0, -90}} -> {90, 0}]
Wolfram Language code: GeoGraphics[%, GeoRange -> "World"]

同じ境界の場所について別の極を指定する：

Wolfram Language code: GeoPolygon[{{0, 0}, {0, 90}, {0, 180}, {0, -90}} -> {-90, 0}]
Wolfram Language code: GeoGraphics[%, GeoRange -> "World"]

外部の点を与えることで地理多角形の側を指定する：

Wolfram Language code: GeoGraphics[GeoPolygon[{{-50, -50}, {50, 0}, {-50, 50}}, {70, 0}]]

{0, 0}が外部の点であると指定することで世界の反対側を選択する：

Wolfram Language code: GeoGraphics[{GeoMarker[{0, 0}], GeoPolygon[{{-50, -50}, {50, 0}, {-50, 50}}, {0, 0}]}]

関心領域が閉じた境界の2つの側の大きい方か小さい方かを示す：

Wolfram Language code: {GeoGraphics[GeoPolygon[{{-50, -50}, {50, 0}, {-50, 50}}, "SmallerArea"]], GeoGraphics[GeoPolygon[{{-50, -50}, {50, 0}, {-50, 50}}, "LargerArea"]]}

ポルトガルの多角形をEntityValueが返すものとする：

Wolfram Language code: pol = EntityValue[Entity["Country", "Portugal"], "Polygon"]

多角形の境界は時計回りに辿られる：

Wolfram Language code: GeoGraphics[{Arrowheads[Large], Arrow[GeoPath@@pol]}]

したがって，ポルトガル内部は曲線の右側になる：

Wolfram Language code: Append[GeoPolygon@@pol, "RightArea"]
Wolfram Language code: GeoGraphics[%, GeoCenter -> Entity["City", {"Lisbon", "Lisboa", "Portugal"}], GeoRange -> Quantity[500, "Miles"]]

"LeftArea"を使って境界の左側を選ぶ：

Wolfram Language code: Append[GeoPolygon@@pol, "LeftArea"]
Wolfram Language code: GeoGraphics[%, GeoCenter -> Entity["City", {"Lisbon", "Lisboa", "Portugal"}], GeoRange -> Quantity[500, "Miles"]]

地理経路のタイプ  (1)

デフォルトで，GeoPolygonオブジェクトの辺は測地線分である：

Wolfram Language code: GeoGraphics[GeoPolygon[{{-60, -60}, {60, 60}, {-60, 60}}]]

同じ頂点を持つ別のGeoPolygonオブジェクトの辺として航程線を使う：

Wolfram Language code: GeoGraphics[GeoPolygon[{{-60, -60}, {60, 60}, {-60, 60}}, Automatic, "Loxodrome"]]

特性と関係  (2)

GeoPolygon[locs]オブジェクトの境界は閉じたGeoPath[locs]オブジェクトである：

Wolfram Language code: locs = {{0, 0}, {40, -90}, {70, 0}};
Wolfram Language code: GeoGraphics[{GeoPolygon[locs], Red, GeoPath[locs, CurveClosed -> True]}]

他の経路タイプについても同じことが言える：

Wolfram Language code: GeoGraphics[{GeoPolygon[locs, Automatic, "Loxodrome"], Red, GeoPath[locs, "Loxodrome", CurveClosed -> True]}]

GeoPolygon[locs]は，頂点と辺の両方のすべての境界点を一意的に定義する：

Wolfram Language code: locs = {{85, -90}, {60, -35}, {0, 0}, {85, -90}};
Wolfram Language code: GeoGraphics[{Red, GeoPolygon[locs]}, GeoProjection -> "Equirectangular"]

Polygon[GeoPosition[locs]]は頂点の位置を点と点の間の直線を使って定義する：

Wolfram Language code: GeoGraphics[{Blue, Polygon[GeoPosition[locs]]}, GeoProjection -> "Equirectangular"]

他の投影法では，赤いGeoPolygonの面積は一定のままだが青い面積はそうではない：

Wolfram Language code: Show[%%, %, GeoProjection -> {"Orthographic", "Centering" -> {60, -15}}, GeoRange -> Quantity[3000, "Miles"], GeoGridLines -> Automatic]
Wolfram Research (2020), GeoPolygon, Wolfram言語関数， https://reference.wolfram.com/language/ref/GeoPolygon.html.

テキスト

Wolfram Research (2020), GeoPolygon, Wolfram言語関数， https://reference.wolfram.com/language/ref/GeoPolygon.html.

CMS

Wolfram Language. 2020. "GeoPolygon." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/GeoPolygon.html.

APA

Wolfram Language. (2020). GeoPolygon. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/GeoPolygon.html

BibTeX

@misc{reference.wolfram_2026_geopolygon, author="Wolfram Research", title="{GeoPolygon}", year="2020", howpublished="\url{https://reference.wolfram.com/language/ref/GeoPolygon.html}", note=[Accessed: 02-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_geopolygon, organization={Wolfram Research}, title={GeoPolygon}, year={2020}, url={https://reference.wolfram.com/language/ref/GeoPolygon.html}, note=[Accessed: 02-August-2026]}