WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

LLMTool["name",params,fun]

LLMが params で記述されたパラメータに fun を作用させるために使えるツールを表す．

LLMTool[{"name","description"},params,fun]

説明を使ってLLMにプロンプトを送る．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
関連項目
関連するガイド
履歴
引用書式

LLMTool   

パラメータタイプのリスト »
この機能には次が必要です：LLMアクセス »

LLMTool["name",params,fun]

LLMが params で記述されたパラメータに fun を作用させるために使えるツールを表す．

LLMTool[{"name","description"},params,fun]

説明を使ってLLMにプロンプトを送る．

詳細

  • LLMToolは，通常，大規模言語モデル(LLM)に厳密な答あるいは最新情報を与えるために使われる．
  • LLMToolを使うと，ツールの使い方，その機能および引数について説明するLLMのプロンプトに変更が加えられる．
  • LLMは，"name"を指定することでツールを使うことができる．この"name"はLLMの使用を効果的にトリガするための実際のツールの機能を説明するものでなければならない．ツールについての追加の詳細は"description"で与えることができる．
  • ツールの呼び出しはLLMToolRequestに解析され，評価結果が文字列としてLLMに送られる．
  • params と fun の形式はAPIFunctionに似ている．
  • 次は，params の有効な形式である．
  • "name"文字列パラメータ
    "name"type型付きパラメータ
    {spec1,spec2,…}パラメータのリスト
  • 次は，type の有効な形式である．
  • "form"Interpreterがサポートする形式
    Interpreter[…]任意のInterpreterオブジェクト
    assocパラメータの扱い方についての詳細を与える連想
    tfun文字列に適用する関数
  • 次は，assoc の可能な要素である．
  • "Interpreter""String"インタープリタタイプ
    "Help"Missing[]プロンプト情報
    "Required"Trueパラメータが必要かどうか

例題

すべて開く すべて閉じる

例  (2)

文字列の文字数を数えるツールを定義する：

Wolfram Language code: tool = LLMTool["countcharacter", "string", StringLength[#string]&]

LLMの呼出しにこのツールを使う：

Wolfram Language code: LLMSynthesize["How many letters in the word \"characters\" (use the tool) ?", LLMEvaluator -> <|"Tools" -> tool|>]

都市名を使ってその年の人口を訪ねるツールを定義し，これをLLMに説明する：

Wolfram Language code: tool = LLMTool[{"cityPopulationFinder", "Query WolframAlpha to get the population of a city from its name."}, "city" -> "City", #city["Population"]&]

このツールをLLMの呼出しに使う：

Wolfram Language code: LLMSynthesize["Use the tool to write a few sentences about Chicago.", LLMEvaluator -> <|"Tools" -> tool|>]

スコープ  (3)

複数の異なる入力解釈を使ってベキ級数展開を計算するツールを定義する：

Wolfram Language code: series = LLMTool[{"series_expand", "compute taylor series of a Wolfram Expression"}, {"input" -> "Expression", "order" -> "Integer", "variable" -> "Expression"}, ToString[Normal@Series[#input, {#variable, 0, #order}], InputForm]&]

LLMに，答えるためには級数展開についてクエリしなければならない質問をする：

Wolfram Language code: LLMSynthesize["What is the tenth order coefficient of w*Sin[w] taylor expansion?", "CompletionText", LLMEvaluator -> LLMConfiguration[<|"Tools" -> series|>]]

パラメーターを都市のリストとして解釈してTravelDistance関数を公開するツールを定義する：

Wolfram Language code: trip = LLMTool[{"CityTravelDistance", "Gives the estimated distance traveling to each city in the list"}, {"cityList" -> DelimitedSequence["City", ","]}, TravelDistance[#cityList]&]

旅の最短経路を求める：

Wolfram Language code: LLMSynthesize["Going from NewYork to Boston is it shorter to pass by Springfield or Providence ?", LLMEvaluator -> <|"Tools" -> trip|>]

Wolfram言語コードを実行するためのプロンプトを含むツールを定義する：

Wolfram Language code: tool = LLMTool[{"runCode", "Run Wolfram Language code"}, "code", If[ChoiceDialog["Run this code? " <> #code], ToString[ToExpression[#code], InputForm], "Code not allowed"]&]

このツールでLLMを実行し，すべての評価特性を返す：

Wolfram Language code: data = LLMSynthesize["Which is closer to Boston: San Francisco or London? Use the tool as you write your response.", All, LLMEvaluator -> <|"Tools" -> tool|>];

LLMが書いた完成文をプロンプトとツールの呼出しを除いて取得する：

Wolfram Language code: data["CompletionText"]

ツールの呼出しを残して完成文を取得する：

Wolfram Language code: data["CompletionToolsText"]

LLMToolRequestオブジェクトとLLMToolResponseオブジェクトのリストを取得する：

Wolfram Language code: data["ToolRequests"]
Wolfram Language code: data["ToolResponses"]
Wolfram Research (2023), LLMTool, Wolfram言語関数， https://reference.wolfram.com/language/ref/LLMTool.html.

テキスト

Wolfram Research (2023), LLMTool, Wolfram言語関数， https://reference.wolfram.com/language/ref/LLMTool.html.

CMS

Wolfram Language. 2023. "LLMTool." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/LLMTool.html.

APA

Wolfram Language. (2023). LLMTool. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/LLMTool.html

BibTeX

@misc{reference.wolfram_2026_llmtool, author="Wolfram Research", title="{LLMTool}", year="2023", howpublished="\url{https://reference.wolfram.com/language/ref/LLMTool.html}", note=[Accessed: 12-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_llmtool, organization={Wolfram Research}, title={LLMTool}, year={2023}, url={https://reference.wolfram.com/language/ref/LLMTool.html}, note=[Accessed: 12-November-2026]}