WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

GridLines

2Dのグラフィックス関数のオプションとして使われ，格子線の指定を行う．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
GridLinesの位置  
GridLinesのスタイル  
一般化と拡張  
アプリケーション  
特性と関係  
考えられる問題  
おもしろい例題  
関連項目
テクニカルノート
関連するガイド
履歴
引用書式

GridLines

GridLines

2Dのグラフィックス関数のオプションとして使われ，格子線の指定を行う．

詳細

  • GridLinesの設定可能な指定値
  • None格子線を描かない
    Automatic自動的に格子線を配置
    {xgrid,ygrid}格子線を各方向に個別に指定
  • Automaticの設定では，通常，十進法表記で桁数が最小になる座標の点に格子線が配置される．
  • 各方向に対し以下のオプションが指定可能である．
  • None格子線を描かない
    Automatic自動的に格子線を配置
    {x1,x2,…}指定された位置に格子線を配置
    {{x1,style1},…}スタイル指定された格子線
    func格子線オプションを得るために xmin, xmaxに適用する関数
  • 格子線のスタイルには，RGBColorやThicknessのような任意のグラフィックス指示子を指定することができる．
  • 格子線の関数 func[xmin,xmax]は，この他の格子線のオプションを返すことがある．
  • AbsoluteOptionsはAutomaticの設定が使用されると，GridLines指定の明示的形式を与える．
  • GridLinesStyleは格子線に使うデフォルトスタイルを返す．

例題

すべて開く すべて閉じる

例  (4)

2Dグラフィックスに格子を置く：

Wolfram Language code: Graphics[Circle[], Frame -> True, GridLines -> Automatic]

特定の位置に格子線を引く：

Wolfram Language code: Plot[Cos[x], {x, 0, 10}, GridLines -> {{Pi, 2Pi}, {-1, -.5, .5, 1}}]

格子のスタイルを指定する：

Wolfram Language code: Plot[Cos[x], {x, 0, 10}, GridLines -> {{{Pi, Dashed}, {2Pi, Thick}}, {{-1, Orange}, -.5, .5, {1, Orange}}}]

GridLinesStyleを使って格子線の全体的なスタイルを指定する：

Wolfram Language code: Graphics[Circle[], Frame -> True, GridLines -> Automatic, GridLinesStyle -> Directive[Orange, Dashed]]

スコープ  (6)

GridLinesの位置  (3)

格子を自動的に置く：

Wolfram Language code: Graphics[Circle[], Axes -> True, GridLines -> Automatic]
Wolfram Language code: Plot[Cos[x], {x, 0, 10}, GridLines -> Automatic]
Wolfram Language code: LogLogPlot[1 / x, {x, 1, 100}, GridLines -> Automatic, Frame -> True]

方向に格子を置く：

Wolfram Language code: Graphics[Circle[], Frame -> True, GridLines -> {Automatic, None}]

方向に格子を置く：

Wolfram Language code: Plot[Cos[x], {x, 0, 10}, GridLines -> {None, Automatic}]

特定の位置に格子線を引く：

Wolfram Language code: Graphics[Circle[], Axes -> True, GridLines -> {{-1, 1}, {-1, 1}}]
Wolfram Language code: Plot[Cos[x], {x, 0, 10}, Ticks -> {None, Automatic}, GridLines -> {{Pi, 2Pi, 3Pi}, {-1, -.5, .5, 1}}]

GridLinesのスタイル  (3)

各格子線のスタイルを指定する：

Wolfram Language code: Graphics[Circle[], Axes -> True, GridLines -> {{-1, {-.5, Dotted}, {.5, Dotted}, 1}, {-1, {-.5, Dotted}, {.5, Dotted}, 1}}]
Wolfram Language code: Plot[Cos[x], {x, 0, 10}, Ticks -> {None, Automatic}, GridLines -> {{{Pi, Dashed}, {2Pi, Directive[Red, Thick]}, 3Pi}, {{-1, Blue}, -.5, .5, {1, Blue}}}]

GridLinesStyleを使って格子線の全体的なスタイルを指定する：

Wolfram Language code: Plot[Cos[x], {x, 0, 10}, Ticks -> {None, Automatic}, GridLines -> {{Pi, 2Pi, 3Pi}, {-1, -.5, .5, 1}}, GridLinesStyle -> Directive[Orange, Dashed]]

GridLinesStyleとともに個々にスタイル付けした格子線を用いることができる．優先順位は個々のスタイルの方が高い：

Wolfram Language code: Plot[Cos[x], {x, 0, 10}, Ticks -> {None, Automatic}, GridLines -> {{{Pi, Dashing[{}]}, {2Pi, Directive[Blue, Thick]}, {3Pi, Red}}, Automatic}, GridLinesStyle -> Directive[Orange, Dashed]]

一般化と拡張  (1)

各方向の xmin と xmax の値に適用する格子関数を指定する：

Wolfram Language code: grids[min_, max_] := Table[If[EvenQ[i], {i, Red}, {i, Blue}], {i, Ceiling[min], Floor[max], 1}]
Wolfram Language code: Graphics[{Circle[{0, 0}, 3]}, Frame -> True, GridLines -> grids]

アプリケーション  (3)

各整数のところに実線を，その間に破線を置く：

Wolfram Language code: grids[min_, max_] := Join[Range[Ceiling[min], Floor[max]], Table[{j + .5, Dashed}, {j, Round[min], Round[max - 1], 1}]]
Wolfram Language code: Graphics[{Circle[{0, 0}, 2]}, Frame -> True, GridLines -> grids]

グラフ用紙をまねる：

Wolfram Language code: grids[min_, max_] := Join[Range[Ceiling[min], Floor[max]], Table[{j + .5, Dashed}, {j, Round[min], Round[max - 1], 1}]]
Wolfram Language code: Plot[Cos[Pi x], {x, 0, 3}, GridLines -> grids, Background -> StandardBlue]

すべての整数値上の格子線：

Wolfram Language code: Graphics[Raster[Table[Append[RandomReal[1, 3], .5], {20}, {20}]], Frame -> True, GridLines -> Function[{min, max}, Range[Floor[min], Ceiling[max]]]]

特性と関係  (3)

デフォルトで，格子線は主な目盛マークの位置に置かれる：

Wolfram Language code: {Graphics[Circle[], Frame -> True], Graphics[Circle[], Frame -> True, GridLines -> Automatic]}
Wolfram Language code: {Plot[Cos[x], {x, 0, 2Pi}], Plot[Cos[x], {x, 0, 2Pi}, GridLines -> Automatic]}

格子線は常にすべてのグラフィックスの下に描かれる：

Wolfram Language code: Graphics[{Pink, Disk[]}, Frame -> True, GridLines -> Automatic]

MeshとMeshFunctionsを使ってある種のプロットの上に線を引くことができる：

Wolfram Language code: Plot3D[Sin[x y], {x, 0, 3}, {y, 0, 3}, Mesh -> {3, 3}]
Wolfram Language code: DensityPlot[Sin[x] + Cos[y], {x, 0, 8}, {y, 0, 8}, Mesh -> {{2, {4, Thick}, 6}, {2, {4, Thick}, 6}}]
Wolfram Language code: ListPlot3D[RandomReal[1, {10, 10}], InterpolationOrder -> 2, Mesh -> 5, MeshFunctions -> (#3&)]

考えられる問題  (1)

プロットによっては，格子線をグラフィックスによって完全に隠すことができる：

Wolfram Language code: DensityPlot[Sin[x] + Cos[y], {x, 0, 8}, {y, 0, 8}, GridLines -> {{2, {4, Red}, 6}, {2, {4, Red}, 6}}]

代りにMeshを使ってグラフィックスの上に線を置くこともできる：

Wolfram Language code: DensityPlot[Sin[x] + Cos[y], {x, 0, 8}, {y, 0, 8}, Mesh -> {{2, {4, Red}, 6}, {2, {4, Red}, 6}}]

おもしろい例題  (1)

格子線のランダムな集合：

Wolfram Language code: Graphics[{}, PlotRange -> {{0, 1}, {0, 1}}, GridLines -> {Table[{RandomReal[], Hue[RandomReal[]]}, {30}], Table[{RandomReal[], Hue[RandomReal[]]}, {30}]}]
Wolfram Research (1991), GridLines, Wolfram言語関数， https://reference.wolfram.com/language/ref/GridLines.html （2007年に更新）.

テキスト

Wolfram Research (1991), GridLines, Wolfram言語関数， https://reference.wolfram.com/language/ref/GridLines.html （2007年に更新）.

CMS

Wolfram Language. 1991. "GridLines." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2007. https://reference.wolfram.com/language/ref/GridLines.html.

APA

Wolfram Language. (1991). GridLines. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/GridLines.html

BibTeX

@misc{reference.wolfram_2026_gridlines, author="Wolfram Research", title="{GridLines}", year="2007", howpublished="\url{https://reference.wolfram.com/language/ref/GridLines.html}", note=[Accessed: 17-July-2026]}

BibLaTeX

@online{reference.wolfram_2026_gridlines, organization={Wolfram Research}, title={GridLines}, year={2007}, url={https://reference.wolfram.com/language/ref/GridLines.html}, note=[Accessed: 17-July-2026]}