JacobiZeta

JacobiZeta[ϕ,m]

ヤコビのゼータ関数を与える．

詳細

記号操作・数値操作の両方に適した数学関数である．
ヤコビのゼータ関数は，によって楕円積分で与えられる．
楕円積分の記述用法については「楕円積分と楕円関数」で解説してある．
JacobiZeta[ϕ,m]は，およびで不連続な分枝切断線を持つ．
特別な引数の場合，JacobiZetaは，自動的に厳密値を計算する．
JacobiZetaは任意の数値精度で評価できる．
JacobiZetaは自動的にリストに縫い込まれる．
JacobiZetaはIntervalオブジェクトおよびCenteredIntervalオブジェクトに使うことができる． »

例題

すべて開くすべて閉じる

例 (4)

数値的に評価する：

Wolfram Language code: JacobiZeta[2, 0.5]

実数の部分集合上でプロットする：

Wolfram Language code: Plot[JacobiZeta[z, 0.5], {z, -5, 5}]

複素数の部分集合上でプロットする：

Wolfram Language code: ComplexPlot3D[JacobiZeta[z, 1 / 3], {z, -2 - 2I, 2 + 2I}, PlotLegends -> Automatic]

原点付近の級数展開：

Wolfram Language code: Series[JacobiZeta[z, m], {z, 0, 4}]

スコープ (30)

数値評価 (5)

高精度で評価する：

Wolfram Language code: N[JacobiZeta[2, 3], 30]

出力精度は入力精度に従う：

Wolfram Language code: JacobiZeta[2, 3.0000000000000000000000]

複素引数とパラメータについて評価する：

Wolfram Language code: JacobiZeta[2 + 3 I, 0.8I]

JacobiZetaを高精度で効率よく評価する：

Wolfram Language code: JacobiZeta[2, 0.3`500]//Timing

Wolfram Language code: JacobiZeta[2, 0.3`100000];//Timing

IntervalオブジェクトとCenteredIntervalオブジェクトを使って最悪の場合に保証される区間を計算する：

Wolfram Language code: JacobiZeta[0.2, Interval[{0.34, 0.35}]]

Wolfram Language code: JacobiZeta[1 / 2, CenteredInterval[1 / 3, 1 / 100]]

Aroundを使って平均的な場合の統計区間を計算することもできる：

Wolfram Language code: JacobiZeta[Pi / 4, Around[1 / 2, 0.01]]

配列の要素ごとの値を計算する：

Wolfram Language code: JacobiZeta[1.5, {{1, 1.2}, {2, 1.6}}]

MatrixFunctionを使って行列のJacobiZeta関数を計算することもできる：

Wolfram Language code: MatrixFunction[JacobiZeta[1.5, #]&, {{1, 1.2}, {2, 1.6}}]

特定の値 (5)

簡単な厳密結果は自動的に生成される：

Wolfram Language code: JacobiZeta[ϕ, 0]

Wolfram Language code: JacobiZeta[Pi / 2, m]

FunctionExpandの後の厳密値が適用される：

Wolfram Language code: {JacobiZeta[Pi / 3, 1], JacobiZeta[Pi / 4, 1], JacobiZeta[Pi / 5, 1]}//FunctionExpand

無限大における値：

Wolfram Language code: JacobiZeta[ϕ, Infinity]

極大値をの根として求める：

Wolfram Language code: xmax = Solve[D[JacobiZeta[ϕ, 1 / 2], ϕ] == 0 && 1 / 2 < ϕ < 2, ϕ][[1, 1, 2]]//FullSimplify

Wolfram Language code: Plot[JacobiZeta[ϕ, 0.5], {ϕ, -3, 3}, Epilog -> Style[Point[{xmax, JacobiZeta[xmax, 0.5]}], PointSize[Large], Red]]

JacobiZetaは，その第1引数について奇関数である：

Wolfram Language code: JacobiZeta[-ϕ, m]

可視化 (3)

JacobiZetaを第1パラメータの関数としてプロットする：

Wolfram Language code: Plot[{JacobiZeta[ϕ, 3 / 10], JacobiZeta[ϕ, 8 / 9], JacobiZeta[ϕ, 1]}, {ϕ, -4, 4}]

JacobiZetaをその第2パラメータの関数としてプロットする：

Wolfram Language code: Plot[{JacobiZeta[-π / 3, m], JacobiZeta[π / 3, m]}, {m, -6, 1}]

の実部をプロットする：

Wolfram Language code: ComplexContourPlot[Re[JacobiZeta[π / 3, z]], {z, -5 - 5I, 5 + 5I}, Contours -> 24]

の虚部をプロットする：

Wolfram Language code: ComplexContourPlot[Im[JacobiZeta[π / 3, z]], {z, -5 - 5I, 5 + 5I}, Contours -> 24]

関数の特性 (6)

JacobiZetaは解析関数ではない：

Wolfram Language code: FunctionAnalytic[JacobiZeta[x, y], {x, y}]

しかし，固定されたについては，はの解析関数である：

Wolfram Language code: FunctionAnalytic[JacobiZeta[x, y], x, Assumptions -> y < 1]

従って，例えばは特異点も不連続点も持たない：

Wolfram Language code: FunctionSingularities[JacobiZeta[x, 1 / 3], x]

Wolfram Language code: FunctionDiscontinuities[JacobiZeta[x, 1 / 3], x]

は非減少でも非増加でもない：

Wolfram Language code: FunctionMonotonicity[JacobiZeta[x, 1 / 3], x]

は単射ではない：

Wolfram Language code: FunctionInjective[JacobiZeta[x, 1 / 3], x]

Wolfram Language code: Plot[{JacobiZeta[x, 1 / 3], .05}, {x, -5, 5}]

は全射ではない：

Wolfram Language code: FunctionSurjective[JacobiZeta[x, 1 / 3], x]

Wolfram Language code: Plot[{JacobiZeta[x, 1 / 3], .15}, {x, -5, 5}]

は非負でも非正でもない：

Wolfram Language code: FunctionSign[JacobiZeta[x, 1 / 2], x]

は凸でも凹でもない：

Wolfram Language code: FunctionConvexity[JacobiZeta[x, 1 / 2], x]

微分と積分 (4)

一次導関数：

Wolfram Language code: D[JacobiZeta[ϕ, m], ϕ]

高次導関数：

Wolfram Language code: derivs = Table[D[JacobiZeta[ϕ, m], {ϕ, n}], {n, 1, 3}]//FullSimplify

について高次導関数をプロットする：

Wolfram Language code:

Plot[Evaluate[derivs /. m -> 0.5], {ϕ, -π, π}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative"}]

第2パラメータについての導関数：

Wolfram Language code: D[JacobiZeta[ϕ, m], m]

原点を中心とする区間上での奇関数の定積分：

Wolfram Language code: Integrate[JacobiZeta[ϕ, m], {ϕ, -3, 3}]

級数展開 (4)

JacobiZetaのテイラー(Taylor)展開：

Wolfram Language code: Series[JacobiZeta[ϕ, m], {ϕ, 0, 5}]//FullSimplify

の周りのの最初の3つの近似をプロットする：

Wolfram Language code:

terms = Normal@Table[Series[JacobiZeta[ϕ, 1 / 2], {ϕ, 0, n}], {n, 1, 5, 2}];
Plot[{JacobiZeta[ϕ, 0.5], terms}, {ϕ, -2, 2}]

パラメータについての原点でのテイラー展開：

Wolfram Language code: Series[JacobiZeta[ϕ, m], {m, 0, 3}]

の周りのの最初の3つの近似をプロットする：

Wolfram Language code:

terms = Normal@Table[Series[JacobiZeta[-π / 3, m], {m, 0, n}], {n, 1, 3}];
Plot[{JacobiZeta[-π / 3, m], terms}, {m, -2, 1}]

分岐点での級数展開を求める：

Wolfram Language code: Series[JacobiZeta[ϕ, m], {m, 1, 0}, Assumptions -> m > 1]

JacobiZetaはベキ級数に適用できる：

Wolfram Language code: JacobiZeta[ϕ, m + (m^2/2) + (m^3/3) + O[m]^4]

関数表現 (3)

主定義：

Wolfram Language code: JacobiZeta[ϕ, m] == EllipticE[ϕ, m] - (EllipticE[m] /EllipticK[m])EllipticF[ϕ, m]//FullSimplify

他の楕円型関数との関係：

Wolfram Language code:

JacobiZeta[z, m] == (1 - m) EllipticPi[m, z, m] - (EllipticE[m] /EllipticK[m])EllipticPi[0, z, m] + (m Sin[2 z]/2 Sqrt[1 - m Sin[z]^2])//FullSimplify

TraditionalFormによる表示：

Wolfram Language code: JacobiZeta[z, m]//TraditionalForm

アプリケーション (3)

複素平面上におけるJacobiZetaの実部のプロット：

Wolfram Language code: Plot3D[Re[JacobiZeta[x + I y, 0.3]], {x, -5, 5}, {y, -2, 2}]

周期的ポテンシャルにおけるシュレディンガー(Schrödinger)方程式の超対称零エネルギー解：

Wolfram Language code: w[x_] := m^2JacobiSN[x, m]^2JacobiCD[x, m]^2 - (2 - m - (2 EllipticE[m]/EllipticK[m]));

Wolfram Language code: v[x_] = w[x]^2 + w'[x];

Wolfram Language code: ψ0[x_] := Exp[m JacobiCD[x, m] JacobiSN[x, m] - 2 JacobiZeta[JacobiAmplitude[x, m], m]] / 10

シュレディンガー方程式をチェックする：

Wolfram Language code: -D[ψ0[x], x, x] + v[x] ψ0[x] /. m -> 1 / 3 /. x -> 2`100

超ポテンシャル，ポテンシャル，波動関数をプロットする：

Wolfram Language code: Plot[Evaluate[{w[x], v[x], ψ0[x]} /. m -> 0.8], {x, 0, 6}]

等角写像を定義する：

Wolfram Language code: z[w_, m_] := JacobiZeta[JacobiAmplitude[w, m], m] + w Pi / (EllipticK[m] EllipticK[1 - m])

Wolfram Language code: ParametricPlot[{Re[#], Im[#]}&[z[u + I v, 0.4]], {u, 0.01, EllipticK[0.39]}, {v, 0.01, EllipticK[0.59]}, Mesh -> 15]

特性と関係 (5)

FunctionExpandを使ってJacobiZetaを不完全楕円積分について表す：

Wolfram Language code: FunctionExpand[JacobiZeta[z, m]]

特殊ケースを展開する：

Wolfram Language code: {JacobiZeta[z, 1] , JacobiZeta[z, 1] , JacobiZeta[ArcCsc[Sqrt[m]], m]}

Wolfram Language code: FunctionExpand[%]

ある種の特殊ケースでは引数を制限する必要がある：

Wolfram Language code: JacobiZeta[z, 1]

Wolfram Language code: FunctionExpand[%]

Wolfram Language code: FunctionExpand[%, 0 < z < Pi / 2]

超越方程式の根を数値的に求める：

Wolfram Language code: FindRoot[JacobiZeta[z, 2]^3 + JacobiZeta[z, 2] + z == 2, {z, I}]

実数引数については，ならについてJacobiZN[u,m]JacobiZeta[ϕ,m]である：

Wolfram Language code:

With[{m = 1 / 3}, {ParametricPlot[{ϕ, JacobiZeta[ϕ, m]}, {ϕ, -Pi, Pi}, PlotStyle -> Thick, AspectRatio -> 1], ParametricPlot[{JacobiAmplitude[u, m], JacobiZN[u, m]}, {u, -2EllipticK[m], 2EllipticK[m]}, PlotStyle -> Directive[Dashed, Orange], AspectRatio -> 1]}]

Wolfram Language code: Show[%, ImageSize -> Tiny]

JacobiZeta[ϕ,m]は，実数引数については，を条件として実数値である：