WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

RegularPolygon[n]

単位円上に等間隔で置かれた n 個の頂点がある正多角形を与える．

RegularPolygon[r,n]

半径 r の正多角形を与える．

RegularPolygon[{r,θ},n]

軸に対して角 θ から始める．

RegularPolygon[{x,y},rspec,n]

多角形の中心を{x,y}にする．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
グラフィックス  
指定  
スタイル付け  
座標  
領域  
アプリケーション  
特性と関係  
おもしろい例題  
関連項目
関連するガイド
関連リンク
履歴
引用書式

RegularPolygon

RegularPolygon[n]

単位円上に等間隔で置かれた n 個の頂点がある正多角形を与える．

RegularPolygon[r,n]

半径 r の正多角形を与える．

RegularPolygon[{r,θ},n]

軸に対して角 θ から始める．

RegularPolygon[{x,y},rspec,n]

多角形の中心を{x,y}にする．

詳細とオプション

  • RegularPolygonは，幾何学領域およびグラフィックスプリミティブとして使うことができる．
  • 角 θ は，正の x 方向から反時計回りにラジアン単位で計測される．
  • 整数 n についてのRegularPolygonは，連続する点の間の角度が等しい多角形を表す．
  • CanonicalizePolygonを使って正多角形を明示的なPolygonオブジェクトに変換することができる．
  • RegularPolygonはGraphicsで使うことができる．
  • グラフィックスでは，点{x,y}は，Scaled，Offset，ImageScaled，Dynamicの式でよく，半径 r は，Scaled，ImageScaled，Dynamicでよい．
  • グラフィックスの描画は，FaceForm，EdgeForm，色等の指示子の影響を受ける．

例題

すべて開く すべて閉じる

例  (3)

五角形：

Wolfram Language code: Graphics[RegularPolygon[5]]

RegularPolygonにさまざまなスタイルを適用する：

Wolfram Language code: ℛ = RegularPolygon[8]; {Graphics[{Pink, ℛ}], Graphics[{EdgeForm[Thick], Pink, ℛ}], Graphics[{EdgeForm[Dashed], Pink, ℛ}], Graphics[{EdgeForm[Directive[Thick, Dashed, Blue]], Pink, ℛ}]}

面積と重心：

Wolfram Language code: Area[RegularPolygon[6]]
Wolfram Language code: RegionCentroid[RegularPolygon[6]]

スコープ  (17)

グラフィックス  (7)

指定  (4)

二等辺三角形，正方形，五角形，六角形等を生成する：

Wolfram Language code: Table[Graphics[RegularPolygon[n]], {n, 3, 10}]

半径が異なる五角形を生成する：

Wolfram Language code: rp = Table[RegularPolygon[r, 5], {r, 1, 4}];
Wolfram Language code: Graphics[{Opacity[0.2], rp}]

さまざまな初期角の三角形を生成する：

Wolfram Language code: rp = Table[RegularPolygon[{1, t Pi / 6}, 3], {t, 4}];
Wolfram Language code: Graphics[{Opacity[0.2], rp}]

6つの六角形を単位円上に等間隔で置く：

Wolfram Language code: cp = CirclePoints[2, 6];
Wolfram Language code: rp = Table[RegularPolygon[p, {1, 0}, 6], {p, cp}];
Wolfram Language code: Graphics[rp]

スタイル付け  (2)

色指示子で正多面体の表面色を指定する：

Wolfram Language code: Table[Graphics[{c, RegularPolygon[7]}], {c, {Red, Green, Blue, Yellow}}]

FaceFormおよびEdgeFormを使って内部と境界のスタイルを指定する：

Wolfram Language code: Graphics[{FaceForm[Pink], EdgeForm[Directive[Dashed, Thick, Blue]], RegularPolygon[7]}]

座標  (1)

Dynamic座標を使う：

Wolfram Language code: Slider2D[Dynamic@a, {0, 3}] Graphics[RegularPolygon[Dynamic[a], 5, 5], Frame -> True, PlotRange -> 5]

動的半径を加える：

Wolfram Language code: Slider[Dynamic@b, {1, 3}] Graphics[RegularPolygon[{0, 0}, Dynamic[b], 5], Frame -> True, PlotRange -> 5]

領域  (10)

埋込み次元：

Wolfram Language code: RegionEmbeddingDimension[RegularPolygon[n]]

幾何次元：

Wolfram Language code: RegionDimension[RegularPolygon[n]]

点の帰属判定：

Wolfram Language code: {RegionMember[RegularPolygon[7], {0, 0}], RegionMember[RegularPolygon[7], {0, 2}]}

点の帰属条件を得る：

Wolfram Language code: RegionMember[RegularPolygon[{0, 0}, {1, 0}, 4], {x, y}]

面積：

Wolfram Language code: ℛ = RegularPolygon[6];
Wolfram Language code: {Area[ℛ], RegionMeasure[ℛ]}

重心：

Wolfram Language code: c = RegionCentroid[ℛ]
Wolfram Language code: Graphics[{{Pink, ℛ}, {Black, Point[c]}}]

点からの距離：

Wolfram Language code: ℛ = RegularPolygon[6];
Wolfram Language code: {RegionDistance[ℛ, {1, 2}], RegionDistance[ℛ, {0, 0}]}

単位円板内の最近点までの距離：

Wolfram Language code: {Plot3D[Evaluate@RegionDistance[ℛ, {x, y}], {x, -2, 2}, {y, -2, 2}, MeshFunctions -> {#3&}, Mesh -> 5, Exclusions -> Norm[{x, y}] == 1], ContourPlot[Evaluate@RegionDistance[ℛ, {x, y}], {x, -3, 3}, {y, -3, 3}, Contours -> {{0.5, Red}, {1, Green}, {1.5, Blue}}]}

点からの符号付き距離：

Wolfram Language code: ℛ = RegularPolygon[6];
Wolfram Language code: {SignedRegionDistance[ℛ, {1, 2}], SignedRegionDistance[ℛ, {0, 0}]}

単位円板までの符号付き距離：

Wolfram Language code: Plot3D[SignedRegionDistance[ℛ, {x, y}], {x, -2, 2}, {y, -2, 2}, MeshFunctions -> {#3&}, Mesh -> {{0}}, MeshShading -> {Red, Green}, Exclusions -> Norm[{x, y}] == 1]

領域内の最近点：

Wolfram Language code: ℛ = RegularPolygon[6];
Wolfram Language code: RegionNearest[ℛ, {5, 6}]

最近点：

Wolfram Language code: pts = Table[2{Cos[k ], Sin[k]}, {k, 0., 15}]; nst = RegionNearest[ℛ, #]& /@ pts;
Wolfram Language code: Legended[Graphics[{{Gray, ℛ}, {Thin, Gray, Line[Transpose[{pts, nst}]]}, {Red, Point[pts]}, {Blue, Point[nst]}}], PointLegend[{Red, Blue}, {"start", "nearest"}]]

正多角形は有界である：

Wolfram Language code: ℛ = RegularPolygon[6];
Wolfram Language code: BoundedRegionQ[ℛ]

その領域を得る：

Wolfram Language code: rr = RegionBounds[ℛ]
Wolfram Language code: Graphics[{StandardGreen, ℛ, {EdgeForm[{Dashed, Red}], Opacity[0.1, Yellow], Cuboid@@Transpose[rr]}}]

六角形上で積分する：

Wolfram Language code: ℛ = RegularPolygon[{Subscript[x, 0], Subscript[y, 0]}, {r, 0}, 6];
Wolfram Language code: Integrate[x y, {x, y}∈ℛ]//Simplify

六角形上で最適化する：

Wolfram Language code: ℛ = RegularPolygon[6];
Wolfram Language code: {MinValue[{x y - x, {x, y}∈ℛ}, {x, y}], ArgMin[{x y - x, {x, y}∈ℛ}, {x, y}]}

六角形内で方程式を解く：

Wolfram Language code: ℛ = RegularPolygon[{1, 2}, {3, 0}, 6];
Wolfram Language code: Solve[x^2 + y^2 == 7 && x y == 1 && {x, y}∈ℛ, {x, y}]
Wolfram Language code: Show[{Graphics[{{StandardGreen, ℛ}, {Blue, Circle[{0, 0}, Sqrt[7]]}}], Plot[1 / x, {x, -3, 5}, PlotRange -> {{-3, 5}, {-3, 6}}], Graphics[{PointSize[Large], Red, Point[{x, y}] /. %}]}, Axes -> True]

アプリケーション  (4)

共通の原点を中心にして回転させた三角形のRegionUnionを取り，星の領域を作る：

Wolfram Language code: ℛ = RegionUnion@@Table[RegularPolygon[{1, t Pi / 6}, 3], {t, 4}];
Wolfram Language code: Region[ℛ]

RegionProductで3Dの押出し形成を作る：

Wolfram Language code: ℛ = RegionProduct[RegularPolygon[5], Line[{{0}, {1}}]];
Wolfram Language code: Region[ℛ]

六角形上で関数をプロットする：

Wolfram Language code: Plot3D[Sin[x + Cos[y]], {x, y}∈RegularPolygon[6]]

格子の中にはセルとして正多角形を持つものがある．格子基底を考える：

Wolfram Language code: b = {{-Sqrt[3], -1}, {-Sqrt[3], 1}};

格子の点とタイルを生成する：

Wolfram Language code: pts = Tuples[Range[0, 4], 2].b;
Wolfram Language code: tiles = Table[RegularPolygon[p, {1, 0}, 6], {p, pts}];

タイル敷きと格子の点を可視化する：

Wolfram Language code: Graphics[{Gray, tiles, Red, Point[pts]}]

特性と関係  (3)

RegularPolygonは， 個の頂点が単位円上に等間隔で置かれたPolygonのことである：

Wolfram Language code: n = 7;
Wolfram Language code: p = Polygon[CirclePoints[n]];
Wolfram Language code: rp = RegularPolygon[n];
Wolfram Language code: Graphics /@ {p, rp}

CirclePointsを使って単位円上に等間隔で置かれた点を生成する：

Wolfram Language code: n = 7; {rp, cp} = {RegularPolygon[n], CirclePoints[n]};
Wolfram Language code: Graphics[{rp, PointSize[Large], Red, Point[cp]}]

とした単位円上の正多角形の面積は，単位Diskのそれである：

Wolfram Language code: Limit[Area[RegularPolygon[n]], n -> Infinity]
Wolfram Language code: Area[Disk[]]

おもしろい例題  (2)

ランダムな正多角形の集合：

Wolfram Language code: Graphics[{EdgeForm[Black], Table[{Opacity[0.2], Hue[RandomReal[]], RegularPolygon[RandomReal[9, 2], {RandomReal[], 0}, RandomInteger[{3, 7}]]}, {200}]}]

半径と頂点数が大きくなっていく，重なり合う正多角形：

Wolfram Language code: rp = Table[RegularPolygon[r, r + 2], {r, 9}];
Wolfram Language code: Graphics[{Opacity[0.15], rp}]
Wolfram Research (2015), RegularPolygon, Wolfram言語関数， https://reference.wolfram.com/language/ref/RegularPolygon.html （2019年に更新）.

テキスト

Wolfram Research (2015), RegularPolygon, Wolfram言語関数， https://reference.wolfram.com/language/ref/RegularPolygon.html （2019年に更新）.

CMS

Wolfram Language. 2015. "RegularPolygon." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2019. https://reference.wolfram.com/language/ref/RegularPolygon.html.

APA

Wolfram Language. (2015). RegularPolygon. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/RegularPolygon.html

BibTeX

@misc{reference.wolfram_2026_regularpolygon, author="Wolfram Research", title="{RegularPolygon}", year="2019", howpublished="\url{https://reference.wolfram.com/language/ref/RegularPolygon.html}", note=[Accessed: 03-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_regularpolygon, organization={Wolfram Research}, title={RegularPolygon}, year={2019}, url={https://reference.wolfram.com/language/ref/RegularPolygon.html}, note=[Accessed: 03-November-2026]}