WOLFRAM

Wolfram 语言与系统参考资料中心

GroupElementToWord[group,g]

把群元素 g 分解为 group 的生成器的乘积.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
选项  
GroupBaseAction  
MaxIterations  
Method  
应用  
属性和关系  
巧妙范例  
参见
技术笔记
相关指南
历史
按以下格式引用：

GroupElementToWord

GroupElementToWord[group,g]

把群元素 g 分解为 group 的生成器的乘积.

更多信息和选项

范例

打开所有单元 关闭所有单元

基本范例  (1)

取群 G 的置换 g：

Wolfram Language code: g = Cycles[{{1, 6, 4}, {2, 3, 5}}]; G = PermutationGroup[{Cycles[{{1, 2, 3}}], Cycles[{{1, 2, 3, 4, 5, 6, 7}}]}];

把 g 分解为 G 的生成器的乘积（负整数表示逆生成器）：

Wolfram Language code: word = GroupElementToWord[G, g]

从单词重新构建置换：

Wolfram Language code: GroupElementFromWord[G, word]

范围  (2)

把置换分解为对称群的默认生成器的乘积：

Wolfram Language code: GroupElementToWord[SymmetricGroup[6], Cycles[{{1, 2}, {3, 6}, {4, 5}}]]

使用相同群的生成器的不同集合，把相同置换分解：

Wolfram Language code: GroupElementToWord[PermutationGroup[{Cycles[{{1, 2}}], Cycles[{{2, 3}}], Cycles[{{3, 4}}], Cycles[{{4, 5}}], Cycles[{{5, 6}}]}], Cycles[{{1, 2}, {3, 6}, {4, 5}}]]

返回的单词通常不是最优：

Wolfram Language code: g = Cycles[{{1, 6, 4}, {2, 3, 5}}]; G = PermutationGroup[{Cycles[{{1, 2, 3}}], Cycles[{{1, 2, 3, 4, 5, 6, 7}}]}];
Wolfram Language code: word = GroupElementToWord[G, g]

这是最优解：

Wolfram Language code: optimalword = {1, 2, -1, -2, -2, -2, -1}

检查它们：

Wolfram Language code: g === GroupElementFromWord[G, word]
Wolfram Language code: g === GroupElementFromWord[G, optimalword]

选项  (3)

GroupBaseAction  (1)

算法使用与给定基相关联的群稳定子的陪集表示法的表格. 选择的这个基可能强烈影响所得的单词：

Wolfram Language code: G = PermutationGroup[{Cycles[{{1, 5, 7, 10, 4, 6, 8, 9}, {2, 3}}], Cycles[{{1, 3, 4}}]}]; g = Cycles[{{2, 5}, {3, 7, 8}, {6, 10}}];
Wolfram Language code: Length[GroupElementToWord[G, g]]
Wolfram Language code: Length[GroupElementToWord[G, g, GroupActionBase -> {1, 2, 3, 4, 8, 6, 5}]]

MaxIterations  (1)

频繁地，可能通过允许内部算法来执行大量额外迭代改善结果：

Wolfram Language code: G = PermutationGroup[{Cycles[{{1, 7, 2, 6, 5, 9, 4, 10, 3, 8}}], Cycles[{{1, 2, 3, 4}}]}]; g = Cycles[{{1, 2, 4, 5}, {6, 8, 7, 9}}];
Wolfram Language code: GroupElementToWord[G, g]
Wolfram Language code: GroupElementToWord[G, g, MaxIterations -> 10 ^ 4]

Method  (1)

在大量参数下，GroupElementToWord 使用 Minkwitz 算法：

Wolfram Language code: G = PermutationGroup[{Cycles[{{1, 5, 10, 4, 19, 7, 17, 12, 2, 8, 18}, {6, 20, 16, 15, 11, 9, 14, 13}}], Cycles[{{1, 4}}]}]; g = Cycles[{{1, 19, 2, 12}, {4, 10, 5, 17, 8, 18}}];

微调这些参数可能产生更短的单词：

Wolfram Language code: Length[GroupElementToWord[G, g]]
Wolfram Language code: Length[GroupElementToWord[G, g, Method -> {"Minkwitz", "InitMaxLength" -> 8}]]
Wolfram Language code: Length[GroupElementToWord[G, g, Method -> {"Minkwitz", "ImprovementPeriod" -> 75}]]

应用  (1)

检查这两个群各自的生成器的映射是同态的：

Wolfram Language code: G1 = PermutationGroup[{Cycles[{{1, 2}}], Cycles[{{1, 2, 3, 4}}]}];
Wolfram Language code: G2 = PermutationGroup[{Cycles[{{1, 2}, {3, 5}, {4, 6}, {7, 8}}], Cycles[{{1, 2, 3, 4}, {5, 6, 7, 8}}]}];

这实现了同态，把生成器的映射扩展到所有元素：

Wolfram Language code: hom[g_] := GroupElementFromWord[G2, GroupElementToWord[G1, g]]

检查对于 G1 的两个元素，遵循同构属性：

Wolfram Language code: With[{ g = RandomPermutation[G1], gg = RandomPermutation[G1] }, hom[ggg] == hom[g]hom[gg] ]

在这种情况下，同构实际上是同形（isomorphism）：

Wolfram Language code: Sort[hom /@ GroupElements[G1], Less] === GroupElements[G2]

属性和关系  (4)

GroupElementFromWord 从单词重新构建了原始群元素：

Wolfram Language code: G = DihedralGroup[8]; g = Cycles[{{1, 6, 3, 8, 5, 2, 7, 4}}]; word = GroupElementToWord[G, g]
Wolfram Language code: GroupElementFromWord[G, word]
Wolfram Language code: % === g

不使用恒等生成器，但是影响其他生成器的索引：

Wolfram Language code: G = PermutationGroup[{Cycles[{{1, 2}}], Cycles[{}], Cycles[{}], Cycles[{{2, 3}}]}];
Wolfram Language code: GroupElementToWord[G, Cycles[{{1, 3}}]]

恒等置换总是对应于空单词：

Wolfram Language code: G = PermutationGroup[{Cycles[{{1, 2}}], Cycles[{{2, 3}}]}];
Wolfram Language code: GroupElementToWord[G, Cycles[{}]]

元素必须属于群：

Wolfram Language code: G = DihedralGroup[6]; g = Cycles[{{1, 2, 3}, {4, 5, 6}}];
Wolfram Language code: GroupElementQ[G, g]
Wolfram Language code: GroupElementToWord[G, g]

巧妙范例  (1)

3×3×3 Rubik 的立方体的群通常以六个生成器给出：

Wolfram Language code: rot1 = Cycles[{{1, 3, 8, 6}, {2, 5, 7, 4}, {9, 48, 15, 12}, {10, 47, 16, 13}, {11, 46, 17, 14}}]; rot2 = Cycles[{{6, 15, 35, 26}, {7, 22, 34, 19}, {8, 30, 33, 11}, {12, 14, 29, 27}, {13, 21, 28, 20}}]; rot3 = Cycles[{{1, 12, 33, 41}, {4, 20, 36, 44}, {6, 27, 38, 46}, {9, 11, 26, 24}, {10, 19, 25, 18}}]; rot4 = Cycles[{{1, 24, 40, 17}, {2, 18, 39, 23}, {3, 9, 38, 32}, {41, 43, 48, 46}, {42, 45, 47, 44}}]; rot5 = Cycles[{{3, 43, 35, 14}, {5, 45, 37, 21}, {8, 48, 40, 29}, {15, 17, 32, 30}, {16, 23, 31, 22}}]; rot6 = Cycles[{{24, 27, 30, 43}, {25, 28, 31, 42}, {26, 29, 32, 41}, {33, 35, 40, 38}, {34, 37, 39, 36}}]; RubikGroup6 = PermutationGroup[{rot1, rot2, rot3, rot4, rot5, rot6}];

但是，其中一个是多余的，而实际上群可以只从五个面旋转构建：

Wolfram Language code: RubikGroup5 = PermutationGroup[{rot1, rot2, rot3, rot4, rot5}];
Wolfram Language code: RubikGroup6 == RubikGroup5

这是一个可能的单词，以前五个单词和它们的逆表示第六个旋转：

Wolfram Language code: word = GroupElementToWord[RubikGroup5, rot6]

检查它：

Wolfram Language code: GroupElementFromWord[RubikGroup5, word] === rot6

在删除了对应相反的面的生成器后，剩下的四个仍然移动所有的 facelet，但是目前它们只生成索引 2048 的子群：

Wolfram Language code: RubikGroup4 = PermutationGroup[{rot2, rot3, rot4, rot5}];
Wolfram Language code: (GroupOrder[RubikGroup6]/GroupOrder[RubikGroup4])

这是因为存在两个不相交的边 facelet：

Wolfram Language code: GroupOrbits[RubikGroup4]

与原始情况比较：

Wolfram Language code: GroupOrbits[RubikGroup6]
Wolfram Research (2012)，GroupElementToWord，Wolfram 语言函数，https://reference.wolfram.com/language/ref/GroupElementToWord.html.

文本

Wolfram Research (2012)，GroupElementToWord，Wolfram 语言函数，https://reference.wolfram.com/language/ref/GroupElementToWord.html.

CMS

Wolfram 语言. 2012. "GroupElementToWord." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/GroupElementToWord.html.

APA

Wolfram 语言. (2012). GroupElementToWord. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/GroupElementToWord.html 年

BibTeX

@misc{reference.wolfram_2026_groupelementtoword, author="Wolfram Research", title="{GroupElementToWord}", year="2012", howpublished="\url{https://reference.wolfram.com/language/ref/GroupElementToWord.html}", note=[Accessed: 04-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_groupelementtoword, organization={Wolfram Research}, title={GroupElementToWord}, year={2012}, url={https://reference.wolfram.com/language/ref/GroupElementToWord.html}, note=[Accessed: 04-November-2026]}