WOLFRAM

Wolfram 语言与系统参考资料中心

TimeSeriesForecast[tproc,data,k]

根据时间序列过程 tproc ，给出超出 data 的 k 步前向预测.

TimeSeriesForecast[tsmod,k]

给出 TimeSeriesModel tsmod 的 k 步前向预测.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
步骤  
均方差  
选项  
Method  
应用  
属性和关系  
可能存在的问题  
参见
相关指南
历史
按以下格式引用：

TimeSeriesForecast

TimeSeriesForecast[tproc,data,k]

根据时间序列过程 tproc ，给出超出 data 的 k 步前向预测.

TimeSeriesForecast[tsmod,k]

给出 TimeSeriesModel tsmod 的 k 步前向预测.

更多信息和选项

  • TimeSeriesForecast[tproc,{x0,…,xm},k] 将给出 Expectation[x[m+k]x[0]x0∧…∧x[m]xm]，其中 xtproc，给定 data 的过程的期望值.
  • TimeSeriesForecast 允许 tproc 为一个时间序列过程，就如 ARProcess，ARMAProcess，SARIMAProcess 等.
  • data 可以是一个数值列表 {x1,x2,…}，一个时间-数值对的列表 {{t1,x1},{t2,x2},…}，或者 TemporalData.
  • 可以设定以下预测规范：
  • k前面第 k 步
    {kmax}前面 1, …, kmax 步
    {kmin,kmax}前面 kmin, …, kmax 步处
    {{k1,k2,…}}使用前面的显式 {k1,k2,…} 步
  • 如果 k 为整数，TimeSeriesForecast 将返回预测值，否则将返回 TemporalData.
  • k 的默认值为1.
  • TimeSeriesForecast 支持 Method 选项，另有下列设置：
  • Automatic自动确定方法
    "AR"使用高阶 AR 过程近似
    "Covariance"基于精确方差函数
    "Kalman"使用卡曼滤波器
  • 预测的均方差是合成操作误差，并且在 TemporalData 输出中以 MetaInformation 给出. 对于 forecast=TimeSeriesForecast[tproc,data,k]，均方差可以使用 forecast["MeanSquaredErrors"] 预测.

范例

打开所有单元 关闭所有单元

基本范例  (3)

对一个 ARProcess 预测前面三步：

Wolfram Language code: data = {.1, .3, -.2, 0, -.2, .2};
Wolfram Language code: TimeSeriesForecast[ARProcess[{-.2, .4, .6}, .1], data, 3]

一个 ARMAProcess：

Wolfram Language code: TimeSeriesForecast[ARMAProcess[{.2, -.1}, {-.2, .3}, .1], data, 3]

预测 TimeSeriesModel 的第七个值：

Wolfram Language code: data = RandomFunction[ARMAProcess[{.2, -.1}, {-.2, .3}, .1], {10 ^ 3}]; tsmod = TimeSeriesModelFit[data, "ARMA"];
Wolfram Language code: forecast = TimeSeriesForecast[tsmod, 7]

预测的均方差：

Wolfram Language code: TimeSeriesForecast[tsmod, {{7}}]["MeanSquaredErrors"]["Path"]

预测一个向量值的时间序列过程：

Wolfram Language code: proc = ARMAProcess[{{{.8, .2}, {.3, .1}}}, {{{.2, 1}, {.5, -.3}}}, {{1, .2}, {.2, .5}}]; SeedRandom[3]; data = RandomFunction[proc, {0, 15}];

求前面 10 步的预测：

Wolfram Language code: forecast = TimeSeriesForecast[proc, data, {10}]

对数据和每个组件的预测绘图：

Wolfram Language code: Row@Table[ListLinePlot[#["PathComponent", j]& /@ {data, forecast}, PlotLabel -> Subscript[x, j], PlotLegends -> {"data", "forecast"}], {j, 1, 2}]

范围  (7)

步骤  (4)

预测前面一步：

Wolfram Language code: data = {.2, .4, -.1}; proc = ARProcess[1, {.4}, 1];
Wolfram Language code: TimeSeriesForecast[proc, data]

预测前面的第三步：

Wolfram Language code: TimeSeriesForecast[proc, data, 3]

找到前面直到第五步的预测：

Wolfram Language code: data = {.2, .4, -.1}; proc = ARProcess[1, {.4}, 1];
Wolfram Language code: TimeSeriesForecast[proc, data, {5}]

显示路径：

Wolfram Language code: %["Path"]

找到前面第三到第五步范围内的预测：

Wolfram Language code: data = {.2, .4, -.1}; proc = ARProcess[1, {.4}, 1];
Wolfram Language code: TimeSeriesForecast[proc, data, {3, 5}]

显示路径：

Wolfram Language code: %["Path"]

预测一个步的列表：

Wolfram Language code: data = {.2, .4, -.1}; proc = ARProcess[1, {.4}, 1];
Wolfram Language code: TimeSeriesForecast[proc, data, {{2, 3, 5}}]

路径：

Wolfram Language code: %["Path"]

均方差  (3)

预测前面一步：

Wolfram Language code: data = {.2, .4, -.1}; proc = ARProcess[1, {.4}, 1];
Wolfram Language code: TimeSeriesForecast[proc, data]

以 TemporalData 的形式返回预测，提取均方差：

Wolfram Language code: forecast = TimeSeriesForecast[proc, data, {{1}}]
Wolfram Language code: err = forecast["MeanSquaredErrors"]
Wolfram Language code: {forecast["Path"], err["Path"]}

求有均方差的预测:

Wolfram Language code: proc = ARMAProcess[1.2, {.3, .2}, {.8}, .1]; data = RandomFunction[proc, {1, 20}];

计算预测：

Wolfram Language code: forecast = TimeSeriesForecast[proc, data, {0, 10}];

标准偏差：

Wolfram Language code: err = Sqrt[forecast["MeanSquaredErrors"]];

定义误差带：

Wolfram Language code: uband = TimeSeriesThread[{1, 1}.#&, {forecast, err}];
Wolfram Language code: lband = TimeSeriesThread[{1, -1}.#&, {forecast, err}];

对数据及有平均误差带的预测进行绘图：

Wolfram Language code: ListLinePlot[{data, forecast, uband, lband}, PlotStyle -> {Automatic, Automatic, Gray, Gray}, Filling -> {3 -> {4}}]

求有 95% 置信区间的预测：

Wolfram Language code: data = RandomFunction[proc = MAProcess[.4, {.3, .2}, .1], {1, 20}];

求前面 10 步的预测：

Wolfram Language code: forecast = TimeSeriesForecast[ARMAProcess[{-.2, .4, .6}, {.2, .1}, .1], data, {0, 10}];

找出均方差和置信区间：

Wolfram Language code: err = Sqrt[forecast["MeanSquaredErrors"]]; quantile = Quantile[NormalDistribution[], 1 - 1 / 2 (1 - .95)];
Wolfram Language code: uband = TimeSeriesThread[{1, quantile}.#&, {forecast, err}];
Wolfram Language code: lband = TimeSeriesThread[{1, -quantile}.#&, {forecast, err}];

绘制数据，预测以及预测限制范围：

Wolfram Language code: ListLinePlot[{data, forecast, uband, lband}, PlotStyle -> {Automatic, Automatic, Gray, Gray}, Filling -> {3 -> {4}}]

选项  (4)

Method  (4)

使用基于协方差的方法求预测：

Wolfram Language code: proc = MAProcess[{.3, .4}, 1]; data = {1, 1.4, 2}; forecast = TimeSeriesForecast[proc, data, {6}, Method -> "Covariance"]
Wolfram Language code: forecast["Path"]

使用自回归方法求预测：

Wolfram Language code: proc = MAProcess[{.3, .4}, 1]; data = {1, 1.4, 2}; forecast = TimeSeriesForecast[proc, data, {6}, Method -> "AR"]
Wolfram Language code: forecast["Path"]

使用卡曼滤波方法，求预测：

Wolfram Language code: proc = MAProcess[{.3, .4}, 1]; data = {1, 1.4, 2}; forecast = TimeSeriesForecast[proc, data, {6}, Method -> "Kalman"]
Wolfram Language code: forecast["Path"]

比较对一个 MAProcess 的精确和近似方法：

Wolfram Language code: ma = MAProcess[{a}, σ^2];
Wolfram Language code: TimeSeriesForecast[ma, Array[x, 3], Method -> "Covariance"]
Wolfram Language code: TimeSeriesForecast[ma, Array[x, 3], Method -> "AR"]

两种方法对自回归过程是一致的：

Wolfram Language code: ar = ARProcess[{a}, σ ^ 2];
Wolfram Language code: TimeSeriesForecast[ar, Array[x, 3], Method -> "Covariance"]
Wolfram Language code: TimeSeriesForecast[ar, Array[x, 3], Method -> "AR"]

应用  (3)

从 2012 年 5 月到 2012 年 9 月，欧元到美元的日汇率：

Wolfram Language code: data = TemporalData[Automatic, {{{1.31, 1.31, 1.31, 1.3, 1.3, 1.3, 1.29, 1.29, 1.29, 1.27, 1.28, 1.28, 1.27, 1.26, 1.26, 1.26, 1.25, 1.24, 1.24, 1.23, 1.24, 1.24, 1.25, 1.26, 1.25, 1.26, 1.25, 1.25, 1.26, 1.26, 1.26, 1.26, 1.27, 1.27, 1.25, 1.25 ... Data`DateSpecification[{2012, 5, 2}, {2012, 9, 28}, "BusinessDay", "DayRange"]}, 1, {"Discrete", 1}, {"Discrete", 1}, 1, {MetaInformation -> {"Source" -> HoldForm[FinancialData]["EUR/USD", {{2012, 5, 1}, {2012, 9, 30}}]}}}, True, 9.];
Wolfram Language code: data["Source"]
Wolfram Language code: DateListPlot[data, Joined -> True, Filling -> Bottom]

对汇率拟合 AR 过程：

Wolfram Language code: eproc = EstimatedProcess[data, ARProcess[3]]

预测未来 20 个工作日：

Wolfram Language code: forecast = TimeSeriesForecast[eproc, data, {20}]

用原始数据绘图:

Wolfram Language code: DateListPlot[{data, forecast}, Joined -> True, Filling -> Bottom]

考虑您的地点附近 2012 年 9 月 9 日每小时温度数据：

Wolfram Language code: data = WeatherData[First@FindGeoLocation[], "Temperature", {2012, 9, 9}]

数据中含有缺失数值：

Wolfram Language code: FreeQ[data, Missing]

用 MissingDataMethod 重新定义时间序列，以便利用插值补充缺失数据：

Wolfram Language code: data1 = TimeSeries[data, MissingDataMethod -> {"Interpolation", InterpolationOrder -> 1}]

查看时间戳是否是均匀间隔的：

Wolfram Language code: RegularlySampledQ[data1]

按小时重新抽样：

Wolfram Language code: temp = TimeSeriesResample[data1, "Hour"]
Wolfram Language code: RegularlySampledQ[temp]

估计 ARProcess:

Wolfram Language code: proc = EstimatedProcess[temp, ARProcess[3]]

计算未来 12 小时的预测：

Wolfram Language code: forecast = TimeSeriesForecast[proc, temp, {12}]

用原始数据绘图：

Wolfram Language code: DateListPlot[{temp, forecast}, Filling -> Axis, Joined -> True]

美国每月零售销售额：

Wolfram Language code: raw = WolframAlpha["usa retail sales", {{"History:RetailSales:EconomicData", 1}, "TimeSeriesData"}];
Wolfram Language code: raw[[1]]

用选中的数据生成 TimeSeries：

Wolfram Language code: data = QuantityMagnitude[TimeSeries[raw[[-12 * 15 ;; , 2]], {Automatic, raw[[-1, 1]], "Month"}]]

绘制销售额，并在十二月高峰值处画出网格线：

Wolfram Language code: grids = Table[{1992, 12 i}, {i, data["PathLength"]}]; DateListPlot[data, GridLines -> {grids, None}, AspectRatio -> 1 / 3]

拟合一个季节性模型：

Wolfram Language code: model = TimeSeriesModelFit[data, {"SARIMA", 12}]

过程的参数：

Wolfram Language code: proc = model["BestFit"]

属性和关系  (3)

使用精确或者近似方法在 ARProcess 下预测给出相同结果：

Wolfram Language code: TimeSeriesForecast[ARProcess[{a}, σ^2], {x, y, z}, {5}, Method -> "Covariance"]["Path"]
Wolfram Language code: TimeSeriesForecast[ARProcess[{a}, σ^2], {x, y, z}, {5}, Method -> "AR"]["Path"]
Wolfram Language code: % - %%

对于时间序列过程和它的可逆表示法，预测是相同的：

Wolfram Language code: proc = MAProcess[{3., 1.}, 1];

过程不是可逆的：

Wolfram Language code: TimeSeriesInvertibility[proc]

求可逆表示法：

Wolfram Language code: invproc = ToInvertibleTimeSeries[proc]

比较预测：

Wolfram Language code: data = {.2, -.3, .4};
Wolfram Language code: forecast = TimeSeriesForecast[proc, data, {3}]
Wolfram Language code: invforecast = TimeSeriesForecast[invproc, data, {3}]
Wolfram Language code: forecast - invforecast
Wolfram Language code: %["Path"]

用 TimeSeriesModel 来预测：

Wolfram Language code: data = TemporalData[TimeSeries, {{{Quantity[46.76, "DegreesFahrenheit"], Quantity[50., "DegreesFahrenheit"], Quantity[68.31, "DegreesFahrenheit"], Quantity[72.84, "DegreesFahrenheit"], Quantity[71.74, "DegreesFahrenheit"], Quantity[76.75, "Deg ... DegreesFahrenheit"]}}, {TemporalData`DateSpecification[{2007, 3, 1, 0, 0, 0.}, {2017, 3, 1, 0, 0, 0}, {1, "Month"}]}, 1, {"Continuous", 1}, {"Discrete", 1}, 1, {ResamplingMethod -> {"Interpolation", InterpolationOrder -> 1}}}, True, 314.1];
Wolfram Language code: tsm = TimeSeriesModelFit[data]

计算 20 步的预测：

Wolfram Language code: forecast = TimeSeriesForecast[tsm, {20}]

明确使用过程和数据：

Wolfram Language code: res = TimeSeriesForecast[tsm["Process"], tsm["TemporalData"], {20}]

比较路径：

Wolfram Language code: forecast["Path"] == res["Path"]

可能存在的问题  (2)

"Kalman" 方法要求过程参数是数值的：

Wolfram Language code: TimeSeriesForecast[ARProcess[{a}, σ^2], {x, y, z}, 6, Method -> "Kalman"]

如果可逆表示法不存在，预测可能是不可靠的：

Wolfram Language code: ft = TimeSeriesForecast[MAProcess[{1}, 1], {1, 2, 3}, {3}, Method -> "AR"]
Wolfram Language code: ft["Path"]
Wolfram Research (2012)，TimeSeriesForecast，Wolfram 语言函数，https://reference.wolfram.com/language/ref/TimeSeriesForecast.html （更新于 2014 年）.

文本

Wolfram Research (2012)，TimeSeriesForecast，Wolfram 语言函数，https://reference.wolfram.com/language/ref/TimeSeriesForecast.html （更新于 2014 年）.

CMS

Wolfram 语言. 2012. "TimeSeriesForecast." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2014. https://reference.wolfram.com/language/ref/TimeSeriesForecast.html.

APA

Wolfram 语言. (2012). TimeSeriesForecast. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/TimeSeriesForecast.html 年

BibTeX

@misc{reference.wolfram_2026_timeseriesforecast, author="Wolfram Research", title="{TimeSeriesForecast}", year="2014", howpublished="\url{https://reference.wolfram.com/language/ref/TimeSeriesForecast.html}", note=[Accessed: 01-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_timeseriesforecast, organization={Wolfram Research}, title={TimeSeriesForecast}, year={2014}, url={https://reference.wolfram.com/language/ref/TimeSeriesForecast.html}, note=[Accessed: 01-November-2026]}