GeoProjection
GeoProjection
GeoGraphicsのオプションで，地図に使用する地図投影法を指定する．
詳細
- GeoProjectionは，任意の投影法"proj"または{"proj",params}を使うことができる．ただし，"proj"はGeoProjectionDataの任意の実体，params は"StandardParallels"{33,60}のようなパラメータの規則である．GeoProjectionData["proj"]は，投影法"proj"についてのパラメータのデフォルト値を与える．
- GeoGraphics[…,GeoProjectionAutomatic]は，投影法を自動的に選択する．これは，小さいスケールの場合は"Mercator"，中くらいのスケールの場合は"LambertAzimuthal"，大きいスケールの場合は"Equirectangular"である．これは，"Centering"と"GridOrigin"の両パラメータも自動的に選ぶ．
- 投影法はGeoGraphics地図の測地的背景，またGeoPathやGeoDiskのような測地プリミティブに適用される．
- AbsoluteOptionsを使って，Automatic設定のGeoProjectionについての明示的な投影情報を与えることができる．
例題
すべて開く すべて閉じる例 (4)
GeoGraphics[GeoRange -> "World"]GeoGraphics[GeoRange -> "World", GeoProjection -> "Albers"]緯度30度と50度のカスタム標準緯線を使用したアルベルス図法を使う：
GeoGraphics[{GeoPath[{"Parallel", 30}], GeoPath[{"Parallel", 50}]}, GeoProjection -> {"Albers", "StandardParallels" -> {30, 50}}, GeoRange -> "World"]さまざまな投影法によるカナダの地図．どれも10度の経緯線網とともに示されている：
mapCanada[proj_] := GeoGraphics[{Polygon[Entity["Country", "Canada"]]}, GeoProjection -> proj, GeoGridLines -> Quantity[10, "AngularDegrees"], GeoBackground -> "Basic"]mapCanada["Mercator"]mapCanada["LambertAzimuthal"]mapCanada["CylindricalEqualArea"]スコープ (4)
GeoGraphics[{Polygon[Entity["Country", "Sweden"]]}, GeoProjection -> "Orthographic"]AbsoluteOptions[%, GeoProjection]GeoGraphics[{Polygon[Entity["Country", "Sweden"]]}, GeoProjection -> {"Orthographic", "Centering" -> GeoPosition[{0, -40}]}, Background -> Black]a = {40, -120};
b = {60, -60};
c = (a + b) / 2prims = {GeoStyling[Opacity[.2]], Orange, GeoDisk[c, Quantity[1000, "Kilometers"]], Blue, GeoPath[{a, b}], Point[GeoPosition[c]]};正距円筒図法では，円板の中心が測地経路の両端点の中心になる：
GeoGraphics[prims, GeoProjection -> "Equirectangular", GeoBackground -> "Plain"]ランベルト方位図法では，測地線はほとんど直線に見え，測地円板は円形に見える：
GeoGraphics[prims, GeoProjection -> "LambertAzimuthal", GeoBackground -> "Plain"]GeoGraphics[GeoRange -> All, GeoModel -> Entity["PlanetaryMoon", "Moon"], GeoProjection -> "Orthographic", GeoGridLines -> Automatic, GeoGridLinesStyle -> White, Background -> Black, PlotRangePadding -> 0.2]アプリケーション (1)
特性と関係 (2)
明示的な投影法が指定されていない場合は，自動的に1つが選ばれる：
GeoGraphics[{
Polygon[EntityClass["Country", "Europe"]],
GeoStyling[Opacity[.2]], Red, Polygon[Entity["Country", "Spain"]]
}, Frame -> True, GeoProjection -> Automatic, GeoBackground -> "Classic"]AbsoluteOptions[%, GeoProjection]1つ以上の測地グラフィックスプリミティブがあり，投影法が明示的には指定されていない場合は，正距円筒図法が常に使われる：
GeoGraphics[{
Polygon[EntityClass["Country", "Europe"]],
GeoStyling[Opacity[.2]],
Red, Polygon[Entity["Country", "Spain"]],
Blue, Opacity[.5], Disk[{10, 50}, 10]
}, Frame -> True, GeoProjection -> Automatic, GeoBackground -> "Classic"]AbsoluteOptions[%, GeoProjection]GeoDisk，Line[{GeoPosition[…], …}]等を使って，正しく投影されたプリミティブを地図上に置く：
GeoGraphics[{
Polygon[EntityClass["Country", "Europe"]],
GeoStyling[Opacity[.2]],
Red, Polygon[Entity["Country", "Spain"]],
Blue, EdgeForm[], GeoDisk[{50, 10}, Quantity[1000, "Kilometers"]]
}, Frame -> True, GeoProjection -> Automatic, GeoBackground -> "Classic"]AbsoluteOptions[%, GeoProjection]あるいは，明示的に投影法を指定して，投影された測地グラフィックスと同じ座標スケール上で，通常のグラフィックスとプリミティブを組み合せる：
GeoGraphics[{
Polygon[EntityClass["Country", "Europe"]],
GeoStyling[Opacity[.2]], Polygon[Entity["Country", "Spain"]],
Blue, EdgeForm[], GeoDisk[{50, 10}, Quantity[1000, "Kilometers"]],
Red, Polygon[Entity["Country", "Spain"]],
Blue, Opacity[.5], Disk[{10, 50}, 10]
}, Frame -> True, GeoProjection -> "CylindricalEqualArea", GeoBackground -> "Classic"]地理投影法における経緯線網，つまり一定の経緯度線の格子の歪みを調べる：
worldGraticule[proj_] := GeoGraphics[GeoRange -> "World", GeoBackground -> None, GeoGridLines -> Quantity[5, "AngularDegrees"], GeoProjection -> proj]worldGraticule["Equirectangular"]worldGraticule["Mercator"]worldGraticule["Bonne"]worldGraticule["Albers"]worldGraticule["WinkelTripel"]worldGraticule["Mollweide"]worldGraticule["Orthographic"]おもしろい例題 (2)
世界の"PeirceQuincuncial"投影は，適切な回転を用いることでタイリングすることができる：
GeoImage["World", GeoProjection -> "PeirceQuincuncial", ImageSize -> {150, 150}]MapIndexed[ImageRotate[#1, (-1) ^ Total[#2]Pi / 2]&, ConstantArray[%, {4, 4}], {2}]//ImageAssemblePolyhedronProjection[polyhedron_] := Module[{pts3D, center, pts2D, proj, pts2Dprojected, geographics, plotrange, pts2Dscaled, rescale},
rescale[{x_, y_}, {xs_, ys_}] := {Rescale[x, xs], Rescale[y, ys]};
Graphics3D[{
pts3D = First[#];
center = Mean[pts3D];
center = MapAt[Most, GeoPosition[GeoPositionXYZ[center, Norm[center]]], {1}];
pts2D = GeoPosition[GeoPositionXYZ[pts3D, Norm[pts3D[[1]]]]];
proj = {"Gnomonic", "Centering" -> center};
pts2Dprojected = Most /@ GeoGridPosition[pts2D, proj][[1]];
geographics = GeoGraphics[{Opacity[0], center, GeoPath[pts2D[[1]], CurveClosed -> True]}, GeoProjection -> proj, GeoZoomLevel -> 1, GeoBackground -> "StreetMapNoLabels"];
plotrange = PlotRange /. AbsoluteOptions[geographics, PlotRange];
pts2Dscaled = rescale[#, plotrange]& /@ pts2Dprojected;
{Texture[ImageData[Rasterize[geographics[[1]], "Image"]]], Polygon[pts3D, VertexTextureCoordinates -> pts2Dscaled]}}& /@ N@Flatten[PolyhedronData[polyhedron, "Faces", "Polygon"]], Lighting -> "Neutral", Boxed -> False, Method -> {"ShrinkWrap" -> True}, ImageSize -> Small]]PolyhedronProjection["Dodecahedron"]PolyhedronProjection["Icosahedron"]
An Elementary Introduction to the Wolfram Language
Wolfram Research (2014), GeoProjection, Wolfram言語関数， https://reference.wolfram.com/language/ref/GeoProjection.html.
テキスト
Wolfram Research (2014), GeoProjection, Wolfram言語関数， https://reference.wolfram.com/language/ref/GeoProjection.html.
CMS
Wolfram Language. 2014. "GeoProjection." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/GeoProjection.html.
APA
Wolfram Language. (2014). GeoProjection. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/GeoProjection.html