TimeSeriesForecast[tproc,data,k]
時系列過程 tproc に従って,data の k ステップ先の予測を与える.
TimeSeriesForecast[tsmod,k]
TimeSeriesModel tsmod についての k ステップ先の予測を与える.
TimeSeriesForecast
TimeSeriesForecast[tproc,data,k]
時系列過程 tproc に従って,data の k ステップ先の予測を与える.
TimeSeriesForecast[tsmod,k]
TimeSeriesModel tsmod についての k ステップ先の予測を与える.
詳細とオプション
- TimeSeriesForecast[tproc,{x0,…,xm},k]はExpectation[x[m+k]x[0]x0∧…∧x[m]xm]を与える.ただし,xtproc,つまり data で与えられた過程の期待値である.
- TimeSeriesForecastでは,tproc は,ARProcess,ARMAProcess,SARIMAProcess等の時系列過程である.
- data は,数値のリスト{x1,x2,…},時間と価値のペアのリスト{{t1,x1},{t2,x2},…}あるいはTemporalDataである.
- 次の予測指定を与えることができる.
-
k k
ステップ先{kmax} 1, …, kmaxステップ先 {kmin,kmax} kmin, …, kmaxステップ先 {{k1,k2,…}} 明示的な{k1,k2,…}ステップ先を使う - TimeSeriesForecastは,k が整数の場合は予測された値を,その他の場合はTemporalDataを返す.
- k のデフォルト値は1である.
- TimeSeriesForecastは次の設定のMethodオプションをサポートする.
-
Automatic メソッドを自動的に決定する "AR" 高次数の自己回帰過程で近似する "Covariance" 厳密な共分散関数に基づく "Kalman" Kalmanフィルタを使う - 予測の平均二乗誤差は複合ノイズ誤差であり,TemporalData出力中のMetaInformationとして与えられる.forecast=TimeSeriesForecast[tproc,data,k]のとき,平均二乗誤差には forecast["MeanSquaredErrors"]でアクセスできる.
例題
すべて開く すべて閉じる例 (3)
ARProcessについて3ステップ先を予測する:
data = {.1, .3, -.2, 0, -.2, .2};TimeSeriesForecast[ARProcess[{-.2, .4, .6}, .1], data, 3]ARMAProcessについて:
TimeSeriesForecast[ARMAProcess[{.2, -.1}, {-.2, .3}, .1], data, 3]TimeSeriesModelから7番目の値を予測する:
data = RandomFunction[ARMAProcess[{.2, -.1}, {-.2, .3}, .1], {10 ^ 3}];
tsmod = TimeSeriesModelFit[data, "ARMA"];forecast = TimeSeriesForecast[tsmod, 7]TimeSeriesForecast[tsmod, {{7}}]["MeanSquaredErrors"]["Path"]proc = ARMAProcess[{{{.8, .2}, {.3, .1}}}, {{{.2, 1}, {.5, -.3}}}, {{1, .2}, {.2, .5}}];
SeedRandom[3];
data = RandomFunction[proc, {0, 15}];forecast = TimeSeriesForecast[proc, data, {10}]Row@Table[ListLinePlot[#["PathComponent", j]& /@ {data, forecast}, PlotLabel -> Subscript[x, j], PlotLegends -> {"data", "forecast"}], {j, 1, 2}]スコープ (7)
ステップ (4)
data = {.2, .4, -.1};
proc = ARProcess[1, {.4}, 1];TimeSeriesForecast[proc, data]TimeSeriesForecast[proc, data, 3]data = {.2, .4, -.1};
proc = ARProcess[1, {.4}, 1];TimeSeriesForecast[proc, data, {5}]%["Path"]data = {.2, .4, -.1};
proc = ARProcess[1, {.4}, 1];TimeSeriesForecast[proc, data, {3, 5}]%["Path"]data = {.2, .4, -.1};
proc = ARProcess[1, {.4}, 1];TimeSeriesForecast[proc, data, {{2, 3, 5}}]%["Path"]平均二乗誤差 (3)
data = {.2, .4, -.1};
proc = ARProcess[1, {.4}, 1];TimeSeriesForecast[proc, data]平均二乗誤差を抽出するために,予測をTemporalDataとして返す:
forecast = TimeSeriesForecast[proc, data, {{1}}]err = forecast["MeanSquaredErrors"]{forecast["Path"], err["Path"]}proc = ARMAProcess[1.2, {.3, .2}, {.8}, .1];
data = RandomFunction[proc, {1, 20}];forecast = TimeSeriesForecast[proc, data, {0, 10}];err = Sqrt[forecast["MeanSquaredErrors"]];uband = TimeSeriesThread[{1, 1}.#&, {forecast, err}];lband = TimeSeriesThread[{1, -1}.#&, {forecast, err}];ListLinePlot[{data, forecast, uband, lband}, PlotStyle -> {Automatic, Automatic, Gray, Gray}, Filling -> {3 -> {4}}]data = RandomFunction[proc = MAProcess[.4, {.3, .2}, .1], {1, 20}];forecast = TimeSeriesForecast[ARMAProcess[{-.2, .4, .6}, {.2, .1}, .1], data, {0, 10}];err = Sqrt[forecast["MeanSquaredErrors"]];
quantile = Quantile[NormalDistribution[], 1 - 1 / 2 (1 - .95)];uband = TimeSeriesThread[{1, quantile}.#&, {forecast, err}];lband = TimeSeriesThread[{1, -quantile}.#&, {forecast, err}];ListLinePlot[{data, forecast, uband, lband}, PlotStyle -> {Automatic, Automatic, Gray, Gray}, Filling -> {3 -> {4}}]オプション (4)
Method (4)
proc = MAProcess[{.3, .4}, 1];
data = {1, 1.4, 2};
forecast = TimeSeriesForecast[proc, data, {6}, Method -> "Covariance"]forecast["Path"]proc = MAProcess[{.3, .4}, 1];
data = {1, 1.4, 2};
forecast = TimeSeriesForecast[proc, data, {6}, Method -> "AR"]forecast["Path"]proc = MAProcess[{.3, .4}, 1];
data = {1, 1.4, 2};
forecast = TimeSeriesForecast[proc, data, {6}, Method -> "Kalman"]forecast["Path"]MAProcessについて,厳密法と近似法を比較する:
ma = MAProcess[{a}, σ^2];TimeSeriesForecast[ma, Array[x, 3], Method -> "Covariance"]TimeSeriesForecast[ma, Array[x, 3], Method -> "AR"]ar = ARProcess[{a}, σ ^ 2];TimeSeriesForecast[ar, Array[x, 3], Method -> "Covariance"]TimeSeriesForecast[ar, Array[x, 3], Method -> "AR"]アプリケーション (3)
2012年5月から2012年9月までのユーロとドルの毎日の為替レート:
data = TemporalData[Automatic, {{{1.31, 1.31, 1.31, 1.3, 1.3, 1.3, 1.29, 1.29, 1.29, 1.27, 1.28, 1.28,
1.27, 1.26, 1.26, 1.26, 1.25, 1.24, 1.24, 1.23, 1.24, 1.24, 1.25, 1.26, 1.25, 1.26, 1.25, 1.25,
1.26, 1.26, 1.26, 1.26, 1.27, 1.27, 1.25, 1.25 ... Data`DateSpecification[{2012, 5, 2}, {2012, 9, 28}, "BusinessDay", "DayRange"]}, 1,
{"Discrete", 1}, {"Discrete", 1}, 1,
{MetaInformation -> {"Source" -> HoldForm[FinancialData]["EUR/USD",
{{2012, 5, 1}, {2012, 9, 30}}]}}}, True, 9.];data["Source"]DateListPlot[data, Joined -> True, Filling -> Bottom]eproc = EstimatedProcess[data, ARProcess[3]]forecast = TimeSeriesForecast[eproc, data, {20}]DateListPlot[{data, forecast}, Joined -> True, Filling -> Bottom]2012年9月9日における現在地近くの1時間ごとの気温変化を考える:
data = WeatherData[First@FindGeoLocation[], "Temperature", {2012, 9, 9}]FreeQ[data, Missing]MissingDataMethodを使い補間値で欠落データを補って時系列を再定義する:
data1 = TimeSeries[data, MissingDataMethod -> {"Interpolation", InterpolationOrder -> 1}]RegularlySampledQ[data1]temp = TimeSeriesResample[data1, "Hour"]RegularlySampledQ[temp]ARProcessを推定する:
proc = EstimatedProcess[temp, ARProcess[3]]forecast = TimeSeriesForecast[proc, temp, {12}]DateListPlot[{temp, forecast}, Filling -> Axis, Joined -> True]raw = WolframAlpha["usa retail sales", {{"History:RetailSales:EconomicData", 1}, "TimeSeriesData"}];raw[[1]]選択したものからTimeSeriesを作る:
data = QuantityMagnitude[TimeSeries[raw[[-12 * 15 ;; , 2]], {Automatic, raw[[-1, 1]], "Month"}]]売上げが最大である12月に格子線を引いて売上げをプロットする:
grids = Table[{1992, 12 i}, {i, data["PathLength"]}];
DateListPlot[data, GridLines -> {grids, None}, AspectRatio -> 1 / 3]model = TimeSeriesModelFit[data, {"SARIMA", 12}]proc = model["BestFit"]特性と関係 (3)
厳密あるいは近似のメソッドを使ったARProcessによる予測は同じ結果を与える:
TimeSeriesForecast[ARProcess[{a}, σ^2], {x, y, z}, {5}, Method -> "Covariance"]["Path"]TimeSeriesForecast[ARProcess[{a}, σ^2], {x, y, z}, {5}, Method -> "AR"]["Path"]% - %%proc = MAProcess[{3., 1.}, 1];TimeSeriesInvertibility[proc]invproc = ToInvertibleTimeSeries[proc]data = {.2, -.3, .4};forecast = TimeSeriesForecast[proc, data, {3}]invforecast = TimeSeriesForecast[invproc, data, {3}]forecast - invforecast%["Path"]TimeSeriesModelを使って予測する:
data = TemporalData[TimeSeries,
{{{Quantity[46.76, "DegreesFahrenheit"], Quantity[50., "DegreesFahrenheit"],
Quantity[68.31, "DegreesFahrenheit"], Quantity[72.84, "DegreesFahrenheit"],
Quantity[71.74, "DegreesFahrenheit"], Quantity[76.75, "Deg ... DegreesFahrenheit"]}}, {TemporalData`DateSpecification[{2007, 3, 1, 0, 0, 0.},
{2017, 3, 1, 0, 0, 0}, {1, "Month"}]}, 1, {"Continuous", 1}, {"Discrete", 1}, 1,
{ResamplingMethod -> {"Interpolation", InterpolationOrder -> 1}}}, True, 314.1];tsm = TimeSeriesModelFit[data]forecast = TimeSeriesForecast[tsm, {20}]res = TimeSeriesForecast[tsm["Process"], tsm["TemporalData"], {20}]forecast["Path"] == res["Path"]テキスト
Wolfram Research (2012), TimeSeriesForecast, Wolfram言語関数, https://reference.wolfram.com/language/ref/TimeSeriesForecast.html (2014年に更新).
CMS
Wolfram Language. 2012. "TimeSeriesForecast." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2014. https://reference.wolfram.com/language/ref/TimeSeriesForecast.html.
APA
Wolfram Language. (2012). TimeSeriesForecast. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/TimeSeriesForecast.html
BibTeX
@misc{reference.wolfram_2026_timeseriesforecast, author="Wolfram Research", title="{TimeSeriesForecast}", year="2014", howpublished="\url{https://reference.wolfram.com/language/ref/TimeSeriesForecast.html}", note=[Accessed: 20-November-2026]}
BibLaTeX
@online{reference.wolfram_2026_timeseriesforecast, organization={Wolfram Research}, title={TimeSeriesForecast}, year={2014}, url={https://reference.wolfram.com/language/ref/TimeSeriesForecast.html}, note=[Accessed: 20-November-2026]}