WOLFRAM

Wolfram 语言与系统参考资料中心

SystemsModelParallelConnect[sys1,sys2]

并行连接系统模型 sys1 和 sys2.

SystemsModelParallelConnect[sys1,sys2,{{in11,in21},…},{{out11,out21},…}]

把输入 in1i 连接到输入 in2i，并且对输出 out1k 和输出 out2k 求和.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
基本用途  
系统类型  
推广和延伸  
应用  
属性和关系  
参见
相关指南
历史
按以下格式引用：

SystemsModelParallelConnect

SystemsModelParallelConnect[sys1,sys2]

并行连接系统模型 sys1 和 sys2.

SystemsModelParallelConnect[sys1,sys2,{{in11,in21},…},{{out11,out21},…}]

把输入 in1i 连接到输入 in2i，并且对输出 out1k 和输出 out2k 求和.

更多信息

范例

打开所有单元 关闭所有单元

基本范例  (4)

并行连接两个连续时间系统：

Wolfram Language code: SystemsModelParallelConnect[TransferFunctionModel[{{{1}}, s*α}, s], TransferFunctionModel[{{{b + s}}, a + s}, s]]

并行连接两个离散时间系统：

Wolfram Language code: SystemsModelParallelConnect[TransferFunctionModel[{{{b + z}}, a + z}, z, SamplingPeriod -> T], TransferFunctionModel[{{{z + β}}, z + α}, z, SamplingPeriod -> T]]

连接状态空间系统：

Wolfram Language code: SystemsModelParallelConnect[StateSpaceModel[{{{0, 1}, {-Subscript[α, 0], -Subscript[α, 1]}}, {{0}, {1}}, {{Subscript[β, 0], Subscript[β, 1]}}, {{0}}}, SamplingPeriod -> None, SystemsModelLabels -> None], StateSpaceModel[{{{0, 1, 0}, {0, 0, 1}, {-Subscript[a, 0], -Subscript[a, 1], -Subscript[a, 2]}}, {{0}, {0}, {1}}, {{Subscript[b, 0], Subscript[b, 1], Subscript[b, 2]}}, {{0}}}, SamplingPeriod -> None, SystemsModelLabels -> None]]

并行连接一个双输出、单输入系统和一个单输入单输出系统：

Wolfram Language code: {sys1, sys2} = {TransferFunctionModel[{{{Subscript[k, 1]}, {Subscript[k, 2]}}, {{z + Subscript[β, 1]}, {z + Subscript[β, 2]}}}, z, SamplingPeriod -> 1], TransferFunctionModel[{{{b}}, a + z}, z, SamplingPeriod -> 1]};

不合并输入，不对输出求和：

Wolfram Language code: SystemsModelParallelConnect[sys1, sys2, None, None]

合并输入，不对输出求和：

Wolfram Language code: SystemsModelParallelConnect[sys1, sys2, All, None]

不合并输入，对 sys1 的输出2和 sys2 的输出1求和：

Wolfram Language code: SystemsModelParallelConnect[sys1, sys2, None, {{2, 1}}]

合并输入，对 sys1 的输出2和 sys2 的输出1求和：

Wolfram Language code: SystemsModelParallelConnect[sys1, sys2, All, {{2, 1}}]

范围  (14)

基本用途  (7)

将双输入单输出系统与单输入单输出系统并行连接：

Wolfram Language code: {Subscript[tfm, 1], Subscript[tfm, 2]} = {TransferFunctionModel[{{{Subscript[a, 1], Subscript[a, 2]}}, s}, s], TransferFunctionModel[{{{b}}, s}, s]};

使用双输入系统的第一个输入：

Wolfram Language code: SystemsModelParallelConnect[Subscript[tfm, 1], Subscript[tfm, 2], {{1, 1}}, All]

使用第二个输入：

Wolfram Language code: SystemsModelParallelConnect[Subscript[tfm, 1], Subscript[tfm, 2], {{2, 1}}, All]

将一个双输出系统与单输出系统并行连接：

Wolfram Language code: {Subscript[tfm, 1], Subscript[tfm, 2]} = {TransferFunctionModel[{{{Subscript[a, 1]}, {Subscript[a, 2]}}, s}, s], TransferFunctionModel[{{{b}}, s}, s]};

使用双输入系统的第一个输出：

Wolfram Language code: SystemsModelParallelConnect[Subscript[tfm, 1], Subscript[tfm, 2], All, {{1, 1}}]

使用第二个输出：

Wolfram Language code: SystemsModelParallelConnect[Subscript[tfm, 1], Subscript[tfm, 2], All, {{2, 1}}]

连接标量系统：

Wolfram Language code: SystemsModelParallelConnect[StateSpaceModel[{{{Subscript[a, 11], Subscript[a, 12]}, {Subscript[a, 21], Subscript[a, 22]}}, {{Subscript[b, 11]}, {Subscript[b, 21]}}, {{Subscript[c, 11], Subscript[c, 12]}}, {{0}}}, SamplingPeriod -> None, SystemsModelLabels -> None], StateSpaceModel[{{{Subscript[α, 11], Subscript[α, 12]}, {Subscript[α, 21], Subscript[α, 22]}}, {{Subscript[β, 11]}, {Subscript[β, 21]}}, {{Subscript[γ, 11], Subscript[γ, 12]}}, {{0}}}, SamplingPeriod -> None, SystemsModelLabels -> None]]

连接多变量系统：

Wolfram Language code: SystemsModelParallelConnect[StateSpaceModel[{{{Subscript[a, 11], Subscript[a, 12]}, {Subscript[a, 21], Subscript[a, 22]}}, {{Subscript[b, 11], Subscript[b, 12]}, {Subscript[b, 21], Subscript[b, 22]}}, {{Subscript[c, 11], Subscript[c, 12]}}, {{0, 0}}}, SamplingPeriod -> None, SystemsModelLabels -> None], StateSpaceModel[{{{Subscript[α, 11], Subscript[α, 12]}, {Subscript[α, 21], Subscript[α, 22]}}, {{Subscript[β, 11], Subscript[β, 12]}, {Subscript[β, 21], Subscript[β, 22]}}, {{Subscript[γ, 11], Subscript[γ, 12]}}, {{0, 0}}}, SamplingPeriod -> None, SystemsModelLabels -> None]]

合并第二个输入，并且对每个系统的第一个输出求和：

Wolfram Language code: SystemsModelParallelConnect[StateSpaceModel[{{{Subscript[a, 11], Subscript[a, 12]}, {Subscript[a, 21], Subscript[a, 22]}}, {{Subscript[b, 11], Subscript[b, 12]}, {Subscript[b, 21], Subscript[b, 22]}}, {{Subscript[c, 11], Subscript[c, 12]}, {Subscript[c, 21], Subscript[c, 22]}}, {{Subscript[d, 11], Subscript[d, 12]}, {Subscript[d, 21], Subscript[d, 22]}}}, SamplingPeriod -> None, SystemsModelLabels -> None], StateSpaceModel[{{{Subscript[α, 11], Subscript[α, 12]}, {Subscript[α, 21], Subscript[α, 22]}}, {{Subscript[β, 11], Subscript[β, 12]}, {Subscript[β, 21], Subscript[β, 22]}}, {{Subscript[γ, 11], Subscript[γ, 12]}}, {{Subscript[D, 11], Subscript[D, 12]}}}, SamplingPeriod -> None, SystemsModelLabels -> None], {{2, 2}}, {{1, 1}}]

将 StateSpaceModel 与 TransferFunctionModel 连接：

Wolfram Language code: SystemsModelParallelConnect[StateSpaceModel[{{{Subscript[a, 11], Subscript[a, 12]}, {Subscript[a, 21], Subscript[a, 22]}}, {{Subscript[b, 11]}, {Subscript[b, 21]}}, {{Subscript[c, 11], Subscript[c, 12]}}, {{0}}}, SamplingPeriod -> None, SystemsModelLabels -> None], TransferFunctionModel[{{{k}}, s + α}, s]]

连接离散时间系统：

Wolfram Language code: SystemsModelParallelConnect[StateSpaceModel[{{{0, 1}, {-5, -6}}, {{0}, {1}}, {{k, 0}}, {{0}}}, SamplingPeriod -> τ], TransferFunctionModel[{{{k}}, 1 + z}, z, SamplingPeriod -> τ]]

系统类型  (7)

连接两个 TransferFunctionModel 系统：

Wolfram Language code: SystemsModelParallelConnect[TransferFunctionModel[{{{a}}, p + s}, s], TransferFunctionModel[{{{α}}, s + ρ}, s]]

具有延迟：

Wolfram Language code: SystemsModelParallelConnect[TransferFunctionModel[{{{a/E^(s*T)}}, p + s}, s], TransferFunctionModel[{{{α/E^(s*τ)}}, s + ρ}, s]]

使用不恰当的传递函数：

Wolfram Language code: SystemsModelParallelConnect[TransferFunctionModel[{{{a + s}}, 1}, s], TransferFunctionModel[{{{s + α}}, 1}, s]]

连接两个 StateSpaceModel 系统：

Wolfram Language code: SystemsModelParallelConnect[StateSpaceModel[{{{a}}, {{b}}, {{c}}, {{d}}}, SamplingPeriod -> None, SystemsModelLabels -> None], StateSpaceModel[{{{α}}, {{β}}, {{γ}}, {{ρ}}}, SamplingPeriod -> None, SystemsModelLabels -> None]]

具有延迟：

Wolfram Language code: SystemsModelParallelConnect[StateSpaceModel[{{{a + SystemsModelDelay[Subscript[τ, 1]]}}, {{b}}, {{c}}, {{d}}}, SamplingPeriod -> None, SystemsModelLabels -> None], StateSpaceModel[{{{α + SystemsModelDelay[Subscript[τ, 2]]}}, {{β}}, {{γ}}, {{ρ}}}, SamplingPeriod -> None, SystemsModelLabels -> None]]

使用描述器状态空间模型：

Wolfram Language code: SystemsModelParallelConnect[StateSpaceModel[{{{a}}, {{b}}, {{c}}, {{d}}, {{e}}}, SamplingPeriod -> None, SystemsModelLabels -> None], StateSpaceModel[{{{α}}, {{β}}, {{γ}}, {{ρ}}, {{η}}}, SamplingPeriod -> None, SystemsModelLabels -> None]]

输入线性 AffineStateSpaceModel 系统：

Wolfram Language code: SystemsModelParallelConnect[AffineStateSpaceModel[{{a[Subscript[x, 1]]}, {{b[Subscript[x, 1]]}}, {c[Subscript[x, 1]]}, {{d[Subscript[x, 1]]}}}, {Subscript[x, 1]}, {Subscript[, 1]}, {Automatic}, Automatic, SamplingPeriod -> None], AffineStateSpaceModel[{{α[Subscript[x, 2]]}, {{β[Subscript[x, 2]]}}, {γ[Subscript[x, 2]]}, {{ρ[Subscript[x, 2]]}}}, {Subscript[x, 2]}, {Subscript[, 1]}, {Automatic}, Automatic, SamplingPeriod -> None]]

一般非线性 NonlinearStateSpaceModel 系统：

Wolfram Language code: SystemsModelParallelConnect[NonlinearStateSpaceModel[{{Subscript[f, 1][Subscript[x, 1], Subscript[u, 1]]}, {Subscript[h, 1][Subscript[x, 1], Subscript[u, 1]]}}, {Subscript[x, 1]}, {Subscript[u, 1]}, {Automatic}, Automatic, SamplingPeriod -> None], NonlinearStateSpaceModel[{{Subscript[f, 2][Subscript[x, 2], Subscript[u, 2]]}, {Subscript[h, 2][Subscript[x, 2], Subscript[u, 2]]}}, {Subscript[x, 2]}, {Subscript[u, 2]}, {Automatic}, Automatic, SamplingPeriod -> None]]

连接传递函数与状态空间模型将给出状态空间模型：

Wolfram Language code: ssm1 = SystemsModelParallelConnect[TransferFunctionModel[{{{k*(s + Subscript[z, 1])}}, s + Subscript[p, 1]}, s], StateSpaceModel[{{{a}}, {{b}}, {{c}}, {{0}}}, SamplingPeriod -> None, SystemsModelLabels -> None]]

将顺序倒过来将给出一个等价的状态空间模型：

Wolfram Language code: ssm2 = SystemsModelParallelConnect[StateSpaceModel[{{{a}}, {{b}}, {{c}}, {{0}}}, SamplingPeriod -> None, SystemsModelLabels -> None], TransferFunctionModel[{{{k*(s + Subscript[z, 1])}}, s + Subscript[p, 1]}, s]]

它们给出相同的传递函数：

Wolfram Language code: TransferFunctionModel /@ {ssm1, ssm2}//Simplify

使用延迟连接：

Wolfram Language code: SystemsModelParallelConnect[TransferFunctionModel[{{{(k*(s + Subscript[z, 1]))/ E^(s*Subscript[τ, 1])}}, s + Subscript[p, 1]}, s], StateSpaceModel[{{{a + SystemsModelDelay[Subscript[τ, 2]]}}, {{b}}, {{c}}, {{d}}}, SamplingPeriod -> None, SystemsModelLabels -> None]]

连接标准线性系统和输入线性系统将给出一个仿射模型：

Wolfram Language code: SystemsModelParallelConnect[TransferFunctionModel[{{{k*(s + Subscript[z, 1])}}, s + Subscript[p, 1]}, s], AffineStateSpaceModel[{{α[x]}, {{β[x]}}, {γ[x]}, {{ρ[x]}}}, {x}, {Subscript[, 1]}, {Automatic}, Automatic, SamplingPeriod -> None]]
Wolfram Language code: SystemsModelParallelConnect[StateSpaceModel[{{{a}}, {{b}}, {{c}}, {{d}}}, SamplingPeriod -> None, SystemsModelLabels -> None], AffineStateSpaceModel[{{α[x]}, {{β[x]}}, {γ[x]}, {{ρ[x]}}}, {x}, {Subscript[, 1]}, {Automatic}, Automatic, SamplingPeriod -> None]]

连接非线性系统和标准线性系统或仿射系统将给出一个非线性模型：

Wolfram Language code: SystemsModelParallelConnect[StateSpaceModel[{{{a}}, {{b}}, {{c}}, {{d}}}, SamplingPeriod -> None, SystemsModelLabels -> None], NonlinearStateSpaceModel[{{f[x, u]}, {h[x, u]}}, {x}, {u}, {Automatic}, Automatic, SamplingPeriod -> None]]
Wolfram Language code: SystemsModelParallelConnect[AffineStateSpaceModel[{{a[x]}, {{b[x]}}, {c[x]}, {{d[x]}}}, {x}, {Subscript[, 1]}, {Automatic}, Automatic, SamplingPeriod -> None], NonlinearStateSpaceModel[{{f[x, u]}, {h[x, u]}}, {x}, {u}, {Automatic}, Automatic, SamplingPeriod -> None]]

推广和延伸  (3)

合并两个系统：

Wolfram Language code: {tf1, tf2} = {TransferFunctionModel[{{{1, 1}}, {{s, 1 + s}}}, s], TransferFunctionModel[{{{1}, {1}}, {{2 + s}, {3 + s}}}, s]};
Wolfram Language code: SystemsModelParallelConnect[tfm1, tfm2, {}, {}]

Connect the corresponding inputs:

Wolfram Language code: {tf1, tf2} = {TransferFunctionModel[{{{Subscript[a, 11], Subscript[a, 12]}}, {{1 + s*Subscript[b, 11], 1 + s*Subscript[b, 12]}}}, s], TransferFunctionModel[{{{Subscript[A, 11], Subscript[A, 12]}, {Subscript[A, 21], Subscript[A, 22]}}, {{1 + s*Subscript[B, 11], 1 + s*Subscript[B, 12]}, {1 + s*Subscript[B, 21], 1 + s*Subscript[B, 22]}}}, s]};
Wolfram Language code: SystemsModelParallelConnect[tf1, tf2, All, {}]

对相应的输出求和：

Wolfram Language code: {tf1, tf2} = {TransferFunctionModel[{{{Subscript[a, 11]}, {Subscript[a, 21]}}, {{1 + s*Subscript[b, 11]}, {1 + s*Subscript[b, 21]}}}, s], TransferFunctionModel[{{{Subscript[A, 11]}, {Subscript[A, 21]}}, {{1 + s*Subscript[B, 11]}, {1 + s*Subscript[B, 21]}}}, s]};
Wolfram Language code: SystemsModelParallelConnect[tf1, tf2, {}, All]

应用  (3)

一个并行连接任何数目的匹配系统的函数：

Wolfram Language code: parallel[s__] := Fold[SystemsModelParallelConnect, First[{s}], Rest[{s}]]

并行连接一阶系统族：

Wolfram Language code: parallel@@Table[TransferFunctionModel[{{{1}}, i + s}, s], {i, 0, 3}]

连接若干个多输入多输出系统：

Wolfram Language code: {Subscript[tfm, 1], Subscript[tfm, 2], Subscript[tfm, 3]} = {TransferFunctionModel[{{{1, 1 + s}, {3*s, 1}}, {{s, s}, {1 + s, 1 + s}}}, s], TransferFunctionModel[{{{4 + s, 4 + s}, {s, s}}, {{6 + s, 3 + s}, {6 + s, 3 + s}}}, s], TransferFunctionModel[{{{5*s, 0}, {0, 1}}, {{1 + s, 1}, {1, 1 + s}}}, s]}; parallel[Subscript[tfm, 1], Subscript[tfm, 2], Subscript[tfm, 3]]

构建一个并行 RLC 电路：

Wolfram Language code: {resistance, inductance, capacitance} = {TransferFunctionModel[{{{1}}, r*s}, s], TransferFunctionModel[{{{1}}, l*s^2}, s], TransferFunctionModel[{{{c}}, 1}, s]};
Wolfram Language code: SystemsModelParallelConnect[resistance, SystemsModelParallelConnect[inductance, capacitance]]//Simplify

对系统输出添加扰动模型：

Wolfram Language code: {tfm, disturbanceModel} = {TransferFunctionModel[{{{s, 2.1, 4}, {3, 4*s, 3 + s}}, {{6 + s + s^2, 1 + s, 3.5 + 2*s + s^2}, {1 + s, 6 + s + s^2, 1 + s}}}, s], TransferFunctionModel[{{{-4 + s}}, 13 - 6*s + s^2}, s]};
Wolfram Language code: SystemsModelParallelConnect[tfm, disturbanceModel, {}, {{1, 1}}]

属性和关系  (3)

SystemsModelParallelConnect 基本上是一个求和操作：

Wolfram Language code: SystemsModelParallelConnect[TransferFunctionModel[{{{Subscript[m1, 1, 1], Subscript[m1, 1, 2], Subscript[m1, 1, 3]}, {Subscript[m1, 2, 1], Subscript[m1, 2, 2], Subscript[m1, 2, 3]}}, 1}, s], TransferFunctionModel[{{{Subscript[m2, 1, 1], Subscript[m2, 1, 2], Subscript[m2, 1, 3]}, {Subscript[m2, 2, 1], Subscript[m2, 2, 2], Subscript[m2, 2, 3]}}, 1}, s]]

SystemsModelParallelConnect 是 SystemsConnectionsModel 的特殊情况：

Wolfram Language code: {Subscript[sys, 1], Subscript[sys, 2]} = {StateSpaceModel[{{{Subscript[a, 1, 1], Subscript[a, 1, 2]}, {Subscript[a, 2, 1], Subscript[a, 2, 2]}}, {{Subscript[b, 1, 1], Subscript[b, 1, 2]}, {Subscript[b, 2, 1], Subscript[b, 2, 2]}}, {{Subscript[c, 1, 1], Subscript[c, 1, 2]}, {Subscript[c, 2, 1], Subscript[c, 2, 2]}}, {{0, 0}, {0, 0}}}, SamplingPeriod -> None, SystemsModelLabels -> None], StateSpaceModel[{{{Subscript[A, 1, 1], Subscript[A, 1, 2]}, {Subscript[A, 2, 1], Subscript[A, 2, 2]}}, {{Subscript[B, 1, 1], Subscript[B, 1, 2]}, {Subscript[B, 2, 1], Subscript[B, 2, 2]}}, {{Subscript[C, 1, 1], Subscript[C, 1, 2]}, {Subscript[C, 2, 1], Subscript[C, 2, 2]}}, {{0, 0}, {0, 0}}}, SamplingPeriod -> None, SystemsModelLabels -> None]};
Wolfram Language code: SystemsModelParallelConnect[Subscript[sys, 1], Subscript[sys, 2]]

常用输入和求和块：

Wolfram Language code: Subscript[com, 1] = Subscript[com, 2] = StateSpaceModel[{{}, {}, {}, {{1}, {1}}}, SamplingPeriod -> None, SystemsModelLabels -> None];
Wolfram Language code: Subscript[sum, 1] = Subscript[sum, 2] = StateSpaceModel[{{}, {}, {}, {{1, 1}}}, SamplingPeriod -> None, SystemsModelLabels -> None];

使用 SystemsConnectionsModel 指定连接：

Wolfram Language code: SystemsConnectionsModel[{Subscript[com, 1], Subscript[com, 2], Subscript[sys, 1], Subscript[sys, 2], Subscript[sum, 1], Subscript[sum, 2]}, {{1, 1} -> {3, 1}, {1, 2} -> {4, 1}, {2, 1} -> {3, 2}, {2, 2} -> {4, 2}, {3, 1} -> {5, 1}, {3, 2} -> {6, 1}, {4, 1} -> {5, 2}, {4, 2} -> {6, 2}}, {{1, 1}, {2, 1}}, {{5, 1}, {6, 1}}]

合并连接：

Wolfram Language code: SystemsModelMerge[%]

并行连接保持子系统状态不变：

Wolfram Language code: {Subscript[ssm, 1], Subscript[ssm, 2]} = {StateSpaceModel[{{{Subscript[a, 1, 1], Subscript[a, 1, 2]}, {Subscript[a, 2, 1], Subscript[a, 2, 2]}}, {{Subscript[b, 1, 1], Subscript[b, 1, 2]}, {Subscript[b, 2, 1], Subscript[b, 2, 2]}}, {{Subscript[c, 1, 1], Subscript[c, 1, 2]}, {Subscript[c, 2, 1], Subscript[c, 2, 2]}}, {{0, 0}, {0, 0}}}, SamplingPeriod -> None, SystemsModelLabels -> {{Subscript[u, 1], Subscript[u, 2]}, {Subscript[y, 11], Subscript[y, 12]}, {Subscript[x, 11], Subscript[x, 12]}}], StateSpaceModel[{{{Subscript[A, 1, 1], Subscript[A, 1, 2]}, {Subscript[A, 2, 1], Subscript[A, 2, 2]}}, {{Subscript[B, 1, 1], Subscript[B, 1, 2]}, {Subscript[B, 2, 1], Subscript[B, 2, 2]}}, {{Subscript[C, 1, 1], Subscript[C, 1, 2]}, {Subscript[C, 2, 1], Subscript[C, 2, 2]}}, {{0, 0}, {0, 0}}}, SamplingPeriod -> None, SystemsModelLabels -> {{Subscript[u, 1], Subscript[u, 2]}, {Subscript[y, 21], Subscript[y, 22]}, {Subscript[x, 21], Subscript[x, 22]}}]};
Wolfram Language code: SystemsModelParallelConnect[Subscript[ssm, 1], Subscript[ssm, 2]]

所得系统具有至少与每个子系统一样多的输入：

Wolfram Language code: sys1 = SystemsModelParallelConnect[Subscript[ssm, 1], Subscript[ssm, 2], {{1, 1}}, {{1, 1}, {2, 2}}]
Wolfram Language code: First[SystemsModelDimensions[sys1]] ≥ Max[First[SystemsModelDimensions[#]]& /@ {Subscript[ssm, 1], Subscript[ssm, 2]}]

对最小数目的输出保持相似的结果：

Wolfram Language code: sys2 = SystemsModelParallelConnect[Subscript[ssm, 1], Subscript[ssm, 2], {{1, 2}, {2, 1}}, {{2, 2}}];Last[SystemsModelDimensions[sys2]] ≥ Max[Last[SystemsModelDimensions[#]]& /@ {Subscript[ssm, 1], Subscript[ssm, 2]}]
Wolfram Research (2010)，SystemsModelParallelConnect，Wolfram 语言函数，https://reference.wolfram.com/language/ref/SystemsModelParallelConnect.html （更新于 2014 年）.

文本

Wolfram Research (2010)，SystemsModelParallelConnect，Wolfram 语言函数，https://reference.wolfram.com/language/ref/SystemsModelParallelConnect.html （更新于 2014 年）.

CMS

Wolfram 语言. 2010. "SystemsModelParallelConnect." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2014. https://reference.wolfram.com/language/ref/SystemsModelParallelConnect.html.

APA

Wolfram 语言. (2010). SystemsModelParallelConnect. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/SystemsModelParallelConnect.html 年

BibTeX

@misc{reference.wolfram_2026_systemsmodelparallelconnect, author="Wolfram Research", title="{SystemsModelParallelConnect}", year="2014", howpublished="\url{https://reference.wolfram.com/language/ref/SystemsModelParallelConnect.html}", note=[Accessed: 15-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_systemsmodelparallelconnect, organization={Wolfram Research}, title={SystemsModelParallelConnect}, year={2014}, url={https://reference.wolfram.com/language/ref/SystemsModelParallelConnect.html}, note=[Accessed: 15-November-2026]}