WOLFRAM

Wolfram 语言与系统参考资料中心

JuliaSetPoints[f,z]

返回坐标列表，这些坐标列表逼近变量 z 的有理函数 f 的朱莉亚集合中复数的实部和虚部.

JuliaSetPoints[c]

返回逼近函数 的朱莉亚集合的点的坐标列表.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
选项  
"ClosenessTolerance"  
"Bound"  
属性和关系  
可能存在的问题  
互动范例  
巧妙范例  
参见
相关指南
历史
按以下格式引用：

JuliaSetPoints

JuliaSetPoints[f,z]

返回坐标列表，这些坐标列表逼近变量 z 的有理函数 f 的朱莉亚集合中复数的实部和虚部.

JuliaSetPoints[c]

返回逼近函数 的朱莉亚集合的点的坐标列表.

更多信息和选项

  • 函数 f 的朱莉亚集合是 f 的所有发散固定点集合的闭集.
  • JuliaSetPoints 使用与 JuliaSetPlot 相同的 "InverseIteration" 算法.
  • JuliaSetPoints 具有选项：
  • "ClosenessTolerance" 0.004点之间的最小距离
    "Bound" 6沿着原点的搜索半径
  • 对于多项式函数，自动判断 "Bound" 以确保捕获整个朱莉亚集合.

范例

打开所有单元 关闭所有单元

基本范例  (2)

求 的朱莉亚集合的点：

Wolfram Language code: JuliaSetPoints[-0.77 + 0.22I]
Wolfram Language code: ListPlot[%]

求 朱莉亚集合的点：

Wolfram Language code: JuliaSetPoints[(z ^ 2 - 1) / (z ^ 2 + 1), z]
Wolfram Language code: ListPlot[%]

范围  (2)

JuliaSetPoints[c] 产生形式为 的函数的朱莉亚集合：

Wolfram Language code: JuliaSetPoints[-0.77 + 0.22I]

JuliaSetPoints[f,z] 生成多项式或更多广义有理函数的朱莉亚集合：

Wolfram Language code: ListPlot@JuliaSetPoints[z ^ 3 - z - 1, z]
Wolfram Language code: ListPlot@JuliaSetPoints[z ^ 2 / (z ^ 2 - 1), z]

选项  (2)

"ClosenessTolerance"  (1)

增加 "ClosenessTolerance"，获取朱莉亚集合快速的低分辨率图片：

Wolfram Language code: AbsoluteTiming[ListPlot[JuliaSetPoints[0.37 + 0.22I, "ClosenessTolerance" -> .05]]]
Wolfram Language code: AbsoluteTiming[ListPlot@JuliaSetPoints[0.37 + 0.22I]]

减小 "ClosenessTolerance" 获取朱莉亚集合小部分的高分辨率图片：

Wolfram Language code: {ListPlot[JuliaSetPoints[-0.77 + 0.22I], PlotRange -> {{0.8, .9}, {.2, .3}}], ListPlot[JuliaSetPoints[-0.77 + 0.22 I, "ClosenessTolerance" -> .001], PlotRange -> {{0.8, .9}, {.2, .3}}]}

"Bound"  (1)

对某些有理函数，增加 "Bound" 可以找到更多点：

Wolfram Language code: {ListPlot[JuliaSetPoints[(2z ^ 3 + 1) / (3z ^ 2), z], PlotRange -> {{-10, 10}, {-10, 10}}], ListPlot[JuliaSetPoints[(2z ^ 3 + 1) / (3z ^ 2), z, "Bound" -> 13], PlotRange -> {{-10, 10}, {-10, 10}}]}

属性和关系  (2)

JuliaSetPlot[c] 本质上是生成 JuliaSetPoints[c] 结果的 ListPlot ：

Wolfram Language code: JuliaSetPlot[-0.77 + 0.22I]
Wolfram Language code: ListPlot[JuliaSetPoints[-0.77 + 0.22I]]

JuliaSetPoints[c] 类似于 JuliaSetPoints[z^2+c,z]：

Wolfram Language code: JuliaSetPoints[-.6 - .5I] === JuliaSetPoints[z ^ 2 - .6 - .5I, z]

可能存在的问题  (1)

如果 "Bound" 选项值对于有理函数太低的话，不会返回点：

Wolfram Language code: JuliaSetPoints[(500 / z ^ 2 - 1), z]
Wolfram Language code: JuliaSetPoints[(500 / z ^ 2 - 1), z, "Bound" -> 9] //ListPlot

用这种方法，某些很大的朱莉亚集合会花很长的时间进行计算：

Wolfram Language code: AbsoluteTiming[JuliaSetPoints[(z ^ 2 - 5 / 19/z ^ 2 + 5 / 19), z]][[1]]

互动范例  (1)

探索参数 c 在单位圆上的朱莉亚集合：

Wolfram Language code: Animate[ListPlot@JuliaSetPoints[Exp[c Pi I], "ClosenessTolerance" -> .02], {{c, 0, "c"}, 0, 2 Pi, 2 Pi / 180}]

巧妙范例  (3)

连续堆栈朱莉亚集合的更精细逼近：

Wolfram Language code: Graphics3D[ Table[{Hue[10 δ], Sphere[Append[#, -δ ^ 2 100], δ]& /@ JuliaSetPoints[0.37 + 0.22I, "ClosenessTolerance" -> δ]}, {δ, 0.1, 0.01, -0.01}]]

通过变化参数添加维数：

Wolfram Language code: Graphics3D[{Specularity[White, 30], Orange, Table[Sphere[Append[#, 1.c]& /@ JuliaSetPoints[1 / (z ^ 3 - c z ^ 2 + 1), z, "ClosenessTolerance" -> 0.01], 0.01], {c, 0, 1.3, 1 / 22}]}]

通过给定单位圆上的部分点可视化朱莉亚集合：

Wolfram Language code: Graphics[{Opacity[0.25], PointSize[0.002], Table[{Hue[ξ / 1.6], Point[JuliaSetPoints[Exp[ξ Pi I]]]}, {ξ, 0, 1, 1 / 18}]}]
Wolfram Research (2014)，JuliaSetPoints，Wolfram 语言函数，https://reference.wolfram.com/language/ref/JuliaSetPoints.html.

文本

Wolfram Research (2014)，JuliaSetPoints，Wolfram 语言函数，https://reference.wolfram.com/language/ref/JuliaSetPoints.html.

CMS

Wolfram 语言. 2014. "JuliaSetPoints." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/JuliaSetPoints.html.

APA

Wolfram 语言. (2014). JuliaSetPoints. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/JuliaSetPoints.html 年

BibTeX

@misc{reference.wolfram_2026_juliasetpoints, author="Wolfram Research", title="{JuliaSetPoints}", year="2014", howpublished="\url{https://reference.wolfram.com/language/ref/JuliaSetPoints.html}", note=[Accessed: 07-July-2026]}

BibLaTeX

@online{reference.wolfram_2026_juliasetpoints, organization={Wolfram Research}, title={JuliaSetPoints}, year={2014}, url={https://reference.wolfram.com/language/ref/JuliaSetPoints.html}, note=[Accessed: 07-July-2026]}