WOLFRAM

Wolfram 语言与系统参考资料中心

PascalBinomial[n,m]

给出保持帕斯卡恒等式成立的二项式系数 TemplateBox[{n, m}, PascalBinomial].

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
数值计算  
特殊值  
可视化  
Show More Show More
函数的属性  
微分  
级数展开式  
函数恒等式和化简  
应用  
属性和关系  
巧妙范例  
参见
历史
按以下格式引用：

PascalBinomial

PascalBinomial[n,m]

给出保持帕斯卡恒等式成立的二项式系数 TemplateBox[{n, m}, PascalBinomial].

更多信息

  • 整数数学函数，适宜于符号和数字运算.
  • PascalBinomial 也称为组合和选择函数.
  • 对于所有整数，PascalBinomial 给出保持 Pascal 恒等式成立的非对称系数. 对于负整数 ，用 Binomial 求对称系数. 除负整数 以外，PascalBinomial 和 Binomial 的结果一致.
  • 通常，TemplateBox[{n, m}, PascalBinomial] 由 (n!)/(m!(n-m)!)=(TemplateBox[{{n, +, 1}}, Gamma])/(TemplateBox[{{m, +, 1}}, Gamma] TemplateBox[{{n, -, m, +, 1}}, Gamma]) 定义，或由适合的极限定义.
  • 为负整数时，TemplateBox[{n, m}, PascalBinomial]=TemplateBox[{TemplateBox[{{{(, TemplateBox[{{nu, +, 1}}, Gamma], )}, /, {(, {TemplateBox[{{mu, +, 1}}, Gamma], , TemplateBox[{{{-, mu}, +, nu, +, 1}}, Gamma]}, )}}, mu, m}, Limit2Arg], nu, n}, Limit2Arg]. »
  • 所选的特定极限对所有复数 和 都可保持帕斯卡恒等式 TemplateBox[{n, m}, PascalBinomial]=TemplateBox[{{n, -, 1}, m}, PascalBinomial]+TemplateBox[{{n, -, 1}, {m, -, 1}}, PascalBinomial] 成立. »
  • 对称规则 TemplateBox[{n, m}, PascalBinomial]=TemplateBox[{n, {n, -, m}}, PascalBinomial] 对所有 和大多数 都适用，但不适用于负整数 . »
  • 对于整数参数，PascalBinomial 自动算出精确值.
  • 对于简单情况，PascalBinomial 会自动进行符号运算；其他情况下，FunctionExpand 会给出结果. »
  • PascalBinomial 的计算结果可以为任意数值精度.
  • PascalBinomial 自动逐项作用于列表的各个元素.
  • PascalBinomial 可与 Interval 和 CenteredInterval 对象一起使用. »

范例

打开所有单元 关闭所有单元

基本范例  (5)

数值计算：

Wolfram Language code: PascalBinomial[10, 3]

符号计算：

Wolfram Language code: Binomial[n, 3]

构建帕斯卡三角：

Wolfram Language code: Column[Table[PascalBinomial[n, k], {n, 0, 5}, {k, 0, n}], Center]

在实数子集上绘制作为第一个参数的函数：

Wolfram Language code: Plot[PascalBinomial[x, 3], {x, -2, 4}]

在实数子集上绘制作为第二个参数的函数：

Wolfram Language code: Plot[PascalBinomial[3, x], {x, -2, 4}]

在复数子集上绘制：

Wolfram Language code: ComplexPlot3D[PascalBinomial[z, 1 / 5], {z, -2 - 2I, 2 + 2I}, PlotLegends -> Automatic]

范围  (36)

数值计算  (7)

数值计算：

Wolfram Language code: PascalBinomial[8, 4]
Wolfram Language code: PascalBinomial[8.5, -4.2]

对半整数参数进行计算：

Wolfram Language code: PascalBinomial[9 / 2, 7 / 2]

算出高精度结果：

Wolfram Language code: N[PascalBinomial[7 / 3, 1 / 5], 20]

输出的精度与输入的精度一致：

Wolfram Language code: PascalBinomial[8.2211111111115000000, 4]

复数输入：

Wolfram Language code: PascalBinomial[1 + I, 5]
Wolfram Language code: PascalBinomial[2. + I, 7 - 3I]

在高精度条件下高效计算：

Wolfram Language code: PascalBinomial[17 / 2, -4.2`100]//Timing
Wolfram Language code: PascalBinomial[-88889 + (1/2), 4.2`1000];//Timing

用 Interval 和 CenteredInterval 对象计算最坏情况下的区间：

Wolfram Language code: PascalBinomial[1 / 2, Interval[{0.5, 0.6}]]
Wolfram Language code: PascalBinomial[1, CenteredInterval[1 / 2, 1 / 100]]

或用 Around 计算一般情况下的统计区间：

Wolfram Language code: PascalBinomial[Around[2, 0.01], 2]

计算数组中各个元素的值：

Wolfram Language code: PascalBinomial[ {{5π / 6, 0}, {3π / 2, -π / 2}}, 2]

或用 MatrixFunction 计算矩阵形式的 PascalBinomial 函数：

Wolfram Language code: MatrixFunction[PascalBinomial[#, 2]&, {{5π / 6, 0}, {3π / 2, -π / 2}}]

特殊值  (5)

特定点上的 PascalBinomial 值：

Wolfram Language code: Table[PascalBinomial[n, 2], {n, 1, 5}]

n 为符号的 PascalBinomial：

Wolfram Language code: PascalBinomial[n, 4]

零处的值：

Wolfram Language code: PascalBinomial[n, 0]
Wolfram Language code: FunctionExpand[PascalBinomial[0, m]]

注意，对于远离 的所有整数，结果都为零：

Wolfram Language code: Simplify[%, m∈ℤ && m != 0]

当 n 和 m 都是负整数时，PascalBinomial[n,m] 为零：

Wolfram Language code: FunctionExpand[PascalBinomial[n, m], n∈NegativeIntegers && m∈NegativeIntegers]

求使得 PascalBinomial[n,2]=15 的 n 的值：

Wolfram Language code: nval = n /. FindRoot[PascalBinomial[ n , 2] == 15, {n, 5}]
Wolfram Language code: Plot[PascalBinomial[n, 2], {n, 0, 10}, Epilog -> Style[Point[{nval, PascalBinomial[nval, 2]}], PointSize[Large], StandardMagenta]]

可视化  (3)

绘制作为参数 n 的函数的 PascalBinomial：

Wolfram Language code: Plot[{PascalBinomial[n, 1], PascalBinomial[n, 2], PascalBinomial[n, 3], PascalBinomial[n, 4]}, {n, -2, 4}]

绘制作为参数 的函数的 PascalBinomial：

Wolfram Language code: Plot[{PascalBinomial[1, m], PascalBinomial[2, m], PascalBinomial[3, m], PascalBinomial[4, m]}, {m, -1, 5}]

绘制 TemplateBox[{z, 5}, PascalBinomial] 的实部：

Wolfram Language code: ComplexContourPlot[Re[PascalBinomial[z, 5]], {z, -4 - 4I, 8 + 4I}, Contours -> 24]

绘制 TemplateBox[{z, 5}, PascalBinomial] 的虚部：

Wolfram Language code: ComplexContourPlot[Im[PascalBinomial[z, 5]], {z, -4 - 4I, 8 + 4I}, Contours -> 24]

函数的属性  (12)

作为参数 n 的函数的 PascalBinomial 的实定义域：

Wolfram Language code: FunctionDomain[PascalBinomial[n, 2], n]

作为参数 m 的函数的 PascalBinomial 的实定义域：

Wolfram Language code: FunctionDomain[PascalBinomial[2, m], m]

复定义域：

Wolfram Language code: FunctionDomain[PascalBinomial[z, 2], z, Complexes]
Wolfram Language code: FunctionDomain[PascalBinomial[2, z], z, Complexes]

PascalBinomial 的值域：

Wolfram Language code: FunctionRange[PascalBinomial[x, 2], x, y]

PascalBinomial 有镜像属性 TemplateBox[{TemplateBox[{z}, Conjugate, SyntaxForm -> SuperscriptBox], 2}, PascalBinomial]=TemplateBox[{TemplateBox[{z, 2}, PascalBinomial]}, Conjugate]：

Wolfram Language code: FullSimplify[PascalBinomial[Conjugate[z], 2] == Conjugate[PascalBinomial[z, 2]]]

计算含有 PascalBinomial 的和：

Wolfram Language code: Sum[PascalBinomial[n, k], {k, 0, n}]
Wolfram Language code: Sum[PascalBinomial[n, k] ^ 2, {k, 0, n}]

为正时，TemplateBox[{x, y}, PascalBinomial] 是两个变量的解析函数：

Wolfram Language code: FunctionAnalytic[{PascalBinomial[x, y], x > 0}, {x, y}]

为负时则不成立：

Wolfram Language code: FunctionAnalytic[{PascalBinomial[x, y], x < 0}, {x, y}]

TemplateBox[{x, 7}, PascalBinomial] 既不是非递增，也不是非递减：

Wolfram Language code: FunctionMonotonicity[PascalBinomial[x, 7], x]

TemplateBox[{x, 7}, PascalBinomial] 不是单射函数：

Wolfram Language code: FunctionInjective[PascalBinomial[x, 7], x]
Wolfram Language code: Plot[{PascalBinomial[x, 7], .01}, {x, -2, 3}]

TemplateBox[{x, 7}, PascalBinomial] 是满射函数：

Wolfram Language code: FunctionSurjective[PascalBinomial[x, 7], x]
Wolfram Language code: Plot[{PascalBinomial[x, 7], 750}, {x, -10, 15}]

PascalBinomial 既不非负的也不非正：

Wolfram Language code: FunctionSign[PascalBinomial[x, 1], x]
Wolfram Language code: FunctionSign[PascalBinomial[1, x], x]

为负整数时，TemplateBox[{x, y}, PascalBinomial] 有奇点和断点：

Wolfram Language code: FunctionSingularities[PascalBinomial[x, y], x]
Wolfram Language code: FunctionDiscontinuities[PascalBinomial[x, y], x]

TemplateBox[{x, 7}, Binomial] 既不凸也不凹：

Wolfram Language code: FunctionConvexity[PascalBinomial[x, 7], x]

TraditionalForm 格式：

Wolfram Language code: PascalBinomial[n, k]//TraditionalForm

微分  (3)

关于 的一阶导数：

Wolfram Language code: D[PascalBinomial[n, m], m]

关于 的高阶导数：

Wolfram Language code: Table[D[PascalBinomial[n, m], {m, k}], {k, 1, 3}]//FullSimplify

绘制 时关于 的高阶导数：

Wolfram Language code: Plot[Evaluate[% /. n -> 2], {m, -5, 5}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative"}]

关于 的一阶导数：

Wolfram Language code: D[PascalBinomial[n, m], n]

级数展开式  (4)

用 Series 求泰勒级数展开：

Wolfram Language code: Series[PascalBinomial[n, x], {x, 0, 3}]//Normal//FullSimplify

绘制 处的前三个近似式：

Wolfram Language code: terms = Normal@Table[Series[PascalBinomial[2, x], {x, 0, m}], {m, 1, 5, 2}]; Plot[{PascalBinomial[2, x], terms}, {x, -5, 5}]

求 Infinity 处的级数展开式：

Wolfram Language code: FullSimplify[Series[PascalBinomial[n, x], {x, Infinity, 1}]//Normal, x > n]

求任意符号方向 上的级数展开式：

Wolfram Language code: Series[PascalBinomial[2, x], {x, DirectedInfinity[z], 1}, Assumptions -> x > 0 ]//Normal// FullSimplify

在普通点上的泰勒展开式：

Wolfram Language code: Series[PascalBinomial[n, x], {x, x0, 2}]// Normal//FullSimplify

函数恒等式和化简  (2)

函数恒等式：

Wolfram Language code: PascalBinomial[n, k] == (k + 1/n - k) PascalBinomial[n, k + 1]//FullSimplify

递归关系式：

Wolfram Language code: PascalBinomial[n, k] == (n/n - k) PascalBinomial[n - 1, k]//FullSimplify
Wolfram Language code: PascalBinomial[n, k] == (n - k + 1/n + 1) PascalBinomial[n + 1, k]//FullSimplify

应用  (9)

从 个元素的集合中，有 TemplateBox[{n, m}, Binomial] 种方式可以不重复地选出 个元素：

Wolfram Language code: With[{n = 5, m = 2}, PascalBinomial[n, m]]

通过直接枚举进行检查：

Wolfram Language code: With[{n = 5, m = 2}, Subsets[Range[n], {m}]]
Wolfram Language code: Length[%]

从 个元素的集合中，有 TemplateBox[{{m, +, n, -, 1}, m}, Binomial] 种方式可以有重复地选出 个元素：

Wolfram Language code: With[{n = 5, m = 2}, PascalBinomial[n + m - 1, m]]

通过直接枚举进行检查：

Wolfram Language code: With[{n = 5, m = 2}, DeleteDuplicates[Sort /@ Tuples[Range[n], {m}]]]
Wolfram Language code: Length[%]

有 TemplateBox[{{m, +, n}, m}, Binomial] 种方式排列 个无法区分的一类物体和 个无法区分的另一类物体：

Wolfram Language code: With[{n = 5, m = 2}, PascalBinomial[n + m, m]]
Wolfram Language code: With[{n = 5, m = 2}, Permutations[Join[ConstantArray[0, n], ConstantArray[1, m]]]]
Wolfram Language code: Length[%]

说明二项式定理：

Wolfram Language code: Sum[PascalBinomial[n, k]x ^ k, {k, 0, n}]
Wolfram Language code: Expand[(1 + x) ^ 10]

分数二项式定理：

Wolfram Language code: Series[(1 + x) ^ (1 / 3), {x, 0, 5}]
Wolfram Language code: Sum[PascalBinomial[1 / 3, k]x ^ k, {k, 0, 5}]

二项式系数模 2：

Wolfram Language code: ArrayPlot[Table[Mod[PascalBinomial[i, j], 2], {i, 50}, {j, i}], PlotTheme -> "Scientific"]

在参数平面中绘制 PascalBinomial：

Wolfram Language code: Plot3D[PascalBinomial[n, k], {n, -10, 10}, {k, -10, 10}]

绘制从 个元素中挑选 个元素的方法的数量的对数：

Wolfram Language code: Plot3D[Log[PascalBinomial[n, k]], {n, 1, 12}, {k, 1, 12}, RegionFunction -> (#2 <= #1&)]

计算两个函数乘积的高阶导数：

Wolfram Language code: Sum[PascalBinomial[4, k] D[f[z], {z, k}]D[g[z], {z, 4 - k}], {k, 0, 4}]
Wolfram Language code: D[f[z] g[z], {z, 4}]

属性和关系  (8)

在整数上，PascalBinomial[n,m] 等于 TemplateBox[{TemplateBox[{{{(, TemplateBox[{{nu, +, 1}}, Gamma], )}, /, {(, {TemplateBox[{{mu, +, 1}}, Gamma], , TemplateBox[{{{-, mu}, +, nu, +, 1}}, Gamma]}, )}}, mu, m}, Limit2Arg], nu, n}, Limit2Arg]：

Wolfram Language code: And@@Flatten@Table[PascalBinomial[n, m] == Underscript[, νUnderscript[ -> , ℂ]n](Underscript[, μUnderscript[ -> , ℂ]m](Gamma[ν + 1]/Gamma[μ + 1] Gamma[-μ + ν + 1])), {n, -5, 5}, {m, -5, 5}]

时，这可以表示为 (-1)^m TemplateBox[{{-, n}, m}, Pochhammer]/m! for ，其他情况下为 0：

Wolfram Language code: And@@Flatten@Table[PascalBinomial[``n``, ``m``] == Piecewise[{{((-1)^m*Pochhammer[-n, m])/m!, m >= 0}, {0, m <= n}}], {n, 5, -5, -1}, {m, 5, -5, -1}]

关于整数的另一种公式：

Wolfram Language code: Assuming[{n, m}∈ℤ, FullSimplify@FunctionExpand[PascalBinomial[n, m]]]

帕斯卡恒等式处处成立：

Wolfram Language code: FullSimplify[PascalBinomial[n, m] == PascalBinomial[n - 1, m] + PascalBinomial[n - 1, m - 1]]

尤其是在原点处也成立：

Wolfram Language code: FullSimplify[PascalBinomial[n, m] == PascalBinomial[n - 1, m] + PascalBinomial[n - 1, m - 1], n == 0 && m == 0]

对称规则 TemplateBox[{n, m}, PascalBinomial]=TemplateBox[{n, {n, -, m}}, PascalBinomial] 可能对负整数 不成立：

Wolfram Language code: FullSimplify[PascalBinomial[n, m] == PascalBinomial[n, n - m], n∈NegativeIntegers && m∈ℤ]

它可能对某些值成立，但对于正整数 通常不成立：

Wolfram Language code: PascalBinomial[n, m] == PascalBinomial[n, n - m] /.  {{n -> -3, m -> 1}, {n -> -3, m -> -1}}

Binomial 处处满足对称规则：

Wolfram Language code: FullSimplify[Binomial[n, m] == Binomial[n, n - m]]

PascalBinomial 对符号参数进行简单的计算：

Wolfram Language code: PascalBinomial[n, 2]

当两个参数都是符号时，PascalBinomial 通常无法进行计算：

Wolfram Language code: PascalBinomial[n + 1, n]

可使用带条件的 FunctionExpand 来实现适当的简化：

Wolfram Language code: FunctionExpand[PascalBinomial[n + 1, n], n∈Integers]

当 n 和 m 都是负整数时，PascalBinomial[n,m] 为 0：

Wolfram Language code: FunctionExpand[PascalBinomial[n, m], n∈NegativeIntegers && m∈NegativeIntegers]

用 FullSimplify 化简含有二项式系数的表达式：

Wolfram Language code: FullSimplify[PascalBinomial[n + 1, k + 1] / PascalBinomial[n, k]]

用 FunctionExpand 展开为 Gamma 函数：

Wolfram Language code: FunctionExpand[PascalBinomial[n, k]]

含有 PascalBinomial 的和：

Wolfram Language code: Underoverscript[∑, k = 0, n](-1)^kPascalBinomial[n, k]
Wolfram Language code: Underoverscript[∑, k = 0, ∞]PascalBinomial[n, k] k
Wolfram Language code: Underoverscript[∑, k = 1, ∞](1/PascalBinomial[2 k, k])

巧妙范例  (7)

构建帕斯卡三角图形：

Wolfram Language code: With[{n = 8}, Graph[Flatten[Table[{b[i, j] <-> b[i + 1, j], b[i, j] <-> b[i + 1, j + 1], b[i + 1, j] <-> b[i + 1, j + 1]}, {i, 0, n - 1}, {j, 0, i}]], VertexCoordinates -> {b[i_, j_] :> {(n + 1/2) - i / 2 + j, -i}}, VertexLabels -> {b[i_, j_] :> Placed[PascalBinomial[i, j], Center]}, IconizedObject[«Style options»]]]

将三角扩展到负整数；未标记的点的值为零：

Wolfram Language code: With[{n = 6}, Graph[Flatten[Table[{b[i, j] <-> b[i + 1, j], b[i, j] <-> b[i + 1, j + 1], b[i + 1, j] <-> b[i + 1, j + 1]}, {i, n - 1, -n - 1, -1}, {j, -n + i UnitStep[i] - UnitStep[-1 - i], n + i UnitStep[-i] + UnitStep[-1 - i]}]], VertexCoordinates -> {b[i_, j_] :> {(n + 1/2) - (i/2) + j, -i}}, IconizedObject[«Style options»]]]

相反，Binomial，通过反射右上角区域来定义左上角区域：

Wolfram Language code: With[{n = 6}, Graph[Flatten[Table[{b[i, j] <-> b[i + 1, j], b[i, j] <-> b[i + 1, j + 1], b[i + 1, j] <-> b[i + 1, j + 1]}, {i, n - 1, -n - 1, -1}, {j, -n + i UnitStep[i] - UnitStep[-1 - i], n + i UnitStep[-i] + UnitStep[-1 - i]}]], VertexCoordinates -> {b[i_, j_] :> {(n + 1/2) - (i/2) + j, -i}}, IconizedObject[«Style options»]]]

二项式系数模 ：

Wolfram Language code: ArrayPlot[Table[Mod[PascalBinomial[i, j], Pi], {i, 50}, {j, i}], PlotTheme -> "Scientific"]

希尔伯特矩阵的逆：

Wolfram Language code: Block[{n = 4}, Table[(-1) ^ (i + j)(i + j - 1)PascalBinomial[n + i - 1, n - j]PascalBinomial[n + j - 1, n - i]PascalBinomial[i + j - 2, i - 1] ^ 2, {i, n}, {j, n}]]//MatrixForm
Wolfram Language code: Inverse[%]

复平面上的嵌套二项式：

Wolfram Language code: DensityPlot[Arg[Nest[PascalBinomial[#, # / 2]&, x + I y, 3]], {x, -1, -0.9}, {y, -0.06, 0.06}, Exclusions -> {}, MaxRecursion -> 4, PlotPoints -> 50]

绘制无穷处的 PascalBinomial：

Wolfram Language code: DensityPlot[Arg[PascalBinomial[(x + I y), 1 / (x + I y)]], {x, -1 / 2, 1 / 2}, {y, -1 / 2, 1 / 2}, Exclusions -> {}, MaxRecursion -> 4, PlotPoints -> 50]

绘制参数为复数的 PascalBinomial：

Wolfram Language code: DensityPlot[Arg[PascalBinomial[4.1 Exp[I ϕ1], 2.2 Exp[I ϕ2]]], {ϕ1, -Pi, Pi}, {ϕ2, -Pi, Pi}, Exclusions -> {}, MaxRecursion -> 4, PlotPoints -> 50]

绘制高斯整数上的 PascalBinomial：

Wolfram Language code: Block[{$MaxExtraPrecision = 1000}, ArrayPlot[Table[Mod[Im@Round[PascalBinomial[x + I y, x ]], 2], {x, 0, 50}, {y, -25, 25}], PlotTheme -> "Scientific"]]
Wolfram Research (2024)，PascalBinomial，Wolfram 语言函数，https://reference.wolfram.com/language/ref/PascalBinomial.html.

文本

Wolfram Research (2024)，PascalBinomial，Wolfram 语言函数，https://reference.wolfram.com/language/ref/PascalBinomial.html.

CMS

Wolfram 语言. 2024. "PascalBinomial." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/PascalBinomial.html.

APA

Wolfram 语言. (2024). PascalBinomial. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/PascalBinomial.html 年

BibTeX

@misc{reference.wolfram_2026_pascalbinomial, author="Wolfram Research", title="{PascalBinomial}", year="2024", howpublished="\url{https://reference.wolfram.com/language/ref/PascalBinomial.html}", note=[Accessed: 08-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_pascalbinomial, organization={Wolfram Research}, title={PascalBinomial}, year={2024}, url={https://reference.wolfram.com/language/ref/PascalBinomial.html}, note=[Accessed: 08-November-2026]}