WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

RankedMax[list,n]

list 中の n 番目に大きい要素を与える．

RankedMax[list,-n]

list 中の n 番目に小さい要素を与える．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
数値評価  
特定の値  
可視化  
関数の特性  
積分  
アプリケーション  
特性と関係  
おもしろい例題  
関連項目
関連するガイド
履歴
引用書式

RankedMax

RankedMax[list,n]

list 中の n 番目に大きい要素を与える．

RankedMax[list,-n]

list 中の n 番目に小さい要素を与える．

詳細

  • RankedMaxはすべての引数が実数である場合は明らかな結果を与える．
  • が順序 のリストなら，RankedMax[x,n]は について を，RankedMax[x,-n]は を与える．
  • RankedMax[{x1,…,xm},1]はMax[{x1,…,xm}]に等しい． »
  • RankedMax[{x1,…,xm},-1]はMin[{x1,…,xm}]に等しい．
  • RankedMax[{x1,…,xm},m]はMin[{x1,…,xm}]に等しい． »
  • RankedMax[{x1,…,xm},n]はQuantile[{x1,…,xm},(m-n+1)/m]に等しい． »

例題

すべて開く すべて閉じる

例  (4)

3つの数のうちで2番目に大きい数：

Wolfram Language code: RankedMax[{12, 13, 11}, 2]

4つの数の内で3番目に大きいもの：

Wolfram Language code: RankedMax[{Pi, Sqrt[2], E, 3}, 3]

日付のリストの中で2番目に大きい日付：

Wolfram Language code: RandomDate[4]
Wolfram Language code: RankedMax[%, 2]

2番目に大きい関数を実数の部分集合上でプロットする：

Wolfram Language code: Plot[RankedMax[{(1/2), Cos[x], -(1/2)}, 2], {x, 0, 2π}]

スコープ  (25)

数値評価  (7)

3つの数のうち2番目に大さいものを評価する：

Wolfram Language code: RankedMax[{12.6555, 33.5265, 25.65}, 2]

4つの数のうち4番目におおきいもの（つまり，一番小さいもの）：

Wolfram Language code: RankedMax[{12, 13, 48.5, Pi}, 4]

5つの数のうち2番目に小さいもの：

Wolfram Language code: RankedMax[{2.5, E, 12, 15, 485}, -2]

5つの数のうち4番目に小さいもの：

Wolfram Language code: RankedMax[{2.5, E, 12, 15, 485}, -4]

5つの数のうち5番目に小さいもの（つまり一番大きいもの）：

Wolfram Language code: RankedMax[{2.5, E, 12, 15, 485}, -5]

高精度で評価する：

Wolfram Language code: N[RankedMax[{12, 24, 48.5, Pi}, 4], 50]
Wolfram Language code: N[RankedMax[{12, 52, E, Pi}, 4], 70]

高精度で効率的に評価する：

Wolfram Language code: RankedMax[{12, E, 99 / 3`100, Pi}, 4]//Timing
Wolfram Language code: RankedMax[{E, 5568586, 4856`10000000, Pi + E}, -4];//Timing

WeightedDataのRankedMaxは重みを無視する：

Wolfram Language code: wd = WeightedData[{1, 2, 3, 4}, {1, 2, 1, 3}];
Wolfram Language code: RankedMax[wd, 2]
Wolfram Language code: RankedMax[wd["InputData"], 2]

日付の順位付き最大値を計算する：

Wolfram Language code: dates = WolframLanguageData[All, "DateIntroduced"];
Wolfram Language code: DateHistogram[dates]
Wolfram Language code: RankedMax[dates, 125]

時間の順位付き最大値を計算する：

Wolfram Language code: RandomTime[10]//Sort
Wolfram Language code: RankedMax[%, 4]

異なる時刻帯指定の時刻のリスト：

Wolfram Language code: {TimeObject[{12}, TimeZone -> 0], TimeObject[{12}, TimeZone -> 2], TimeObject[{12}, TimeZone -> "Asia/Tokyo"]}
Wolfram Language code: RankedMax[%, 2]

特定の値  (4)

無限大における値：

Wolfram Language code: RankedMax[{∞, 5, ∞, -∞}, 2]
Wolfram Language code: RankedMax[{∞, 5, ∞, -∞}, -1]

記号的に評価する：

Wolfram Language code: PiecewiseExpand[RankedMax[ {x, x + 1, y}, 3], -2 < x < 2, 3 < y < 4]

方程式と不等式を解く：

Wolfram Language code: Reduce[{RankedMax[{Sin[x], Cos[x], Sec[x]}, 2] > 0, 0 < x < 5}, x, Reals]

RankedMax[{Sin[x],Cos[x],Exp[x]},2]1となるような x の値を求める：

Wolfram Language code: xval = x /. FindRoot[RankedMax[{Sin[x], Cos[x], Exp[x]}, 2] == 1, {x, 2}]
Wolfram Language code: Plot[RankedMax[{Sin[x], Cos[x], Exp[x]}, 2], {x, -5, 6}, Epilog -> Style[Point[{xval, RankedMax[{Sin[xval], Cos[xval], Exp[xval]}, 2]}], PointSize[Large], Red]]

可視化  (3)

いくつかの関数のRankedMaxをプロットする：

Wolfram Language code: Plot[RankedMax[{Sin[x], Cos[x], Tan[x]}, 2], {x, 0, 2π}, PlotRange -> All]

RankedMaxを三次元でプロットする：

Wolfram Language code: Plot3D[RankedMax[{x, y, x + y}, 2], {x, -3, 3}, {y, -3, 3}, ColorFunction -> "BlueGreenYellow"]

3つの関数のRankedMaxを三次元でプロットする：

Wolfram Language code: Plot3D[RankedMax[{Tan[x], Tan[y], Tan[x + y]}, 2], {x, -3, 3}, {y, -3, 3}, ColorFunction -> "BlueGreenYellow"]

関数の特性  (8)

RankedMaxは実数値の入力についてのみ定義される：

Wolfram Language code: RankedMax[{1, I, E}, 2]

RankedMaxの値域は実数である：

Wolfram Language code: FindInstance[Im[RankedMax[{x, y, z}, 2]] ≠ 0, {x, y, z}]

基本的な記号的簡約は自動的に行われる：

Wolfram Language code: RankedMax[{x, y, z}, 1]
Wolfram Language code: RankedMax[{x, y, z}, 3]

引数が複数のランク付きRankedMaxは，一般に，解析関数ではない：

Wolfram Language code: FunctionAnalytic[RankedMax[ {1, x, x ^ 2}, 2], x]

関数が交差するところに特異点を持つが，連続である：

Wolfram Language code: FunctionSingularities[RankedMax[ {1, x, x ^ 2}, 2], x]//Quiet//Reduce
Wolfram Language code: FunctionDiscontinuities[RankedMax[ {1, x, x ^ 2}, 2], x]//Quiet//Reduce

は非減少でも非増加でもない：

Wolfram Language code: FunctionMonotonicity[RankedMax[ {1, x, x ^ 2}, 2], x]

は単射ではない：

Wolfram Language code: FunctionInjective[RankedMax[ {1, x, x ^ 2}, 2], x]
Wolfram Language code: Plot[{RankedMax[ {1, x, x ^ 2}, 2], 1 / 2}, {x, -2, 2}]

は全射ではない：

Wolfram Language code: FunctionSurjective[RankedMax[ {1, x, x ^ 2}, 2], x]
Wolfram Language code: Plot[{RankedMax[ {1, x, x ^ 2}, 2], -1}, {x, -2, 2}]

は非負である：

Wolfram Language code: FunctionSign[RankedMax[ {1, x, x ^ 2}, 2], x]

積分  (3)

2番目に大きい関数の原点における級数展開：

Wolfram Language code: Series[RankedMax[{Exp[x], x ^ 2, Tanh[x]}, 2], {x, 0, 3}]

Infinityにおける漸近展開：

Wolfram Language code: Series[RankedMax[{1 / x, 1 / (x - 1), 1 / (x + 2)}, 3], {x, ∞, 3}]//FullSimplify

RankedMaxを含む式を積分する：

Wolfram Language code: Integrate[RankedMax[{x + 1, x, 1 + x^2}, 2], x]
Wolfram Language code: Integrate[Boole[RankedMax[{x + y, x - y, x y}, 2] < 2], {x, 0, 2}, {y, 0, 2}]

アプリケーション  (7)

2変数のRankedMax関数をプロットする：

Wolfram Language code: Table[Plot3D[RankedMax[{x, y}, k], {x, -2, 2}, {y, -2, 2}, PlotLabel -> RankedMax[{x, y}, k]], {k, 2}]

2変数および3変数のRankedMax関数の等高線（面）をプロットする：

Wolfram Language code: Table[ContourPlot[RankedMax[{x, y}, k] == 0, {x, -2, 2}, {y, -2, 2}, PlotLabel -> RankedMax[{x, y}, k] == 0], {k, 2}]
Wolfram Language code: ParallelTable[ContourPlot3D[RankedMax[{x, y, z}, k] == 0, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, PlotLabel -> RankedMax[{x, y, z}, k] == 0], {k, 3}]

x の関数としてのRankedMax[{y1,…,yn,x},k]：

Wolfram Language code: data = Append[Range[1, 5] / 6, x]
Wolfram Language code: Table[Plot[RankedMax[data, k], {x, 0, 1}, Filling -> Axis, PlotLabel -> k, PlotRange -> {0, 1}], {k, 6}]

2番目に小さい（中央値の）変数の期待値を計算する：

Wolfram Language code: Expectation[RankedMax[{x, y, z}, 2], {x, y, z}ProductDistribution[{ExponentialDistribution[λ], 3}]]

あるいはOrderDistributionを使う：

Wolfram Language code: Mean[OrderDistribution[{ExponentialDistribution[λ], 3}, 2]]

2番目に小さい変数が1より小さい確率を求める：

Wolfram Language code: Probability[RankedMax[{x, y, z, w}, 2] < 1, {x, y, z, w}ProductDistribution[{ExponentialDistribution[λ], 4}]]
Wolfram Language code: Plot[%, {λ, 0, 5}]

学級で4番目に背が高い生後の身長を求める：

Wolfram Language code: heights = Quantity[{134, 143, 131, 140, 145, 136, 131, 136, 143, 136, 133, 145, 147, 150, 150, 146, 137, 143, 132, 142, 145, 136, 144, 135, 141}, "Centimeters"];
Wolfram Language code: ListPlot[heights, Filling -> Axis, AxesLabel -> Automatic]
Wolfram Language code: r = RankedMax[heights, 4]
Wolfram Language code: n = Length[heights]; ListPlot[{heights, {{0, r}, {n, r}}}, Filling -> {1 -> 0}, Joined -> {False, True}, AxesLabel -> Automatic]

ドイツの2番目に長い国境線を求める：

Wolfram Language code: data = CountryData["Germany", "BordersLengths"]
Wolfram Language code: RankedMax[Values[data], 2]

それがどことの国境かを求める：

Wolfram Language code: Select[data, Last[#] == %&]

特性と関係  (6)

RankedMax[{x1,…,xm},1]はMax[x1,…,xm]に等しい：

Wolfram Language code: Table[RankedMax[Array[Subscript[x, #]&, {m}], 1] == Max[Array[Subscript[x, #]&, {m}]], {m, 4}]

RankedMax[{x1,…,xm},m]はMin[x1,…,xm]に等しい：

Wolfram Language code: Table[RankedMax[Array[Subscript[x, #]&, {m}], m] == Min[Array[Subscript[x, #]&, {m}]], {m, 4}]

RankedMax[{x1,…,xm},k]はRankedMin[{x1,…,xm},m-k+1]に等しい：

Wolfram Language code: With[{k = 2}, Table[RankedMax[Array[Subscript[x, #]&, {m}], k] == RankedMin[Array[Subscript[x, #]&, {m}], m - k + 1], {m, 2, 3}]]
Wolfram Language code: FullSimplify[PiecewiseExpand /@ %, _∈Reals]

RankedMax[{x1,…,xm},n]はQuantile[{x1,…,xm},(m-n+1)/m]に等しい：

Wolfram Language code: data = RandomSample[Range[100], 10];
Wolfram Language code: Table[RankedMax[data, n] == Quantile[data, (10 - n + 1) / 10], {n, 10}]

RankedMax[{x1,…,xm},n]はSort[{x1,…,xm},Greater]〚n〛:に等しい：

Wolfram Language code: data = RandomSample[Range[100], 10];
Wolfram Language code: Table[RankedMax[data, n] == Sort[data, Greater][[n]], {n, 10}]

等価のPiecewise関数には互いに素な区分ケースの領域がある：

Wolfram Language code: PiecewiseDomains[HoldPattern[Piecewise[cases_, default_]]] := Module[{dl = Last /@ cases}, Append[dl, Not[Or@@dl]]]
Wolfram Language code: PiecewiseExpand[RankedMax[{x, y}, 2]]
Wolfram Language code: doms1 = PiecewiseDomains[%]

区分ケースは互いに素であることを代数的に証明する：

Wolfram Language code: Table[Resolve[ForAll[t, Exists[{x, y}, And@@ineqs]]], {ineqs, Subsets[doms1, {2}]}]

これを視覚的に示す：

Wolfram Language code: Table[RegionPlot[Evaluate[doms1[[i]]], {x, -2, 2}, {y, -2, 2}, PlotStyle -> ColorData[95, i]], {i, 2}]
Wolfram Language code: doms2 = PiecewiseDomains[PiecewiseExpand[RankedMax[{x, y, z}, 2]]]

区分ケースの領域は区分的に互いに素であることを代数的に証明する：

Wolfram Language code: Table[Resolve[ForAll[t, Exists[{x, y}, And@@ineqs]]], {ineqs, Subsets[doms2, {2}]}]

これを視覚的に示す：

Wolfram Language code: Table[RegionPlot3D[Evaluate[doms2[[i]]], {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, PlotStyle -> ColorData[95, i], Lighting -> "Neutral", Mesh -> None, PlotPoints -> 35], {i, 3}]

おもしろい例題  (2)

二次元の部分レベル集合：

Wolfram Language code: Table[RegionPlot[RankedMax[{x, y}, 1] < t, {x, -2, 2}, {y, -2, 2}, PlotLabel -> RankedMax[{x, y}, 1] < t], {t, {-1, 0, 1}}]
Wolfram Language code: Table[RegionPlot[RankedMax[{x, y}, 2] < t, {x, -2, 2}, {y, -2, 2}, PlotLabel -> RankedMax[{x, y}, 2] < t], {t, {-1, 0, 1}}]

三次元の部分レベル集合：

Wolfram Language code: Table[RegionPlot3D[RankedMax[{x, y, z}, 1] < t, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, PlotLabel -> RankedMax[{x, y, z}, 1] < t], {t, {-1, 0, 1}}]
Wolfram Language code: Table[RegionPlot3D[RankedMax[{x, y, z}, 2] < t, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, PlotLabel -> RankedMax[{x, y, z}, 2] < t], {t, {-1, 0, 1}}]
Wolfram Language code: Table[RegionPlot3D[RankedMax[{x, y, z}, 3] < t, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, PlotLabel -> RankedMax[{x, y, z}, 3] < t], {t, {-1, 0, 1}}]
Wolfram Research (2010), RankedMax, Wolfram言語関数， https://reference.wolfram.com/language/ref/RankedMax.html （2024年に更新）.

テキスト

Wolfram Research (2010), RankedMax, Wolfram言語関数， https://reference.wolfram.com/language/ref/RankedMax.html （2024年に更新）.

CMS

Wolfram Language. 2010. "RankedMax." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2024. https://reference.wolfram.com/language/ref/RankedMax.html.

APA

Wolfram Language. (2010). RankedMax. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/RankedMax.html

BibTeX

@misc{reference.wolfram_2026_rankedmax, author="Wolfram Research", title="{RankedMax}", year="2024", howpublished="\url{https://reference.wolfram.com/language/ref/RankedMax.html}", note=[Accessed: 16-July-2026]}

BibLaTeX

@online{reference.wolfram_2026_rankedmax, organization={Wolfram Research}, title={RankedMax}, year={2024}, url={https://reference.wolfram.com/language/ref/RankedMax.html}, note=[Accessed: 16-July-2026]}