WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

RescalingTransform[{{xmin,xmax},{ymin,ymax},…},{{xpmin,xpmax},…}]

座標 xminから xmaxまで等の範囲を座標 xpminから xpmaxまで等の範囲に再スケールするTransformationFunctionを返す．

RescalingTransform[{{xmin,xmax},{ymin,ymax},…}]

単位正方形，立方体等に再スケールするTransformationFunctionを返す．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
アプリケーション  
特性と関係  
おもしろい例題  
関連項目
関連するガイド
履歴
引用書式

RescalingTransform

RescalingTransform[{{xmin,xmax},{ymin,ymax},…},{{xpmin,xpmax},…}]

座標 xminから xmaxまで等の範囲を座標 xpminから xpmaxまで等の範囲に再スケールするTransformationFunctionを返す．

RescalingTransform[{{xmin,xmax},{ymin,ymax},…}]

単位正方形，立方体等に再スケールするTransformationFunctionを返す．

詳細

例題

すべて開く すべて閉じる

例  (2)

長方形をに再スケールする：

Wolfram Language code: t = RescalingTransform[{{xmin, xmax}, {ymin, ymax}}]

これで，{xmax,ymax}を{1,1}にマップする：

Wolfram Language code: t[{xmax, ymax}]//Simplify

立方体をに再スケールする：

Wolfram Language code: t = RescalingTransform[{{xmin, xmax}, {ymin, ymax}, {zmin, zmax}}]

{xmax,ymax,zmax}を{1,1,1}にマップする：

Wolfram Language code: t[{xmax, ymax, zmax}]//Simplify

スコープ  (3)

長方形を長方形に変換する：

Wolfram Language code: t = RescalingTransform[{{l1, u1}, {l2, u2}}, {{L1, U1}, {L2, U2}}]

これは，もとの長方形の中点を目的の長方形の中点にする：

Wolfram Language code: t[{(l1 + u1) / 2, (l2 + u2) / 2}]//Simplify

2Dの形に適用された変換：

Wolfram Language code: gr = {Rectangle[], AbsolutePointSize[10], Opacity[1], {Magenta, Point[{0, 0}]}, {Green, Point[{1, 1}]}};
Wolfram Language code: Graphics[{{Opacity[.35], Blue, gr}, GeometricTransformation[{Opacity[.85], Red, gr}, RescalingTransform[{{0, 1}, {0, 1}}, {{1.1, 2.1}, {0, 1.5}}]]}]

3Dの形に適用された変換：

Wolfram Language code: gr = {Cuboid[], AbsolutePointSize[10], Opacity[1], {Magenta, Point[{0, 0, 0}]}, {Green, Point[{1, 1, 1}]}};
Wolfram Language code: Graphics3D[{{Opacity[.35], Blue, gr}, GeometricTransformation[{Opacity[.85], Red, gr}, RescalingTransform[{{0, 1}, {0, 1}, {0, 1}}, {{1.2, 2.2}, {0, 1.5}, {0, .5}}]]}, Boxed -> False]

アプリケーション  (5)

グラフィックスプリミティブを変換する：

Wolfram Language code: Graphics3D[{{Opacity[.5], Cuboid[]}, GeometricTransformation[Cylinder[], RescalingTransform[{{-1, 1}, {-1, 1}, {-1, 1}}]]}, Boxed -> False]

2Dにおけるユーザ座標からスケールされた(Scaled)座標への変換を計算する：

Wolfram Language code: userToScaled = RescalingTransform[{{xmin, xmax}, {ymin, ymax}}, {{0, 1}, {0, 1}}]

特定の座標を変換する：

Wolfram Language code: userToScaled /@ {{xmin, ymin}, {(xmin + xmax) / 2, ymax}}//Simplify

スケールされた(Scaled)座標からユーザ座標への変換を計算する：

Wolfram Language code: scaledToUser = RescalingTransform[{{0, 1}, {0, 1}}, {{xmin, xmax}, {ymin, ymax}}]

特定の座標を変換する：

Wolfram Language code: scaledToUser /@ {{0, 1 / 3}, {1 / 2, 1}}//Simplify

3Dにおけるユーザ座標からスケールされた(Scaled)座標への変換を計算する：

Wolfram Language code: userToScaled = RescalingTransform[{{xmin, xmax}, {ymin, ymax}, {zmin, zmax}}, {{0, 1}, {0, 1}, {0, 1}}]

特定の座標を変換する：

Wolfram Language code: userToScaled /@ {{xmin, ymin, zmin}, {(xmin + xmax) / 2, ymax, zmax}}//Simplify

スケールされた(Scaled)座標からユーザ座標への変換を計算する：

Wolfram Language code: scaledToUser = RescalingTransform[{{0, 1}, {0, 1}, {0, 1}}, {{xmin, xmax}, {ymin, ymax}, {zmin, zmax}}]

特定の座標を変換する：

Wolfram Language code: scaledToUser /@ {{0, 1 / 3, 1 / 2}, {1 / 2, 1, 1}}//Simplify

ユーザ定義の座標から特定のプロット範囲(PlotRange)を持つスケールされた(Scaled )座標に変換する：

Wolfram Language code: pr = {{-1, 3}, {-1, 4}}; scaled = RescalingTransform[pr]

ユーザ定義の座標で円板を，スケールされた(Scaled )座標で円を指定する：

Wolfram Language code: Graphics[{Cyan, Disk[{2, 2}], Thick, Red, Circle[Scaled[scaled[{2, 2}]]]}, PlotRange -> pr, Axes -> True]

スクリーンから突き出している 軸を使ってOpenGLのモデルビュー変換を計算する：

Wolfram Language code: modelTransform = RescalingTransform[{{left, right}, {bottom, top}, {far, near}}, {{-1, 1}, {-1, 1}, {-1, 1}}]//Simplify

ユーザ座標から標準的なモデル座標に変換する：

Wolfram Language code: modelTransform /@ {{left, bottom, far}, {right, top, near}}//Simplify

特性と関係  (3)

RescalingTransform[{{l1,u1},…},{{L1,U1},…}]の逆はRescalingTransform[{{L1,U1},…},{{l1,u1},…}]で与えられる：

Wolfram Language code: t1 = RescalingTransform[{{l1, u1}, {l2, u2}}, {{L1, U1}, {L2, U2}}]; t2 = RescalingTransform[{{L1, U1}, {L2, U2}}, {{l1, u1}, {l2, u2}}];

t1とt2が逆であることを示す：

Wolfram Language code: Composition[t1, t2]//Simplify

再スケール変換はスケールと変換の合成である：

Wolfram Language code: RescalingTransform[{{a, b}}] == Composition[TranslationTransform[{-a / (b - a)}], ScalingTransform[{1 / (b - a)}]]

RescaleはRescalingTransformのスカラー版を与える：

Wolfram Language code: Rescale[x, {Subscript[l, 1], Subscript[u, 1]}, {Subscript[L, 1], Subscript[U, 1]}] == First@RescalingTransform[{{Subscript[l, 1], Subscript[u, 1]}}, {{Subscript[L, 1], Subscript[U, 1]}}][{x}]//Simplify

おもしろい例題  (1)

ランダムに再スケールされた直方体の集合：

Wolfram Language code: Graphics3D[Table[GeometricTransformation[Cuboid[], RescalingTransform[{{0, 1}, {0, 1}, {0, 1}}, RandomReal[1, {3, 2}]]], {30}]]
Wolfram Research (2007), RescalingTransform, Wolfram言語関数， https://reference.wolfram.com/language/ref/RescalingTransform.html.

テキスト

Wolfram Research (2007), RescalingTransform, Wolfram言語関数， https://reference.wolfram.com/language/ref/RescalingTransform.html.

CMS

Wolfram Language. 2007. "RescalingTransform." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/RescalingTransform.html.

APA

Wolfram Language. (2007). RescalingTransform. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/RescalingTransform.html

BibTeX

@misc{reference.wolfram_2026_rescalingtransform, author="Wolfram Research", title="{RescalingTransform}", year="2007", howpublished="\url{https://reference.wolfram.com/language/ref/RescalingTransform.html}", note=[Accessed: 05-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_rescalingtransform, organization={Wolfram Research}, title={RescalingTransform}, year={2007}, url={https://reference.wolfram.com/language/ref/RescalingTransform.html}, note=[Accessed: 05-August-2026]}