WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

SliceDistribution[proc,t]

時間 t における過程状態の分布を表す．

SliceDistribution[proc,{t1,…,tk}]

時間 t1<⋯<tkにおける過程状態の結合分布を表す．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
特性と関係  
考えられる問題  
関連項目
関連するガイド
履歴
引用書式

SliceDistribution

SliceDistribution[proc,t]

時間 t における過程状態の分布を表す．

SliceDistribution[proc,{t1,…,tk}]

時間 t1<⋯<tkにおける過程状態の結合分布を表す．

詳細

  • SliceDistribution[proc,t]は proc[t]として入力することができる．
  • SliceDistribution[proc,{t1,…,tk}]は proc[{t1,…,tk}]として入力することができる．
  • ランダム過程 xproc の場合，時間 t におけるその状態は確率変数 x[t]proc[t]であり，時間 t1, …, tkにおけるその状態は確率変数{x[t1],…,x[tk]}proc[{t1,…,tk}]である．
  • SliceDistributionは可能な場合は常に既知の特殊分布に簡約される．
  • SliceDistributionは，Mean，CDF，RandomVariate等の関数で使うことができる．

例題

すべて開く すべて閉じる

例  (3)

PoissonProcessの一変量スライス分布を求める：

Wolfram Language code: SliceDistribution[PoissonProcess[λ], t]

WienerProcessの二変量スライス分布を求める：

Wolfram Language code: WienerProcess[][{s, t}]

移動平均時系列の多変量スライス分布を求める：

Wolfram Language code: SliceDistribution[MAProcess[{2, 4}, 1], {1, 2, 3}]

これは，自動評価は行わないが，分布のような動作を示す：

Wolfram Language code: Mean[%]

スコープ  (3)

スライス分布は分布のように振る舞う：

Wolfram Language code: 𝒟 = SliceDistribution[TelegraphProcess[3], 1]

確率密度関数：

Wolfram Language code: PDF[𝒟, x]

特性関数：

Wolfram Language code: CharacteristicFunction[𝒟, x]

モーメント：

Wolfram Language code: Moment[𝒟, r]

擬似乱数の集合を生成する：

Wolfram Language code: sample = RandomVariate[𝒟, 20]
Wolfram Language code: ListStepPlot[sample]

スライス分布は自動評価で既知の分布になることがある：

Wolfram Language code: SliceDistribution[WienerProcess[μ, σ], t]
Wolfram Language code: SliceDistribution[WienerProcess[μ, σ], {s, t}]
Wolfram Language code: SliceDistribution[OrnsteinUhlenbeckProcess[μ, σ, θ], t]
Wolfram Language code: SliceDistribution[WienerProcess[μ, σ], {s, t}]
Wolfram Language code: SliceDistribution[OrnsteinUhlenbeckProcess[μ, σ, θ, Subscript[x, 0]], t]
Wolfram Language code: SliceDistribution[OrnsteinUhlenbeckProcess[μ, σ, θ, Subscript[x, 0]], {s, t}]
Wolfram Language code: SliceDistribution[BernoulliProcess[p], t]
Wolfram Language code: SliceDistribution[BernoulliProcess[p], {s, t, w}]
Wolfram Language code: SliceDistribution[BinomialProcess[p], t]
Wolfram Language code: SliceDistribution[PoissonProcess[p], t]
Wolfram Language code: SliceDistribution[CompoundPoissonProcess[λ, GammaDistribution[a, b]], t]

M/M/待ち行列のためのスライス分布：

Wolfram Language code: 𝒬 = QueueingProcess[λ, μ, ∞];
Wolfram Language code: 𝒟 = SliceDistribution[𝒬, t];

確率密度関数：

Wolfram Language code: PDF[𝒟, x]
Wolfram Language code: Sum[%, {x, 0, ∞}]

累積分布関数：

Wolfram Language code: CDF[𝒟, x]//FullSimplify

スライス分布の平均：

Wolfram Language code: m = Mean[𝒟]

tが に近付く際の平均の極限を求める：

Wolfram Language code: Limit[m, t -> Infinity, Assumptions -> λ > 0 && μ > 0]

これは対応するStationaryDistributionの平均と一致する：

Wolfram Language code: Mean[StationaryDistribution[𝒬]]

同時に定常状態の平均の系のサイズとも一致する：

Wolfram Language code: QueueProperties[𝒬, "MeanSystemSize"]

特性と関係  (2)

無限大におけるスライス分布はStationaryDistributionである：

Wolfram Language code: SliceDistribution[OrnsteinUhlenbeckProcess[μ, σ, θ, Subscript[x, 0]], ∞]
Wolfram Language code: StationaryDistribution[OrnsteinUhlenbeckProcess[μ, σ, θ, Subscript[x, 0]]]

確率の計算に暗黙の時間を使う：

Wolfram Language code: Probability[x[t] ^ 2 + x[t] < 34, xPoissonProcess[μ]]

スライス分布を使って同じ結果を得る：

Wolfram Language code: Probability[x ^ 2 + x < 34, xPoissonProcess[μ][t]]

変数 x[t]で暗黙の時間を使って期待値を計算する：

Wolfram Language code: Expectation[x[t] ^ 2 + x[t] + 3E ^ (-x[t]), xPoissonProcess[μ]]

スライス分布を使って同じ結果を得る：

Wolfram Language code: Expectation[x ^ 2 + x + 3E ^ (-x), xPoissonProcess[μ][t]]

考えられる問題  (1)

連続時間ランダムん過程の中には，スライス分布のシミュレーションがうまく定義されていないものがある：

Wolfram Language code: proc = ItoProcess[ⅆx[t] == -x[t] ⅆt + Sqrt[1 + x[t] ^ 2] ⅆw[t], x[t], {x, 1}, t, wWienerProcess[]];
Wolfram Language code: RandomVariate[SliceDistribution[proc, 1]]

開始時間と終了時間の間の過程の経路のシミュレーションは，ステップの選択によって異なる：

Wolfram Language code: Table[SeedRandom[1];RandomFunction[proc, {0, 1, step}]["LastValue"], {step, {0.001, .005, .01, .03, .05, .07, .09, .1, .3, .5, .7, .9, 1}}]

数ステップを選択したスライス分布のシミュレーションは，厳密なスライス分布の近似を示している：

Wolfram Language code: sim = Table[SeedRandom[1];RandomFunction[proc, {0, 1, step}, 10 ^ 4]["LastValues"], {step, r = {0.001, .005, .01, .05, .1, .5}}];
Wolfram Language code: Table[Histogram[sim[[k]], {-2, 4, .5}, PDF, PlotLabel -> Row[{"Step = ", r[[k]]}]], {k, Length[sim]}]
Wolfram Research (2012), SliceDistribution, Wolfram言語関数， https://reference.wolfram.com/language/ref/SliceDistribution.html.

テキスト

Wolfram Research (2012), SliceDistribution, Wolfram言語関数， https://reference.wolfram.com/language/ref/SliceDistribution.html.

CMS

Wolfram Language. 2012. "SliceDistribution." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/SliceDistribution.html.

APA

Wolfram Language. (2012). SliceDistribution. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/SliceDistribution.html

BibTeX

@misc{reference.wolfram_2026_slicedistribution, author="Wolfram Research", title="{SliceDistribution}", year="2012", howpublished="\url{https://reference.wolfram.com/language/ref/SliceDistribution.html}", note=[Accessed: 15-July-2026]}

BibLaTeX

@online{reference.wolfram_2026_slicedistribution, organization={Wolfram Research}, title={SliceDistribution}, year={2012}, url={https://reference.wolfram.com/language/ref/SliceDistribution.html}, note=[Accessed: 15-July-2026]}