WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

ReflectionTransform[v]

ベクトル v にとって法線となる，原点を通った鏡面上の像を表すTransformationFunctionを返す．

ReflectionTransform[v,p]

ベクトル v にとって法線となる点 p を通った鏡面上の像を与える．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
アプリケーション  
特性と関係  
考えられる問題  
おもしろい例題  
関連項目
関連するガイド
履歴
引用書式

ReflectionTransform

ReflectionTransform[v]

ベクトル v にとって法線となる，原点を通った鏡面上の像を表すTransformationFunctionを返す．

ReflectionTransform[v,p]

ベクトル v にとって法線となる点 p を通った鏡面上の像を与える．

詳細

例題

すべて開く すべて閉じる

例  (2)

直線についての反射：

Wolfram Language code: rt = ReflectionTransform[{1, -1}]
Wolfram Language code: rt[{x, y}]

平面での反射：

Wolfram Language code: rt = ReflectionTransform[{0, 0, 1}]
Wolfram Language code: rt[{x, y, z}]

スコープ  (3)

記号単位ベクトル{u, v, w}についての反射変換：

Wolfram Language code: rt = ReflectionTransform[{u, v, w}]//Simplify[#, {Element[{u, v, w}, Reals], u ^ 2 + v ^ 2 + w ^ 2 == 1}]&

{u, v, w}に垂直のベクトルは変化しない：

Wolfram Language code: rt[NullSpace[{{u, v, w}}]] == NullSpace[{{u, v, w}}]//Simplify[#, u ^ 2 + v ^ 2 + w ^ 2 == 1]&

2Dの形に適用された変換：

Wolfram Language code: gr = {Rectangle[], AbsolutePointSize[10], Opacity[1], {Magenta, Point[{0, 0}]}, {Green, Point[{1, 1}]}};
Wolfram Language code: Graphics[{{Opacity[.35], Blue, gr}, GeometricTransformation[{Opacity[.85], Red, gr}, ReflectionTransform[{1, 1}, {-.2, -.2}]]}]

3Dの形に適用された変換：

Wolfram Language code: gr = {Cuboid[], AbsolutePointSize[10], Opacity[1], {Magenta, Point[{0, 0, 0}]}, {Green, Point[{1, 1, 1}]}};
Wolfram Language code: Graphics3D[{{Opacity[.35], Blue, gr}, GeometricTransformation[{Opacity[.85], Red, gr}, ReflectionTransform[{2, 1, 0}, {-.1, -.1, 0}]]}, Boxed -> False]

アプリケーション  (4)

グラフィックスを反射させる：

Wolfram Language code: gr = Plot[E ^ x, {x, -3, 2}];
Wolfram Language code: Show[gr, Plot[x, {x, -3, 7}, PlotStyle -> StandardGray], gr /. L_Line :> {Red, GeometricTransformation[L, ReflectionTransform[{-1, 1}]]}, PlotRange -> All]

正弦波の反射：

Wolfram Language code: Plot[Sin[x], {x, -2Pi, 2Pi}, AspectRatio -> Automatic, Axes -> False, PlotRange -> All] /. L_Line :> Table[GeometricTransformation[L, ReflectionTransform[{Cos[u], Sin[u]}]], {u, Pi / 14Range[7]}]

画像の鏡映：

Wolfram Language code: ImageTransformation[[image], ReflectionTransform[{1, 0}, {.5, 0}]]

3D画像の 軸についての反射変換：

Wolfram Language code: ImageTransformation[\!\(\*Graphics3DBox[«8»]\), ReflectionTransform[{1, 0, 0}], DataRange -> {{-.5, .5}, Automatic, Automatic}]

特性と関係  (5)

反射変換は等長変換，つまり距離を保つ変換である：

Wolfram Language code: t = ReflectionTransform[{1, 2}, {3, 4}];
Wolfram Language code: {p1, p2} = {{10, 17}, {1, 2}}; {tp1, tp2} = t[{p1, p2}];
Wolfram Language code: EuclideanDistance[p1, p2] == EuclideanDistance[tp1, tp2]

反射変換はそれ自身の逆になる：

Wolfram Language code: t = ReflectionTransform[{1, 1, 1}];
Wolfram Language code: InverseFunction[t] == t

変換行列の行列式はである：

Wolfram Language code: t = ReflectionTransform[{1, 2, 3}];
Wolfram Language code: Det[TransformationMatrix[t]]

ReflectionTransformはスケール変換として表すことができる：

Wolfram Language code: t = ReflectionTransform[{1, 1, 1}];
Wolfram Language code: t == ScalingTransform[-1, {1, 1, 1}]

ImageTransformationを使った画像の上下反射：

Wolfram Language code: i = [image]; ImageReflect[i] == ImageTransformation[i, ReflectionTransform[{0, 1}], PlotRange -> All]

主対角についての反射：

Wolfram Language code: ImageReflect[i, Left -> Top] == ImageTransformation[i, ReflectionTransform[{1, 1}], PlotRange -> All]

主反対角についての反射：

Wolfram Language code: ImageReflect[i, Right -> Top] == ImageTransformation[i, ReflectionTransform[{-1, 1}], PlotRange -> All]

考えられる問題  (1)

反射は多角形の向きを変える：

Wolfram Language code: gr = {FaceForm[Red, Blue], Polygon[{{0, 0, 0}, {1, 0, 0}, {0, 1, 0}}]};
Wolfram Language code: {Graphics3D[gr, PlotRange -> {-.1, .1}], Graphics3D[GeometricTransformation[gr, ReflectionMatrix[{0, 0, 1}]], PlotRange -> {-.1, .1}]}

おもしろい例題  (1)

3Dオブジェクトを点 p で反射させる：

Wolfram Language code: cow = ExampleData[{"Geometry3D", "Cow"}, "GraphicsComplex"];
Wolfram Language code: p = {0, 0, -0.251619};

軸に沿って， 平面で：

Wolfram Language code: Graphics3D[{EdgeForm[None], Opacity[0.5], Lighter[ColorData[1, 1], 0.5], cow, Lighter[ColorData[1, 2], 0.5], GeometricTransformation[cow, ReflectionTransform[{1, 0, 0}, p]]}, Lighting -> "Neutral", ImageSize -> Large, Boxed -> False]

軸に沿って， 平面で：

Wolfram Language code: Graphics3D[{EdgeForm[None], Opacity[0.5], Lighter[ColorData[1, 1], 0.5], cow, Lighter[ColorData[1, 2], 0.5], GeometricTransformation[cow, ReflectionTransform[{0, 1, 0}, p]]}, Lighting -> "Neutral", ImageSize -> Large, Boxed -> False]

軸に沿って， 平面で：

Wolfram Language code: Graphics3D[{EdgeForm[None], Opacity[0.5], Lighter[ColorData[1, 1], 0.5], cow, Lighter[ColorData[1, 2], 0.5], GeometricTransformation[cow, ReflectionTransform[{0, 0, 1}, p]]}, Lighting -> "Neutral", ImageSize -> Large, Boxed -> False]
Wolfram Research (2007), ReflectionTransform, Wolfram言語関数， https://reference.wolfram.com/language/ref/ReflectionTransform.html.

テキスト

Wolfram Research (2007), ReflectionTransform, Wolfram言語関数， https://reference.wolfram.com/language/ref/ReflectionTransform.html.

CMS

Wolfram Language. 2007. "ReflectionTransform." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/ReflectionTransform.html.

APA

Wolfram Language. (2007). ReflectionTransform. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/ReflectionTransform.html

BibTeX

@misc{reference.wolfram_2026_reflectiontransform, author="Wolfram Research", title="{ReflectionTransform}", year="2007", howpublished="\url{https://reference.wolfram.com/language/ref/ReflectionTransform.html}", note=[Accessed: 31-October-2026]}

BibLaTeX

@online{reference.wolfram_2026_reflectiontransform, organization={Wolfram Research}, title={ReflectionTransform}, year={2007}, url={https://reference.wolfram.com/language/ref/ReflectionTransform.html}, note=[Accessed: 31-October-2026]}