WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

ImageForwardTransformation[image,function]

位置 function[{x,y}]の各画素が image の位置{x,y}に対応する画像を返す．

ImageForwardTransformation[image,function,size]

指定された大きさの画像を返す．

ImageForwardTransformation[video,…]

動画のフレームを変換する．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
データ  
変換  
サイズ  
オプション  
Background  
DataRange  
Method  
PlotRange  
アプリケーション  
特性と関係  
おもしろい例題  
関連項目
関連するガイド
履歴
引用書式

ImageForwardTransformation

ImageForwardTransformation[image,function]

位置 function[{x,y}]の各画素が image の位置{x,y}に対応する画像を返す．

ImageForwardTransformation[image,function,size]

指定された大きさの画像を返す．

ImageForwardTransformation[video,…]

動画のフレームを変換する．

詳細とオプション

  • ImageForwardTransformation[image, f]は，前方変換として知られるもので，image の位置{x,y}にある画素すべを出力画像の位置 f[{x,y}]に変換する．
  • ImageForwardTransformation[image,function]はもとの画像と同じ大きさの画像を返す．
  • ImageForwardTransformationは任意の二次元画像に使うことができる．
  • もとの画像の画素位置は水平方向が0から1まで，垂直方向が0から縦横比までの範囲であると想定される．
  • 次は，size の可能な設定である．
  • Automatic自動画像サイズ
    All入力の画像サイズと同じ
    width明示的な width，高さは自動
    {width,height}明示的な width と height
    {width,depth,height}3Dで，明示的な width，depth，height
  • width，depth，height の可能な指定については，ImageResizeの関数ページを参照のこと．
  • 可能な size 指定についてはImageResizeの説明を参照のこと．
  • ImageForwardTransformationの可能なオプション
  • Background Black背景の値
    DataRange Automaticもとの画像中の と の値の仮定される範囲
    Method Automatic使用する補間法
    PlotRange Automatic変換結果に含まれる座標範囲
  • DataRangeのよく使われる設定値
  • Automatic2Dでは{{0,1},{0,h/w}}，3Dでは{{0,1},{0,d/w},{0,h/w}}
    Full2Dでは{{0,w},{0,h}}，3Dでは{{0,1},{0,d},{0,h}}
    {{left,right},{bottom,top}}2Dにおける明示的な座標範囲
    {{left,right},{front,back},{bottom,top}}3Dにおける明示的な座標範囲
  • 結果の画像の座標系はPlotRangeオプションで指定される．次はよく使われる設定値である．
  • AutomaticDataRangeの設定と同じ
    All変換された全画素を含もうとする
    Full入力画像と同じ範囲
    {{left,right},…}明示的な座標範囲
  • PlotRangeがAutomatic以外のとき，size はもとの画像の大きさとPlotRangeとDataRangeの比に基づいて選ばれる．
  • デフォルトで，変換された点はMethod->"Interpolated"を使って補間される．MethodNoneを使って補間を避けることができる．

例題

すべて開く すべて閉じる

例  (1)

画像に前方変換を適用する：

Wolfram Language code: ImageForwardTransformation[[image], # ^ 2&]

スコープ  (8)

データ  (3)

グレースケールの画像を変換する：

Wolfram Language code: ImageForwardTransformation[[image], # ^ 2&]

カラー画像を変換する：

Wolfram Language code: ImageForwardTransformation[[image], # ^ 2&]

動画のフレームを変換する：

Wolfram Language code: ImageForwardTransformation[\!\(\*VideoBox["![Video Player: ExampleData/fish.mp4](video://content-83a60)"]\), # ^ 2&]

変換  (4)

変換に任意の関数を使う：

Wolfram Language code: i = [image];
Wolfram Language code: ImageForwardTransformation[i, Cos[Pi / 2 #]&]
Wolfram Language code: ImageForwardTransformation[i, ArcSin[ # ^ 4]&]
Wolfram Language code: ImageTransformation[i, FractionalPart[3# Total[#]] ^ 1.5&]
Wolfram Language code: ImageForwardTransformation[i, # Total[#]&]

画素と 画素の位置を明示的に操作する：

Wolfram Language code: i = [image];
Wolfram Language code: ImageForwardTransformation[i, {#[[1]] ^ 2, #[[2]] #[[1]]}&]

垂直次元のみを操作する：

Wolfram Language code: ImageForwardTransformation[i, {#[[1]], 1 - Sqrt[#[[2]]]}&]

行列変換を行う：

Wolfram Language code: ImageForwardTransformation[[image], {{(1/2), (1/4)}, {1, -(1/2)}}.#&]

幾何変換関数を使う：

Wolfram Language code: ImageForwardTransformation[[image], ReflectionTransform[{1, -1}]]

回転変換を使って画像をその中心を中心にして回転させる：

Wolfram Language code: ImageForwardTransformation[[image], RotationTransform[35°, {0.5, 0.5}]]

サイズ  (1)

デフォルトで，出力画像のサイズは入力画像と同じである：

Wolfram Language code: i = [image];
Wolfram Language code: ImageForwardTransformation[i, # ^ 2&]
Wolfram Language code: ImageDimensions[i] == ImageDimensions[%]

結果の画像のサイズを指定する：

Wolfram Language code: ImageForwardTransformation[i, # ^ 2&, 100]

幅と高さを明示的に指定する：

Wolfram Language code: ImageForwardTransformation[i, # ^ 2&, {200, 100}]

スケールされた値を使う：

Wolfram Language code: ImageForwardTransformation[i, # ^ 2&, Scaled[0.5]]

名前付きのサイズを使う：

Wolfram Language code: ImageForwardTransformation[i, # ^ 2&, Tiny]

Allを使ってもとの画像と同じ大きさのものを得る：

Wolfram Language code: ImageForwardTransformation[[image], RotationTransform[45°, {0.5, 0.5}], #, PlotRange -> (⁠| | | | ------------------- | ------------------ | | (1/2) (1 - Sqrt[2]) | (1/2)(1 + Sqrt[2]) | | (1/2) (1 - Sqrt[2]) | (1/2)(1 + Sqrt[2]) |⁠)]& /@ {All, Automatic}

オプション  (4)

Background  (1)

デフォルトで，黒い背景が使われる：

Wolfram Language code: i = [image]; ImageForwardTransformation[i, RotationTransform[-20]]

背景に特定の色を使う：

Wolfram Language code: ImageForwardTransformation[i, RotationTransform[-20], Background -> Red]

透明な背景を使う：

Wolfram Language code: ImageForwardTransformation[i, RotationTransform[-20Degree], Background -> Transparent]

DataRange  (1)

デフォルトで，DataRange->Automaticが使われる：

Wolfram Language code: i = [image];
Wolfram Language code: ImageForwardTransformation[i, TranslationTransform[{-0.2, -0.2}], DataRange -> Automatic]

画素座標で平行移動を定義するときは，DataRange->Fullを使う：

Wolfram Language code: ImageForwardTransformation[i, TranslationTransform[{50, 50}], DataRange -> Full]

カスタムのDataRangeを使う：

Wolfram Language code: ImageForwardTransformation[i, TranslationTransform[{-0.2, -0.2}], DataRange -> {{0, 1}, {0, 0.5}}]

軸について対称なデータ範囲を選んで垂直鏡映を表示する：

Wolfram Language code: ImageForwardTransformation[i, ReflectionTransform[{0, 1}], DataRange -> #]& /@ {Automatic, {Automatic, {-.5, .5}}}

画像の全画素が入るようにプロット範囲を調整する：

Wolfram Language code: ImageForwardTransformation[i, # + 50&, DataRange -> Full, PlotRange -> Transpose@{{0, 0}, ImageDimensions@i + 50}]

Method  (1)

デフォルトで，変換された点は結果の画像の潜在的なギャップを埋めるために補間される：

Wolfram Language code: i = [image]; ImageForwardTransformation[i, # ^ 2&]

Method->Noneを使って補間されないようにする：

Wolfram Language code: ImageForwardTransformation[i, # ^ 2&, Method -> None]

PlotRange  (1)

デフォルトで，出力画像には入力画像のプロット範囲が残される：

Wolfram Language code: i = [image]; ImageForwardTransformation[i, RotationTransform[-45°]]

PlotRange->Allを使って変換された画像のすべての画素を見る：

Wolfram Language code: ImageForwardTransformation[i, RotationTransform[-45°], PlotRange -> All]

明示的なプロット範囲の値を使う：

Wolfram Language code: ImageForwardTransformation[i, RotationTransform[-45°], PlotRange -> {{0, Sqrt[2]}, {-(1/Sqrt[2]), Sqrt[2] - (1/Sqrt[2])}}]

PlotRangeFullオプションで画素座標を使う：

Wolfram Language code: ImageForwardTransformation[i, RotationTransform[35°, ImageDimensions[i] / 2], PlotRange -> Full]

アプリケーション  (3)

画像のペアから変換関数を決定することで，未知の幾何変換を反転させる：

Wolfram Language code: i = [image];j = [image]; tf = FindGeometricTransform[i, j, TransformationClass -> "Rigid"][[2]]

変換された画像に変換を適用する：

Wolfram Language code: ImageForwardTransformation[j, tf, DataRange -> Full]

画像をモザイクにする：

Wolfram Language code: ImageForwardTransformation[[image], 8.3Floor[# / 8] + 1&, DataRange -> All]

汚れ効果：

Wolfram Language code: ImageForwardTransformation[[image], # + .1Floor[10#]&, 200, PlotRange -> All]

特性と関係  (3)

画像を拡大する：

Wolfram Language code: ImageForwardTransformation[[image], 1.5#&]

ImageTransformationはその逆を行う：

Wolfram Language code: ImageTransformation[[image], 1.5#&]

画素の座標を反転させることは，前方変換および逆変換と同じ結果を与える操作である：

Wolfram Language code: ImageForwardTransformation[[image], Reverse]
Wolfram Language code: ImageTransformation[[image], Reverse]

関数とその逆関数を使った変換を行うと，補間によって少しぼやけたもとの画像が与えられる：

Wolfram Language code: ImageForwardTransformation[ImageForwardTransformation[[image], Sqrt], # ^ 2&]

おもしろい例題  (3)

魚眼効果：

Wolfram Language code: i = [image]; f[x_, y_, c_] := With[{r = N@Sqrt[(x - c[[1]]) ^ 2 + (y - c[[2]]) ^ 2], a = ArcTan[x - c[[1]], y - c[[2]]], R = Min[c]}, rn = Sqrt[r * R]; {rn * Cos[a] + c[[1]], rn * Sin[a] + c[[2]]}] ImageForwardTransformation[i, f[#[[1]], #[[2]], ImageDimensions[i] / 2]&, DataRange -> Full, Background -> None]

メルティング効果：

Wolfram Language code: ImageForwardTransformation[[image], {#[[1]], #[[2]] - RandomReal[] * 30}&, PlotRange -> Full]

多数の鏡面による効果：

Wolfram Language code: img = [image]; f[x_, y_, c_] := With[{r = N@Sqrt[(x - c[[1]]) ^ 2 + (y - c[[2]]) ^ 2], a = ArcTan[x - c[[1]], y - c[[2]]] / Pi * 180}, {x + Mod[(a + r / 2.), 16] - 8, y}]; ImageForwardTransformation[img, f[#[[1]], #[[2]], ImageDimensions[img] / 2.]&, DataRange -> Full]
Wolfram Research (2010), ImageForwardTransformation, Wolfram言語関数， https://reference.wolfram.com/language/ref/ImageForwardTransformation.html （2021年に更新）.

テキスト

Wolfram Research (2010), ImageForwardTransformation, Wolfram言語関数， https://reference.wolfram.com/language/ref/ImageForwardTransformation.html （2021年に更新）.

CMS

Wolfram Language. 2010. "ImageForwardTransformation." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2021. https://reference.wolfram.com/language/ref/ImageForwardTransformation.html.

APA

Wolfram Language. (2010). ImageForwardTransformation. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/ImageForwardTransformation.html

BibTeX

@misc{reference.wolfram_2026_imageforwardtransformation, author="Wolfram Research", title="{ImageForwardTransformation}", year="2021", howpublished="\url{https://reference.wolfram.com/language/ref/ImageForwardTransformation.html}", note=[Accessed: 03-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_imageforwardtransformation, organization={Wolfram Research}, title={ImageForwardTransformation}, year={2021}, url={https://reference.wolfram.com/language/ref/ImageForwardTransformation.html}, note=[Accessed: 03-November-2026]}