WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

Insert[list,elem,n]

list の位置 n に要素 elem を挿入する．n が負の場合，この位置は末尾から数えられる．

Insert[expr,elem,{i,j,…}]

式 expr の位置{i,j,…}に要素 elem を挿入する．

Insert[expr,elem,{{i1,j1,…},{i2,j2,…},…}]

複数の位置に要素 elem を挿入する．

Insert[elem,pos]

式に適用可能なInsertの演算子形を表す．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
位置指定  
連想  
アプリケーション  
特性と関係  
関連項目
テクニカルノート
関連するガイド
関連リンク
履歴
引用書式

Insert

Insert[list,elem,n]

list の位置 n に要素 elem を挿入する．n が負の場合，この位置は末尾から数えられる．

Insert[expr,elem,{i,j,…}]

式 expr の位置{i,j,…}に要素 elem を挿入する．

Insert[expr,elem,{{i1,j1,…},{i2,j2,…},…}]

複数の位置に要素 elem を挿入する．

Insert[elem,pos]

式に適用可能なInsertの演算子形を表す．

詳細

  • 位置 n が正の整数として与えられた場合，新規要素は位置 n にある要素の前に挿入される．n が負の数の場合，新規要素は既存のものの後ろに挿入される． »
  • list の頭部はListである必要はなく，任意のものが与えられる． »
  • expr の長さが l のとき，Insert[expr,elem,l+1]は elem を末尾に加える．これとは逆に，Insert[expr,elem,-l-1]は elem を先頭に加える． »
  • expr がAssociationオプジェクトのとき，Insert[expr,key->value,pos]は連想に要素を挿入する．
  • 連想に挿入する際は，位置がKey[k]あるいは短縮形の"key"として追加的に加えられることがある． »
  • 挿入する要素のキーがすでに存在する場合は，同じキーを持つ古い要素が削除される． »
  • Insertは，事実上対応する通常のリストに挿入することで，SparseArrayオブジェクトに使うことができる．
  • Insert[elem,pos][expr]はInsert[expr,elem,pos]に等しい．

例題

すべて開く すべて閉じる

例  (5)

3番目の位置の前にxを挿入する：

Wolfram Language code: Insert[{a, b, c, d, e}, x, 3]

後ろから2番目の位置の後ろにxを挿入する：

Wolfram Language code: Insert[{a, b, c, d, e}, x, -2]

xを，最初の要素の前，3番目の要素の前，最後の要素の後ろに挿入する：

Wolfram Language code: Insert[{a, b, c, d, e}, x, {{1}, {3}, {-1}}]

連想の場合，位置はKeyを使って指定できる：

Wolfram Language code: Insert[<|a -> 1, b -> 2|>, c -> 3, Key[a]]

任意の頭部を持つ式に挿入する：

Wolfram Language code: Insert[f[a, b, c, d], x, 2]

スコープ  (11)

位置指定  (5)

単一の，よリ深い位置に挿入する：

Wolfram Language code: Insert[{{a, b}, {c, d}}, x, {1, 2}]

任意の式の任意の位置に挿入する：

Wolfram Language code: 1 + x ^ (a + b) + y ^ (c + d)
Wolfram Language code: Insert[%, zzz, {3, 2, 3}]

行列の位置{1,3}に挿入して最初の行を4要素の長さにする：

Wolfram Language code: mat = {{a, b, c}, {d, e, f}, {g, h, i}};
Wolfram Language code: Insert[mat, x, {1, 3}]

行列の最初と3番目の部分（行）の前に挿入する：

Wolfram Language code: Insert[mat, x, {{1}, {3}}]

行列にいくつかの要素を挿入して3×4行列にする：

Wolfram Language code: Insert[mat, x, {{1, 2}, {3, 3}, {2, 1}}]

Insertの演算子形を定義して，複数の式に使う：

Wolfram Language code: op = Insert[x, 3];
Wolfram Language code: op /@ {Range[3], {a, b, c}, {i, j, k, l}}

単一の指定で整数部分とKey[key]部分を混ぜる：

Wolfram Language code: Insert[{<|a -> 1, b -> 2|>, <|a -> 2, b -> 4|>}, x -> Infinity, {1, Key[a]}]

連想  (6)

文字列のキーの場合，Keyラッパーは使わなくてもよい：

Wolfram Language code: Insert[<|"a" -> 1, "b" -> 2|>, "c" -> 3, "b"]
Wolfram Language code: % === Insert[<|"a" -> 1, "b" -> 2|>, "c" -> 3, Key["b"]]

2番目の位置の前に挿入する：

Wolfram Language code: Insert[<|2 -> {a, b}, 1 -> {c, d}|>, 3 -> {e, f}, 2]

キー2の前に挿入する：

Wolfram Language code: Insert[<|2 -> {a, b}, 1 -> {c, d}|>, 3 -> {e, f}, Key[2]]

複数の要素を挿入する：

Wolfram Language code: Insert[<|a -> 1, b -> 2|>, {c -> 3, d -> 4}, Key[a]]

Association中のキーを繰り返す項目の挿入は，前の値を上書きする：

Wolfram Language code: Insert[<|a -> 1, b -> 2|>, a -> 3, Key[a]]

最終要素の後ろに挿入する：

Wolfram Language code: Insert[<|1 -> a, 2 -> b|>, 3 -> c, -1]

より深いレベルに挿入する：

Wolfram Language code: Insert[<|1 -> {a, b}, 2 -> {c, d}|>, x, {2, 1}]

連想の最初のレベルに挿入できるのは，規則または規則のリストだけである：

Wolfram Language code: Insert[<|a -> 1, b -> 2|>, foo, Key[a]]

アプリケーション  (1)

ホールドされている式に挿入する：

Wolfram Language code: Insert[Hold[x + x], y, {1, 2}]

未評価の式をホールドされた式に挿入する：

Wolfram Language code: Insert[Hold[x + x], Unevaluated[1 + 1], {1, 2}]

特性と関係  (7)

挿入位置が正のとき，新規要素は既存の要素の前に挿入される：

Wolfram Language code: Insert[{a, b, c}, x, 2]

挿入位置が負のとき，新規要素は既存の要素の後ろに置かれる：

Wolfram Language code: Insert[{a, b, c}, x, -2]

有効な正の位置の範囲は1からLength[expr]+1までである：

Wolfram Language code: expr = {1, 2, 3};
Wolfram Language code: Table[Insert[expr, x, k], {k, 1, Length[expr] + 1}]

有効な負の位置の範囲は-1 から-Length[expr]-1までである：

Wolfram Language code: Table[Insert[expr, x, k], {k, -1, -Length[expr] - 1, -1}]

挿入位置は，常にもとの式の位置を参照する：

Wolfram Language code: Insert[{a, b, c}, x, {{1}, {3}}]

したがって，指定の挿入位置に出現することが保証されるのは最初の挿入のみである：

Wolfram Language code: Position[%, x]

位置が繰り返された場合は，その位置に複数の挿入が行われる：

Wolfram Language code: Insert[{a, b, c}, x, {{1}, {1}, {1}}]

これを使って既存の要素を新しい要素で囲むことができる：

Wolfram Language code: Insert[{a, b, c}, x, {{1}, {-3}}]

Insert[elem,1]はPrepend[elem]に等しい：

Wolfram Language code: list = {a, b, c}; Insert[x, 1][{a, b, c}] === Prepend[x][{a, b, c}]

Insert[elem,-1]はAppend[elem]に等しい：

Wolfram Language code: list = {a, b, c}; Insert[x, -1][{a, b, c}] === Append[x][{a, b, c}]

Insertは，Positionが返すような位置指定を取る：

Wolfram Language code: expr = {1, two, <|a -> {3}|>};
Wolfram Language code: Position[expr, _Integer]
Wolfram Language code: Insert[expr, "an integer follows", %]
Wolfram Research (1988), Insert, Wolfram言語関数， https://reference.wolfram.com/language/ref/Insert.html （2014年に更新）.

テキスト

Wolfram Research (1988), Insert, Wolfram言語関数， https://reference.wolfram.com/language/ref/Insert.html （2014年に更新）.

CMS

Wolfram Language. 1988. "Insert." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2014. https://reference.wolfram.com/language/ref/Insert.html.

APA

Wolfram Language. (1988). Insert. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Insert.html

BibTeX

@misc{reference.wolfram_2026_insert, author="Wolfram Research", title="{Insert}", year="2014", howpublished="\url{https://reference.wolfram.com/language/ref/Insert.html}", note=[Accessed: 31-October-2026]}

BibLaTeX

@online{reference.wolfram_2026_insert, organization={Wolfram Research}, title={Insert}, year={2014}, url={https://reference.wolfram.com/language/ref/Insert.html}, note=[Accessed: 31-October-2026]}