WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

MatrixQ[expr]

expr が長さが等しいリストのリストのときはTrueを．そ例外の場合はFalseを返す．

MatrixQ[expr,test]

expr の各行列要素に test を適用した結果がTrueのときに限りTrueを返す．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
アプリケーション  
特性と関係  
関連項目
テクニカルノート
関連するガイド
履歴
引用書式

MatrixQ

MatrixQ[expr]

expr が長さが等しいリストのリストのときはTrueを．そ例外の場合はFalseを返す．

MatrixQ[expr,test]

expr の各行列要素に test を適用した結果がTrueのときに限りTrueを返す．

詳細

  • MatrixQ[expr]は，expr がリストであり，そのリストの各要素がリストである要素を含まない同じ長さのリストである場合，あるいはそのような指揮を表す場合にのみTrueとなる．
  • 行列は，リストの長方形リスト，深さ2の配列，または階数2の配列としても知られている．
  • 行列の表現として可能なものには以下が含まれる． »
  • {{…},{…},…}またはList[List[…],…]通常のリストのリスト
    SparseArray[…]疎行列
    CauchyMatrix[…]，PermutationMatrix[…]，QuantityArray[…]，SymmetrizedArray[…]等構造化行列
    {v1,v2,…}．ここで，VectorQ[vi]はTrueである通常のベクトル，疎ベクトル，および／または構造化ベクトルのリスト »
  • 空リスト{}は長さ 0 のベクトルであり，したがって行列ではない． »
  • test のMatrixQ[expr,test]における数値行列での使用に対する一般的な値には，次のものが含まれる．
  • NumberQexpr が明示的な数値からなる行列であるかどうかを判定する
    NumericQexpr が数値表現からなる行列であるかどうかを判定する
    Positiveexpr が正の数からなる行列であるかどうかを判定する
    RealValuedNumberQexpr が頭部Integer，RationalまたはRealを持つ数からなる行列かどうかを判定する
    RealValuedNumericQexpr が実数値を持つ数式からなる行列かどうかを判定する
  • 一般に用いられる構造テストには，次のものが含まれる．
  • IntegerQexpr が整数の行列かどうかを判定する
    PolynomialQ[#,x]&expr が x に関する多項式の行列かどうかを判定する
    QuantityQexpr が数量の行列かどうかを判定する
    StringQexpr が文字列の行列かどうかを判定する

例題

すべて開く すべて閉じる

例  (3)

オブジェクトが行列かどうかのテスト：

Wolfram Language code: MatrixQ[{{a, b}, {3, 4}}]

次は，行の長さが違うので行列ではない：

Wolfram Language code: MatrixQ[{{a, b}, {3}}]

次は，要素がリストではないので行列ではない：

Wolfram Language code: MatrixQ[{1, 2, 3}]

次は，リストが深くネストしすぎているので行列ではない：

Wolfram Language code: MatrixQ[Array[a, {2, 2, 2}]]

検定を使って特定の種類の数を制限する：

Wolfram Language code: MatrixQ[RandomReal[1, {3, 3}], NumberQ]
Wolfram Language code: MatrixQ[RandomReal[1, {3, 3}], IntegerQ]

スコープ  (8)

異なる多くの頭部で行列を表すことができる：

Wolfram Language code: MatrixQ[SparseArray[{{1, 3} -> a, {5, 1} -> b}]]
Wolfram Language code: MatrixQ[PermutationMatrix[{1, 3, 2}]]
Wolfram Language code: MatrixQ[Quantity[{{1.3, 2.2, 3.3}, {3.1, 3.3, 2.2}}, "Meters"]]

行列は，異なる表現のリストを行として持つことができる：

Wolfram Language code: m = {{1, 2, 3}, SparseArray[Automatic, {3}, 0, {1, {{0, 1}, {{3}}}, {a}}], SymmetrizedArray[StructuredArray`StructuredData[{3}, {{{1} -> c}, {}}]]}; MatrixQ[m]

行列をフォーマットする：

Wolfram Language code: m//MatrixForm

数値行を持つ行列かどうかテストする：

Wolfram Language code: MatrixQ[{{E, 1}, {π, 2}, {Sin[1], Cos[2]}}, NumericQ]

明示的な数を持つ行列かどうかテストする：Test for a matrix with explicit numbers:

Wolfram Language code: MatrixQ[{{E, 1}, {π, 2}, {Sin[1], Cos[2]}}, NumberQ]

行列が実数値の項を持つかどうかをテストする：

Wolfram Language code: MatrixQ[{{Pi, Sin[1]}, {Cos[2], E}}, RealValuedNumericQ]

実数値に関するより速いテスト：

Wolfram Language code: MatrixQ[Im[{{1, 2.}, {3 / 4, 5`20}}], RealValuedNumberQ]

整数の行列についてテストする：

Wolfram Language code: MatrixQ[{{1, 2}, {3, 4}}, IntegerQ]

小数第2位で丸めたときに整数となる数から成る行列についてテストする：

Wolfram Language code: MatrixQ[{{1, 1.005}, {1.997, 4.002}}, Abs[# - Round[#]] < 0.005&]

文字列の行列についてテストする：

Wolfram Language code: MatrixQ[{{"a", "b"}, {"c", "d"}}, StringQ]
Wolfram Language code: MatrixQ[{{"a", "b"}, {c, d}}, StringQ]

xにおける多項式の行列についてテストする：

Wolfram Language code: MatrixQ[{{1, x}, {1 + x, x ^ 2 + 2x + 1}}, PolynomialQ[#, x]&]
Wolfram Language code: MatrixQ[{{1, x}, {Sin[x], Exp[x]}}, PolynomialQ[#, x]&]

テストを使ってMatrixQを一般化する：

Wolfram Language code: MatrixQ[Array[a, {2, 2, 2}], ListQ]

テストされた式は，一般的な定義では行列ではない：

Wolfram Language code: MatrixQ[Array[a, {2, 2, 2}]]

アプリケーション  (1)

明示的な行列についてのみ評価する関数を定義する：

Wolfram Language code: hpart[m_ ? MatrixQ] := (m + ConjugateTranspose[m]) / 2

次は行列のエルミート(Hermit)部分を記号的に表す：

Wolfram Language code: hpart[a]

次は，エルミート部分を明示的に返す：

Wolfram Language code: hpart[{{1, 2I}, {3I, 4}}]
Wolfram Language code: HermitianMatrixQ[%]

特性と関係  (6)

行列は等しい長さのベクトルからなる：

Wolfram Language code: m = RandomReal[1, {3, 2}];
Wolfram Language code: vecq = Map[VectorQ, m]
Wolfram Language code: lens = Map[Length, m]
Wolfram Language code: Apply[And, Append[vecq, Apply[Equal, lens]]]

組込み関数で確認する：

Wolfram Language code: MatrixQ[m]

空リストは行列ではない：

Wolfram Language code: MatrixQ[{}]

それは長さが0のベクトルである：

Wolfram Language code: VectorQ[{}]

A list of empty lists is considered an matrix:

Wolfram Language code: MatrixQ[{{}, {}, {}}]
Wolfram Language code: Dimensions[{{}, {}, {}}]

MatrixQ[expr]はArrayQ[expr,2]に等しい：

Wolfram Language code: m = RandomReal[1, {2, 2}]
Wolfram Language code: {ArrayQ[m, 2], MatrixQ[m]}

MatrixQ[expr]はArrayQ[expr,2]に等しい：

Wolfram Language code: {ArrayQ[m, 2, MachineNumberQ], MatrixQ[m, MachineNumberQ]}
Wolfram Language code: {ArrayQ[m, 2, IntegerQ], MatrixQ[m, IntegerQ]}

MatrixQ[arr,MatrixQ]は，深さ4の配列 arr に対してTrueを返す：

Wolfram Language code: arr = Array[a, {2, 3, 4, 5}]; {ArrayQ[arr, 4], MatrixQ[arr, MatrixQ]}

この陳述の逆はFalseである：

Wolfram Language code: narr = {Array[a, {3, 4, 5}], Array[a, {3, 4, 6}]}; {ArrayQ[narr, 4], MatrixQ[narr, MatrixQ]}

MatrixQは，事実上，AllowedHeads"ListLike"を使う：

Wolfram Language code: mat = {SparseArray[{1, 2}], QuantityArray[{1, 2}, "Meters"]}; expr = f[f[1, 2], f[3, 4]];
Wolfram Language code: {MatrixQ[mat], MatrixQ[expr]}
Wolfram Language code: {ArrayDepth[mat, AllowedHeads -> "ListLike"], ArrayDepth[expr, AllowedHeads -> "ListLike"]}
Wolfram Language code: {Dimensions[mat, AllowedHeads -> "ListLike"], Dimensions[expr, AllowedHeads -> "ListLike"]}
Wolfram Research (1988), MatrixQ, Wolfram言語関数， https://reference.wolfram.com/language/ref/MatrixQ.html （2003年に更新）.

テキスト

Wolfram Research (1988), MatrixQ, Wolfram言語関数， https://reference.wolfram.com/language/ref/MatrixQ.html （2003年に更新）.

CMS

Wolfram Language. 1988. "MatrixQ." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2003. https://reference.wolfram.com/language/ref/MatrixQ.html.

APA

Wolfram Language. (1988). MatrixQ. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/MatrixQ.html

BibTeX

@misc{reference.wolfram_2026_matrixq, author="Wolfram Research", title="{MatrixQ}", year="2003", howpublished="\url{https://reference.wolfram.com/language/ref/MatrixQ.html}", note=[Accessed: 29-October-2026]}

BibLaTeX

@online{reference.wolfram_2026_matrixq, organization={Wolfram Research}, title={MatrixQ}, year={2003}, url={https://reference.wolfram.com/language/ref/MatrixQ.html}, note=[Accessed: 29-October-2026]}