WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

OrderedQ[h[e1,e2,…]]

ei が正規順序に並ぶ場合にはTrueを，その他の場合にはFalseを与える．

OrderedQ[h[e1,e2,…],p]

順序関数 p を使って要素 ei, ei+1の各ペアが順に並んでいるかどうかを判定する．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
アプリケーション  
特性と関係  
考えられる問題  
関連項目
テクニカルノート
関連するガイド
履歴
引用書式

OrderedQ

OrderedQ[h[e1,e2,…]]

ei が正規順序に並ぶ場合にはTrueを，その他の場合にはFalseを与える．

OrderedQ[h[e1,e2,…],p]

順序関数 p を使って要素 ei, ei+1の各ペアが順に並んでいるかどうかを判定する．

詳細

  • OrderedQ[{e,e}]は，Trueを与える．
  • デフォルトで，OrderedQ[list,p]はSortの説明に記されているように正規順序を使う．これは，Orderを順序関数 p として指定することと同じである． »
  • 要素ペア e1, e2に適用された順序関数 p は，1，0または-1あるいはTrueまたはFalseを返す．p[e1,e2]の値は次のように解釈される．
  • 1e1は e2の前
    0e1と e2は同一なものとして扱われなければならない
    -1e1は e2の後ろ
    Truee1と e2は順序通りである
    Falsee1と e2は順序通りではない
  • 順序関数 p が上記以外の値 p[e1,e2]を返すとき，e1と e2は事実上順序付けられているものとして扱われる． »

例題

すべて開く すべて閉じる

例  (4)

数のリストが順序付けられているかどうかをチェックする：

Wolfram Language code: OrderedQ[{1, 4, 2}]

文字列のリストが順序付けられているかどうかをチェックする：

Wolfram Language code: OrderedQ[{"cat", "catfish", "fish"}]

数式がその構造でソートされているかどうかをチェックする：

Wolfram Language code: OrderedQ[{1, Sqrt[2], 2, E, 3, π}]

数値がソートされているかどうかをチェックする：

Wolfram Language code: OrderedQ[{1, Sqrt[2], 2, E, 3, π}, Less]

各要素の第2部分だけを調べる際に，リストが順序付けられているかどうかをチェックする：

Wolfram Language code: OrderedQ[{{a, 2}, {c, 1}, {d, 3}}, #1[[2]] < #2[[2]]&]

スコープ  (8)

OrderedQは任意の式で使うことができる：

Wolfram Language code: OrderedQ[{x, y, x + y}]

OrderedQはListだけでなく，任意の頭部で使うことができる：

Wolfram Language code: OrderedQ[f[b, a, c]]

連想の値が順序づけられているかどうかをチェックする：

Wolfram Language code: OrderedQ[<|1 -> 10, 2 -> 5, 3 -> 0|>]

順序関数としてGreaterを指定する：

Wolfram Language code: OrderedQ[{4, 3, 2, 1}, Greater]

GreaterEqualを使って要素の繰返しが使えるようにする：

Wolfram Language code: OrderedQ[{4, 3, 3, 1}, Greater]
Wolfram Language code: OrderedQ[{4, 3, 3, 1}, GreaterEqual]

NumericalOrderを使って複素数と数のような式が使えるようにする：

Wolfram Language code: OrderedQ[{1 + I, 2 - I, 3}, NumericalOrder]
Wolfram Language code: OrderedQ[{Yesterday, Today, Tomorrow}, NumericalOrder]

AlphabeticOrderで特定の言語の規則に従ってソートする：

Wolfram Language code: words = {"čeština", "hebrejčina", "hebrejčina", "chorvátčina"};
Wolfram Language code: OrderedQ[words, AlphabeticOrder["Slovak"]]
Wolfram Language code: OrderedQ[words, AlphabeticOrder["Serbian"]]

記号を数の前に置くカスタムの順序関数を定義する：

Wolfram Language code: p[_ ? NumberQ, _Symbol] := -1 p[_Symbol, _ ? NumberQ] := 1 p[_Symbol, _Symbol] := 0 p[x_ ? NumberQ, y_ ? NumberQ] := x ≤ y
Wolfram Language code: OrderedQ[{x, z, a, e, 1, 2, 5}, p]

純関数の順序関数を使う：

Wolfram Language code: OrderedQ[{Entity["City", {"LosAngeles", "California", "UnitedStates"}], Entity["City", {"Chicago", "Illinois", "UnitedStates"}], Entity["City", {"Denver", "Colorado", "UnitedStates"}]}, Sign[#2["Elevation"] - #1["Elevation"]]&]

アプリケーション  (2)

順番になっているタプルを求める：

Wolfram Language code: Select[Tuples[{1, 2, 3}, 4], OrderedQ]

どのタプルが順番になっているかを見る：

Wolfram Language code: Tuples[{0, 1, -1}, 2]
Wolfram Language code: OrderedQ /@ %
Wolfram Language code: ListPlot[Flatten[Position[OrderedQ /@ Tuples[{0, 1, -1}, 6], True]]]

特性と関係  (7)

OrderedQ[expr]はOrderedQ[expr,Order]に等しい：

Wolfram Language code: data = {1, I Sqrt[2], RGBColor[1, 0, 0], "word", {a, α, ℵ}};
Wolfram Language code: OrderedQ[data] == OrderedQ[data, Order]

比較は，ペアが順序通りではないと判定された時点で終了する：

Wolfram Language code: OrderedQ[{1, 3, 5, 2, 7, 10}, (Print[{##}];Less[##])&]

明示的な数については，OrderedQは，事実上，LessEqualに等しい：

Wolfram Language code: OrderedQ[{1, 2, 2, 4}]
Wolfram Language code: LessEqual[1, 2, 2, 4]

任意の連想についてOrderedQ[assoc,…]==OrderedQ[Values[assoc],…]である：

Wolfram Language code: assoc = <|c -> 1, b -> 2, a -> 3|>;
Wolfram Language code: OrderedQ[assoc] == OrderedQ[Values[assoc]]

Sort[expr]===expr のとき，OrderedQ[expr]はTrueを与える：

Wolfram Language code: list = {I, 2, (1/Sqrt[3]), "hello", a, π, {1, 7}};
Wolfram Language code: OrderedQ[list]
Wolfram Language code: Sort[list] === list

Sortは，デフォルトで，事実上OrderedQを使ってソートする：

Wolfram Language code: Sort[{x, y, x ^ 2, y ^ 2, x + y}]
Wolfram Language code: Sort[{x, y, x ^ 2, y ^ 2, x + y}, OrderedQ[{#1, #2}]&]

OrderedQは，デフォルトで，あまり厳密ではない順序を使う：

Wolfram Language code: OrderedQ[{a, b, b, c}]

UnsameQを順序関数に加えて厳密な標準順序かどうかチェックする：

Wolfram Language code: OrderedQ[{a, b, b, c}, OrderedQ[{#1, #2}] && UnsameQ[#1, #2]&]
Wolfram Language code: OrderedQ[{a, b, c}, OrderedQ[{#1, #2}] && UnsameQ[#1, #2]&]

Orderが1を与えるかどうかを調べることもできる：

Wolfram Language code: OrderedQ[{a, b, b, c}, Order[#1, #2] == 1&]
Wolfram Language code: OrderedQ[{a, b, c}, Order[#1, #2] == 1&]

考えられる問題  (2)

OrderedQは，数値によってではなく，デフォルトで構造的に作用する：

Wolfram Language code: OrderedQ[{2, 4, E, Pi}]

要素を数値化するか，NumericalOrderを使って数値によって比較するかする：

Wolfram Language code: OrderedQ[N[{2, 4, E, Pi}]]
Wolfram Language code: OrderedQ[{2, 4, E, Pi}, NumericalOrder]

順序関数で認識できない値の要素は順序付けられていると解釈される：

Wolfram Language code: OrderedQ[{1, 2, a, 3, 4}, Echo[#1 < #2]&]

TrueQを使って，比較できなかったものを順序付けられていないものとして解釈する：

Wolfram Language code: OrderedQ[{1, 2, a, 3, 4}, TrueQ[#1 < #2]&]
Wolfram Research (1988), OrderedQ, Wolfram言語関数， https://reference.wolfram.com/language/ref/OrderedQ.html （2017年に更新）.

テキスト

Wolfram Research (1988), OrderedQ, Wolfram言語関数， https://reference.wolfram.com/language/ref/OrderedQ.html （2017年に更新）.

CMS

Wolfram Language. 1988. "OrderedQ." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2017. https://reference.wolfram.com/language/ref/OrderedQ.html.

APA

Wolfram Language. (1988). OrderedQ. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/OrderedQ.html

BibTeX

@misc{reference.wolfram_2026_orderedq, author="Wolfram Research", title="{OrderedQ}", year="2017", howpublished="\url{https://reference.wolfram.com/language/ref/OrderedQ.html}", note=[Accessed: 15-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_orderedq, organization={Wolfram Research}, title={OrderedQ}, year={2017}, url={https://reference.wolfram.com/language/ref/OrderedQ.html}, note=[Accessed: 15-November-2026]}