Wolfram 语言与系统参考资料中心

TimeSeriesModelFit

TimeSeriesModelFit[data]

从自动选择的模型系列中构建 data 的时间序列模型.

TimeSeriesModelFit[data,mspec]

从由 mspec 指定的模型系列中构建 data 的时间序列.

范例

打开所有单元关闭所有单元

基本范例 (1)

对一些数据拟合时间序列模型：

Wolfram Language code:

data = {5., 9., 8., 10., 6.1, 10.4, 9.1, 11.6, 7.5, 12.1, 10.4, 13.5, 9., 14.1, 11.9, 15.7, 10.8, 16.4, 13.7, 18.3, 12.9, 19., 15.8, 21.2, 
	15.3, 22.1, 18.3, 24.6};

Wolfram Language code: tsm = TimeSeriesModelFit[data]

拟合的时间序列模型：

Wolfram Language code: Normal[tsm]

在时间35获取点预测和95%预测极限：

Wolfram Language code: tsm[35]

Wolfram Language code: tsm["PredictionLimits"][35]

用10步向前预测可视化数据：

Wolfram Language code: ListLinePlot[{tsm["TemporalData"], TimeSeriesForecast[tsm, {10}]}]

范围 (22)

基本用途 (5)

自动拟合一个模型为时间序列：

Wolfram Language code: ts = Accumulate[RandomVariate[NormalDistribution[], 10 ^ 4]];

Wolfram Language code: ListLinePlot[ts]

Wolfram Language code: tsm = TimeSeriesModelFit[ts]

为数据选择的模型：

Wolfram Language code: Normal[tsm]

使用某些月温度数据创建预测：

Wolfram Language code:

tsm = TimeSeriesModelFit[TemporalData[TimeSeries, {{{-1.16, -0.98, 2.7, 12.08, 16.83, 20.78, 24.32, 24.92, 19.28, 13.34, 
    11.19, 3.3, 1.91, 2.02, 2.36, 10.27, 13.16, 22.26, 26.67, 24.55, 22.07, 11.81, 5.49, 0.88, 
    -3.71, -2.51, 4.42, 9.55, 13.82, 19.35, 23.29, 24.0 ... ation[{2001, 1, 1, 0, 0, 0.}, {2012, 1, 1, 0, 0, 0.}, {1, "Month"}]}, 
  1, {"Discrete", 1}, {"Discrete", 1}, 1, 
  {MetaInformation -> {"Caller" :> TemporalData[WeatherData["Chicago", "Temperature", dates][[All,
        2]], dates]}}}, True, 10.]]

月温度数据和24个月预测：

Wolfram Language code: DateListPlot[{tsm["TemporalData"], TimeSeriesForecast[tsm, {24}]}, Joined -> True]

预测2014年6月1号的平均温度：

Wolfram Language code: tsm["June 1, 2014"]

预测的95%置信区间：

Wolfram Language code: tsm["PredictionLimits"]["June 1, 2014"]

拟合一个特殊模型为时间序列：

Wolfram Language code:

ts = TimeSeries[TimeEventSeries`TimestampData[Association["UniformlySpacedQ" -> True, "Count" -> 3362, 
   "Endpoints" -> TabularColumn[Association["Data" -> {{0, 3361}, {}, None}, 
      "ElementType" -> "Integer64"]], "MinimumTimeIncrement" -> 1, "Cal ... 28697962798989, 
      0.014550264550264647, -0.009995654063450599, 0.005267778753292207, -0.0021834061135369565, 
      0.0070021881838073785, 0.009995654063450488, 0.001290877796902068}, {}, None}, 
   "ElementType" -> "Real64"]], Association[]];

Wolfram Language code: ListLinePlot[ts, PlotRange -> All]

用一个 "GARCH"(1,1) 模型拟合数据：

Wolfram Language code: tsm = TimeSeriesModelFit[ts, {"GARCH", {1, 1}}]

模型和参数估计：

Wolfram Language code: tsm["ParameterTable"]

用一个时间序列模型拟合一个100个工作日的时间序列：

Wolfram Language code:

data = TimeSeries[RandomFunction[ARIMAProcess[{.1}, 2, {.1, .2}, 2], {1, 10 ^ 2}]["Values"], {Automatic, Today, "BusinessDay"}]

Wolfram Language code: p1 = DateListPlot[data]

Wolfram Language code: tsm = TimeSeriesModelFit[data, {"ARIMA", {1, 2, 2}}]

模拟下一个30个工作日50次：

Wolfram Language code: Show[p1, DateListPlot[RandomFunction[tsm, {1, 30}, 50], Joined -> True], PlotRange -> All]

使用原始数据用 TimeSeriesModel 模拟未来观察：

Wolfram Language code: data = TemporalData[RandomFunction[ARProcess[{.8}, 1], {100}]["Values"], {"January 24 1982", Automatic, "Month"}]

拟合一个模型：

Wolfram Language code: model = TimeSeriesModelFit[data]

使用最佳拟合过程模拟10个未来观察：

Wolfram Language code: process = model["Process"]

时间戳或初始值的信息不会传给 RandomFunction：

Wolfram Language code: SeedRandom["TSM"];BlockRandom[sim1 = RandomFunction[process, {10}, 4]]

使用 TimeSeriesModel 的模拟会使用由原始数据给出的信息：

Wolfram Language code: SeedRandom["TSM"];BlockRandom[sim2 = RandomFunction[model, {10}, 4]]

Wolfram Language code: {ListLinePlot[sim1], DateListPlot[sim2]}

模型规范 (6)

为时间序列自动选择模型：

Wolfram Language code: ts = RandomFunction[ARMAProcess[{.1, -.3}, {.1}, 1], {0, 10 ^ 4}];

Wolfram Language code: tsm = TimeSeriesModelFit[ts]

等价于指定 Automatic：

Wolfram Language code: TimeSeriesModelFit[ts, Automatic]

找到在特殊系列中的模型：

Wolfram Language code:

SeedRandom[235];
ts = RandomFunction[ARProcess[{.1, .2}, 1], {0, 10 ^ 4}];

搜索模型的自回归系列：

Wolfram Language code: tsm = TimeSeriesModelFit[ts, "AR"]

从一个明确的候选集中选择最佳模型：

Wolfram Language code:

SeedRandom[203371];
ts = RandomFunction[ARMAProcess[{.1}, {.2, -.3}, 1], {0, 10 ^ 4}];

搜索 ARMA 系列，其中，阶数和为0到2：

Wolfram Language code: TimeSeriesModelFit[ts, {"ARMA", {0 ;; 2, 0 ;; 2}}]

Wolfram Language code: %["CandidateSelectionTable"]

用固定阶数拟合模型：

Wolfram Language code: ts = RandomFunction[ARIMAProcess[{.2, -.1}, 1, {.5, -.3, .4}, 2], {0, 10 ^ 4}];

Wolfram Language code: ListLinePlot[ts]

用 "ARIMA"(2,1,3) 模型拟合数据：

Wolfram Language code: tsm1 = TimeSeriesModelFit[ts, {"ARIMA", {2, 1, 3}}]

拟合积分阶数并搜索自回归和移动平均阶数：

Wolfram Language code: tsm2 = TimeSeriesModelFit[ts, {"ARIMA", {Automatic, 1, Automatic}}]

参数化模型的 ARIMA 系列：

Wolfram Language code:

ts = TemporalData[Automatic, {{{-0.6234770849029923, -0.43353873731436093, -1.4384562423305023, 
    -0.6121753077532655, -1.6377557914754912, -0.965769312027555, 0.11900665884869621, 
    1.7632213409033033, 2.595842448714646, 3.511220729322236, 3.4379 ... 13.320609605604798, -12.854481578284084, -10.497526742053997, -10.370034746782753, 
    -10.688808347192714, -9.898759741498635, -8.080916162954333, -7.919847928681525}}, 
  {{0, 1000, 1}}, 1, {"Continuous", 1}, {"Discrete", 1}, 1, {}}, False, 9.];

自动检测阶数、和：

Wolfram Language code: TimeSeriesModelFit[ts, "ARIMA"]

或者，对所有参数阶数使用 Automatic：

Wolfram Language code: p = d = q = Automatic;

Wolfram Language code: TimeSeriesModelFit[ts, {"ARIMA", {p, d, q}}]

相同的方法，固定积分阶数，其中，和为 Automatic：

Wolfram Language code: TimeSeriesModelFit[ts, {"ARIMA", {p, 1, q}}]

Wolfram Language code: TimeSeriesModelFit[ts, {"ARIMA", 1}]

相同的方法，固定和，其中设积分阶数为 Automatic：

Wolfram Language code: TimeSeriesModelFit[ts, {"ARIMA", {1, d, 2}}]

Wolfram Language code: TimeSeriesModelFit[ts, {"ARIMA", {1, 2}}]

参数化模型的 SARIMA 系列：

Wolfram Language code: ts = RandomFunction[SARIMAProcess[{.3}, 1, {.2}, {12, {.2}, 2, {}}, 1], {1, 10 ^ 4}];

自动检测、、、、、和：

Wolfram Language code: tsm = TimeSeriesModelFit[ts, "SARIMA"]

或者，对所有参数阶数使用 Automatic：

Wolfram Language code: p = d = q = sp = sd = sq = s = Automatic;

Wolfram Language code: TimeSeriesModelFit[ts, {"SARIMA", {{p, d, q}, {sp, sd, sq}, s}}]

同样，固定季节性参数，其他为 Automatic：

Wolfram Language code: TimeSeriesModelFit[ts, {"SARIMA", {{p, d, q}, {sp, sd, sq}, 12}}]

Wolfram Language code: TimeSeriesModelFit[ts, {"SARIMA", 12}]

同样，固定季节性参数，积分阶数和：

Wolfram Language code: TimeSeriesModelFit[ts, {"SARIMA", {{p, 1, q}, {sp, 2, sq}, 12}}]

Wolfram Language code: TimeSeriesModelFit[ts, {"SARIMA", {1, 2, 12}}]

模型属性 (11)

获取可用属性列表：

Wolfram Language code:

tsm = TimeSeriesModelFit[TemporalData[TimeSeries, {{{-0.7935061667730144, 4.3778286773763035, 2.922958541001586, 
    1.9853580784609617, 1.147308854130249, 1.698080426822207, 0.008331318340714766, 
    0.10200160157297689, 2.2513707375476235, 0.8328655174414309, -2.378076 ... 761350230830915, 2.4578396008405163, 
    -0.9273117800247228, 0.3871528084319487, 1.0557919551990362, 1.8934299378382737, 
    3.913518335425615, 1.3010389634021429}}, {{1, 10000, 1}}, 1, {"Continuous", 1}, 
  {"Discrete", 1}, 1, {}}, False, 10.]];

Wolfram Language code: tsm["Properties"]

提取最佳拟合过程：

Wolfram Language code:

tsm = TimeSeriesModelFit[TemporalData[TimeSeries, {{{-0.7935061667730144, 4.3778286773763035, 2.922958541001586, 
    1.9853580784609617, 1.147308854130249, 1.698080426822207, 0.008331318340714766, 
    0.10200160157297689, 2.2513707375476235, 0.8328655174414309, -2.378076 ... 761350230830915, 2.4578396008405163, 
    -0.9273117800247228, 0.3871528084319487, 1.0557919551990362, 1.8934299378382737, 
    3.913518335425615, 1.3010389634021429}}, {{1, 10000, 1}}, 1, {"Continuous", 1}, 
  {"Discrete", 1}, 1, {}}, False, 10.]];

Wolfram Language code: tsm["BestFit"]

使用 Normal 得到同等的结果：

Wolfram Language code: Normal[tsm]

显示选择模型的某些拟合标准：

Wolfram Language code:

tsm = TimeSeriesModelFit[TemporalData[TimeSeries, {{{-0.7935061667730144, 4.3778286773763035, 2.922958541001586, 
    1.9853580784609617, 1.147308854130249, 1.698080426822207, 0.008331318340714766, 
    0.10200160157297689, 2.2513707375476235, 0.8328655174414309, -2.378076 ... 761350230830915, 2.4578396008405163, 
    -0.9273117800247228, 0.3871528084319487, 1.0557919551990362, 1.8934299378382737, 
    3.913518335425615, 1.3010389634021429}}, {{1, 10000, 1}}, 1, {"Continuous", 1}, 
  {"Discrete", 1}, 1, {}}, False, 10.]];

Wolfram Language code: sc = {"AIC", "AICc", "BIC", "SBC"};

Wolfram Language code: TableForm[{#, tsm[#]}& /@ sc]

用于选择最佳模型的标准：

Wolfram Language code: tsm["SelectionCriterion"]

报告能拟合数据的前几个模型：

Wolfram Language code:

tsm = TimeSeriesModelFit[TemporalData[TimeSeries, {{{-0.7935061667730144, 4.3778286773763035, 2.922958541001586, 
    1.9853580784609617, 1.147308854130249, 1.698080426822207, 0.008331318340714766, 
    0.10200160157297689, 2.2513707375476235, 0.8328655174414309, -2.378076 ... 761350230830915, 2.4578396008405163, 
    -0.9273117800247228, 0.3871528084319487, 1.0557919551990362, 1.8934299378382737, 
    3.913518335425615, 1.3010389634021429}}, {{1, 10000, 1}}, 1, {"Continuous", 1}, 
  {"Discrete", 1}, 1, {}}, False, 10.]];

Wolfram Language code: tsm["CandidateSelectionTable"]

表格中的条目：

Wolfram Language code: tsm["CandidateSelectionTableEntries"]//Shallow

获取拟合数据的候选模型列表：

Wolfram Language code:

tsm = TimeSeriesModelFit[TemporalData[TimeSeries, {{{-0.7935061667730144, 4.3778286773763035, 2.922958541001586, 
    1.9853580784609617, 1.147308854130249, 1.698080426822207, 0.008331318340714766, 
    0.10200160157297689, 2.2513707375476235, 0.8328655174414309, -2.378076 ... 761350230830915, 2.4578396008405163, 
    -0.9273117800247228, 0.3871528084319487, 1.0557919551990362, 1.8934299378382737, 
    3.913518335425615, 1.3010389634021429}}, {{1, 10000, 1}}, 1, {"Continuous", 1}, 
  {"Discrete", 1}, 1, {}}, False, 10.], Method -> {"GridSearch", "SelectionCriterion" -> "AICc"}];

Wolfram Language code: Shallow[mod = tsm["CandidateModels"]]

通过 AIC 比较模型：

Wolfram Language code:

ListPlot[MapThread[Tooltip, {tsm["CandidateModelSelectionValues"], mod}], PlotRange -> All, PlotStyle -> PointSize[Large], Filling -> Axis]

检验拟合残差是否自相关：

Wolfram Language code:

ts = TemporalData[TimeSeries, {{{-0.7935061667730144, 4.3778286773763035, 2.922958541001586, 
    1.9853580784609617, 1.147308854130249, 1.698080426822207, 0.008331318340714766, 
    0.10200160157297689, 2.2513707375476235, 0.8328655174414309, -2.378076 ... 761350230830915, 2.4578396008405163, 
    -0.9273117800247228, 0.3871528084319487, 1.0557919551990362, 1.8934299378382737, 
    3.913518335425615, 1.3010389634021429}}, {{1, 10000, 1}}, 1, {"Continuous", 1}, 
  {"Discrete", 1}, 1, {}}, False, 10.];

Wolfram Language code: tsm1 = TimeSeriesModelFit[ts, {"ARMA", {2, 0}}];

在滞后3时有一个明显的尖峰：

Wolfram Language code: tsm1["ACFPlot"]

添加平均移动成分去除滞后3的自相关：

Wolfram Language code: tsm2 = TimeSeriesModelFit[ts, {"ARMA", {2, 1}}];

Wolfram Language code: tsm2["ACFPlot"]

检验拟合残差的偏相关函数是否为0：

Wolfram Language code:

ts = TemporalData[TimeSeries, {{{-0.7935061667730144, 4.3778286773763035, 2.922958541001586, 
    1.9853580784609617, 1.147308854130249, 1.698080426822207, 0.008331318340714766, 
    0.10200160157297689, 2.2513707375476235, 0.8328655174414309, -2.378076 ... 761350230830915, 2.4578396008405163, 
    -0.9273117800247228, 0.3871528084319487, 1.0557919551990362, 1.8934299378382737, 
    3.913518335425615, 1.3010389634021429}}, {{1, 10000, 1}}, 1, {"Continuous", 1}, 
  {"Discrete", 1}, 1, {}}, False, 10.];

Wolfram Language code: tsm1 = TimeSeriesModelFit[ts, {"ARMA", {2, 0}}];

在滞后3有明显的尖峰：

Wolfram Language code: tsm1["PACFPlot"]

添加移动平均成分去除在滞后3的偏相关：

Wolfram Language code: tsm2 = TimeSeriesModelFit[ts, {"ARMA", {2, 1}}];

Wolfram Language code: tsm2["PACFPlot"]

检验模型残差的自相关：

Wolfram Language code:

ts = TemporalData[TimeSeries, {{{-0.7935061667730144, 4.3778286773763035, 2.922958541001586, 
    1.9853580784609617, 1.147308854130249, 1.698080426822207, 0.008331318340714766, 
    0.10200160157297689, 2.2513707375476235, 0.8328655174414309, -2.378076 ... 761350230830915, 2.4578396008405163, 
    -0.9273117800247228, 0.3871528084319487, 1.0557919551990362, 1.8934299378382737, 
    3.913518335425615, 1.3010389634021429}}, {{1, 10000, 1}}, 1, {"Continuous", 1}, 
  {"Discrete", 1}, 1, {}}, False, 10.];

Wolfram Language code: tsm1 = TimeSeriesModelFit[ts, {"ARMA", {2, 0}}];

在滞后3和4有明显的尖峰：

Wolfram Language code: tsm1["LjungBoxPlot"]

添加移动平均成分去除明显的自相关：

Wolfram Language code: tsm2 = TimeSeriesModelFit[ts, {"ARMA", {2, 1}}];

Wolfram Language code: tsm2["LjungBoxPlot"]

获取用在残差白噪声诊断图中使用的值：

Wolfram Language code:

mod = TimeSeriesModelFit[TemporalData[TimeSeries, {{{-0.7935061667730144, 4.3778286773763035, 2.922958541001586, 
    1.9853580784609617, 1.147308854130249, 1.698080426822207, 0.008331318340714766, 
    0.10200160157297689, 2.2513707375476235, 0.8328655174414309, -2.378076 ... 761350230830915, 2.4578396008405163, 
    -0.9273117800247228, 0.3871528084319487, 1.0557919551990362, 1.8934299378382737, 
    3.913518335425615, 1.3010389634021429}}, {{1, 10000, 1}}, 1, {"Continuous", 1}, 
  {"Discrete", 1}, 1, {}}, False, 10.], {"ARMA", {2, 1}}];

Wolfram Language code: mod /@ {"ACFPlot", "PACFPlot", "LjungBoxPlot"}//GraphicsRow

在 "ACFPlot" 中使用了前5个自相关值和95%的置信区域：

Wolfram Language code: mod["ACFValues", "LagMax" -> 5]

在 "PACFPlot" 中使用了前5个偏自相关值和95%的置信区域：

Wolfram Language code: mod["PACFValues", "LagMax" -> 5]

滞后1到12的 Ljung–Box 值和标准值被用在图线中：

Wolfram Language code: mod["LjungBoxValues", "LagMax" -> 12]

报告模型参数的值和显著性：

Wolfram Language code:

tsm = TimeSeriesModelFit[TemporalData[TimeSeries, {{{-1.16, -0.98, 2.7, 12.08, 16.83, 20.78, 24.32, 24.92, 19.28, 13.34, 
    11.19, 3.3, 1.91, 2.02, 2.36, 10.27, 13.16, 22.26, 26.67, 24.55, 22.07, 11.81, 5.49, 0.88, 
    -3.71, -2.51, 4.42, 9.55, 13.82, 19.35, 23.29, 24.0 ... ation[{2001, 1, 1, 0, 0, 0.}, {2012, 1, 1, 0, 0, 0.}, {1, "Month"}]}, 
  1, {"Discrete", 1}, {"Discrete", 1}, 1, 
  {MetaInformation -> {"Caller" :> TemporalData[WeatherData["Chicago", "Temperature", dates][[All,
        2]], dates]}}}, True, 10.]]

Wolfram Language code: tsm["ParameterTable"]

来自于表格的值：

Wolfram Language code: tsm["ParameterTableEntries"]

从参数协方差矩阵中获取参数标准误差：

Wolfram Language code:

tsm = TimeSeriesModelFit[d = TemporalData[TimeSeries, {{{-1.16, -0.98, 2.7, 12.08, 16.83, 20.78, 24.32, 24.92, 19.28, 13.34, 
    11.19, 3.3, 1.91, 2.02, 2.36, 10.27, 13.16, 22.26, 26.67, 24.55, 22.07, 11.81, 5.49, 0.88, 
    -3.71, -2.51, 4.42, 9.55, 13.82, 19.35, 23.29, 24.0 ... ation[{2001, 1, 1, 0, 0, 0.}, {2012, 1, 1, 0, 0, 0.}, {1, "Month"}]}, 
  1, {"Discrete", 1}, {"Discrete", 1}, 1, 
  {MetaInformation -> {"Caller" :> TemporalData[WeatherData["Chicago", "Temperature", dates][[All,
        2]], dates]}}}, True, 10.]]

Wolfram Language code: Sqrt[Diagonal[tsm["CovarianceMatrix"]] / d["PathLength"]]

可以直接获取标准误差：

Wolfram Language code: tsm["ParameterStandardErrors"]

选项 (9)

ConfidenceLevel (2)

为预测极限设置置信水平：

Wolfram Language code: ts = RandomFunction[ARIMAProcess[{.1}, 2, {.2}, 1], {1, 150}];

Wolfram Language code: ListLinePlot[ts]

使用90%的置信水平：

Wolfram Language code: tsm = TimeSeriesModelFit[ts, ConfidenceLevel -> .9]

Wolfram Language code: t = tsm["PredictionLimits"][155]

拟合后置信水平可以更改：

Wolfram Language code: tsm["PredictionLimits", ConfidenceLevel -> .99][155]

ConfidenceLevel 设置影响特征检测的阈值：

Wolfram Language code:

SeedRandom[11];
data = RandomFunction[GARCHProcess[2, {.5}, {.3}], {1, 10 ^ 4}];

Wolfram Language code: TimeSeriesModelFit[data, ConfidenceLevel -> .9]

Wolfram Language code: Normal[%]

Wolfram Language code: TimeSeriesModelFit[data, ConfidenceLevel -> .99]

Wolfram Language code: Normal[%]

IncludeConstantBasis (1)

需要为模型估计常数：

Wolfram Language code:

data = TemporalData[Automatic, {{{-0.14119052344221666, -1.596907640266988, -2.2582073671446694, 
    -1.9319420528595548, -1.1478947661154448, -0.3674878918612522, 0.6590713786839412, 
    -1.102826183727665, -1.674076427012788, -3.9969894719586714, -6.1 ...   -27.10459273737598, -28.088716540543274, -29.740726054951963, -29.922334674607573, 
    -30.038824585257633, -32.389230950434325, -32.06299441006345, -32.95643499312959}}, 
  {{0, 999, 1}}, 1, {"Discrete", 1}, {"Discrete", 1}, 1, {}}, False, 9.];

Wolfram Language code: TimeSeriesModelFit[data, "ARMA", IncludeConstantBasis -> True]//Normal

设置常数为0：

Wolfram Language code: TimeSeriesModelFit[data, "ARMA", IncludeConstantBasis -> False]//Normal

Method (5)

默认情况下，使用逐步搜索选择参数阶数：

Wolfram Language code: data = RandomFunction[ARMAProcess[{.1}, {.2}, 1], {1, 10 ^ 4}];

Wolfram Language code: tsm1 = TimeSeriesModelFit[data, "ARMA", Method -> Automatic]//Normal

Wolfram Language code: tsm2 = TimeSeriesModelFit[data, "ARMA", Method -> "Stepwise"]//Normal

Wolfram Language code: tsm1 == tsm2

使用网格搜索：

Wolfram Language code: TimeSeriesModelFit[data, "ARMA", Method -> "GridSearch"]//Normal

执行混合搜索：

Wolfram Language code: TimeSeriesModelFit[data, {"ARMA", {Automatic, 0 ;; 10}}, Method -> "Stepwise"]//Normal

使用不同的选择标准选取最佳模型：

Wolfram Language code: data = RandomFunction[ARMAProcess[{.1}, {.2}, 1], {1, 10 ^ 4}];

默认情况下，使用 "AIC"：

Wolfram Language code: TimeSeriesModelFit[data, "ARMA"]["CandidateSelectionTable"]

使用 "BIC"：

Wolfram Language code: TimeSeriesModelFit[data, "ARMA", Method -> {Automatic, "SelectionCriterion" -> "BIC"}]["CandidateSelectionTable"]

设置候选模型的最大数目，以便继续报告：

Wolfram Language code:

temp = TemporalData[Automatic, {{{-1.16, -0.98, 2.7, 12.08, 16.83, 20.78, 24.32, 24.92, 19.28, 13.34, 
    11.19, 3.3, 1.91, 2.02, 2.36, 10.27, 13.16, 22.26, 26.67, 24.55, 22.07, 11.81, 5.49, 0.88, 
    -3.71, -2.51, 4.42, 9.55, 13.82, 19.35, 23.29, 24.09 ... cation[{2001, 1, 1, 0, 0, 0.}, {2012, 1, 1, 0, 0, 0.}, {1, "Month"}]}, 
  1, {"Discrete", 1}, {"Discrete", 1}, 1, 
  {MetaInformation -> {"Caller" :> TemporalData[WeatherData["Chicago", "Temperature", dates][[All,
        2]], dates]}}}, True, 9.];

保留最多15个模型：

Wolfram Language code: TimeSeriesModelFit[temp, Method -> {Automatic, "MaxCandidates" -> 15}]["CandidateModels"]//Length

保留所有适合的模型：

Wolfram Language code: TimeSeriesModelFit[temp, Method -> {Automatic, "MaxCandidates" -> Infinity}]["CandidateModels"]//Length

默认情况下，保留10个模型：

Wolfram Language code: TimeSeriesModelFit[temp]["CandidateModels"]//Length

设置最大允许的自回归和移动平均阶数：

Wolfram Language code:

temp = TemporalData[Automatic, {{{-1.16, -0.98, 2.7, 12.08, 16.83, 20.78, 24.32, 24.92, 19.28, 13.34, 
    11.19, 3.3, 1.91, 2.02, 2.36, 10.27, 13.16, 22.26, 26.67, 24.55, 22.07, 11.81, 5.49, 0.88, 
    -3.71, -2.51, 4.42, 9.55, 13.82, 19.35, 23.29, 24.09 ... cation[{2001, 1, 1, 0, 0, 0.}, {2012, 1, 1, 0, 0, 0.}, {1, "Month"}]}, 
  1, {"Discrete", 1}, {"Discrete", 1}, 1, 
  {MetaInformation -> {"Caller" :> TemporalData[WeatherData["Chicago", "Temperature", dates][[All,
        2]], dates]}}}, True, 9.];

Wolfram Language code:

TimeSeriesModelFit[temp, Method -> {Automatic, "MaxAROrder" -> 1, "MaxMAOrder" -> 1, "MaxSeasonalAROrder" -> 1, "MaxSeasonalMAOrder" -> 1}]

最大阶数限制拟合的模型数目：

Wolfram Language code:

TimeSeriesModelFit[temp, Method -> {"GridSearch", "MaxCandidates" -> Infinity, "MaxAROrder" -> 2, "MaxMAOrder" -> 2, "MaxSeasonalAROrder" -> 2, "MaxSeasonalMAOrder" -> 2}]["CandidateModels"]//Length

Wolfram Language code:

TimeSeriesModelFit[temp, Method -> {"GridSearch", "MaxCandidates" -> Infinity, "MaxAROrder" -> 1, "MaxMAOrder" -> 1, "MaxSeasonalAROrder" -> 1, "MaxSeasonalMAOrder" -> 1}]["CandidateModels"]//Length

逐步方法拟合模型在当前最佳模型的 "MaxStepSize" 阶数中：

Wolfram Language code:

data = TemporalData[Automatic, {{{0.48567872304876314, 0.554843335241101, 0.5934652242460972, 
    0.760477909565011, 1.7297685613735987, 1.212965224485393, 0.7565266649282496, 
    0.9400845884689406, -0.34817802196504266, -1.3246407289324051, -0.9286445 ... 646355753, 1.8935789572854922, 
    -0.002929238988200883, -0.771594065167061, -2.3867138941136625, -0.8945349352440608, 
    -2.3615995758210637, -0.5623814423867756}}, {{1, 10000, 1}}, 1, {"Continuous", 1}, 
  {"Discrete", 1}, 1, {}}, False, 9.];

默认情况下，最大阶数步长设为1：

Wolfram Language code: AbsoluteTiming[tsmDefault = TimeSeriesModelFit[data, Method -> {Automatic, "MaxStepSize" -> 1}]]

增加步长大小可以提高质量，但是可能增加搜索时间：

Wolfram Language code: AbsoluteTiming[tsmBigStep = TimeSeriesModelFit[data, Method -> {"Stepwise", "MaxStepSize" -> 5}]]

比较网格搜索：

Wolfram Language code: AbsoluteTiming[tsmGrid = TimeSeriesModelFit[data, "ARMA", Method -> "GridSearch"]]

WorkingPrecision (1)

使用 WorkingPrecision 获取更高精度的估计：

Wolfram Language code: ts = Accumulate[RandomChoice[{-1, 1}, 10 ^ 4]];

Wolfram Language code: TimeSeriesModelFit[ts, {"ARIMA", {1, 1, 1}}, WorkingPrecision -> 50]//Normal

应用 (8)

本地温度 (1)

预测在你的位置，下一个月的平均温度：

Wolfram Language code:

today = DateValue[Today, {"Year", "Month"}];
start = DateValue[DatePlus[Today, {-10, "Year"}], {"Year", "Month"}];
tspec = {start, today, "Month"};

过去10年本地平均月温度：

Wolfram Language code: temp = TimeSeries[WeatherData[FindGeoLocation[], "Temperature", tspec, "NonMetricValue"], {start, Automatic, "Month"}]

Wolfram Language code: DateListPlot[temp, Joined -> True, FrameLabel -> Automatic]

拟合时间序列模型：

Wolfram Language code: tsm = TimeSeriesModelFit[temp]

下一个月的预测：

Wolfram Language code: tsm[DatePlus[today, {1, "Month"}]]

在95%的置信带中绘制明年的预测：

Wolfram Language code: fdates = DateRange[today, DatePlus[today, {1, "Year"}], "Month"];

Wolfram Language code:

forecast = tsm /@ fdates;
bands = tsm["PredictionLimits"][#]& /@ fdates;

Wolfram Language code:

DateListPlot[{bands[[All, 1]], forecast, bands[[All, 2]]}, {today, Automatic, "Month"}, Joined -> True, PlotStyle -> {Gray, Automatic}]

飞机上的乘客 (2)

以下数据包括1949年1月到1960年12月美国国际航空乘客（按千计）的月总人数：

Wolfram Language code:

passengers = TemporalData[TimeSeries, {{{112, 118, 132, 129, 121, 135, 148, 148, 136, 119, 104, 118, 115, 126, 
    141, 135, 125, 149, 170, 170, 158, 133, 114, 140, 145, 150, 178, 163, 172, 178, 199, 199, 184, 
    162, 146, 166, 171, 180, 193, 181, 183, 218,  ... . (1994) Time \
Series Analysis, Forecasting and\nControl. Second Edition. New York: Prentice-Hall.", 
     "Description" -> "International Airline Passengers: Monthly Totals (Thousands of Passengers) \
January 1949 - December 1960"}}}, True, 10.];

在1958年1月分割数据：

Wolfram Language code:

before1958 = TimeSeriesWindow[passengers, {Automatic, "December 1957"}];
since1958 = TimeSeriesWindow[passengers, {"January 1958", Automatic}];

Wolfram Language code: p = DateListPlot[{before1958, since1958}, Joined -> True, PlotLegends -> {"Before 1958", "After 1958"}]

对1958年前的飞机乘客数据拟合一个时间序列模型：

Wolfram Language code: tsm = TimeSeriesModelFit[before1958]

比较1959年6月预测的和实际的飞机乘客数：

Wolfram Language code: tsm["June 1959"] * 1000//Round

Wolfram Language code: 1000since1958["June 1959"]

1958年到1961年预测数据与实际数据比较：

Wolfram Language code:

DateListPlot[{before1958, since1958, Table[{t, tsm[t]}, {t, DateRange["January 1958", "December 1960", "Month"]}]}, Joined -> True, PlotLegends -> {"Before 1958", "After 1958", "Forecast"}]

模拟未来7年的飞机乘客数并和预测相比较：

Wolfram Language code:

passengers = TemporalData[TimeSeries, {{{112, 118, 132, 129, 121, 135, 148, 148, 136, 119, 104, 118, 115, 126, 
    141, 135, 125, 149, 170, 170, 158, 133, 114, 140, 145, 150, 178, 163, 172, 178, 199, 199, 184, 
    162, 146, 166, 171, 180, 193, 181, 183, 218,  ... . (1994) Time \
Series Analysis, Forecasting and\nControl. Second Edition. New York: Prentice-Hall.", 
     "Description" -> "International Airline Passengers: Monthly Totals (Thousands of Passengers) \
January 1949 - December 1960"}}}, True, 10.];

对数据进行时间序列模型拟合：

Wolfram Language code: tsm = TimeSeriesModelFit[passengers]

创建7年预报并预测极限：

Wolfram Language code:

k = 7;
start = "December 1st, 1960";

Wolfram Language code: tsm["TemporalData"]["DateFunction"] /@ tsm["TemporalData"]["FirstTimes"]

Wolfram Language code: forecastDates = DateRange[start, DatePlus[start, {k, "Year"}], "Month"];

Wolfram Language code:

forecast = tsm /@ forecastDates;
bands = tsm["PredictionLimits"][#]& /@ forecastDates;

绘制预测的图线：

Wolfram Language code:

pforecast = DateListPlot[{bands[[All, 1]], forecast, bands[[All, 2]]}, {start, Automatic, "Month"}, Joined -> True, Filling -> {1 -> {3}}, PlotStyle -> {Directive[Dashed, StandardGray], Directive[Thick, Green]}]

模拟未来7年的100条路径：

Wolfram Language code: sim = RandomFunction[tsm, {0, 12 * k}, 100];

Wolfram Language code: psim = DateListPlot[sim, PlotStyle -> Directive[Opacity[.25]], Joined -> True, PlotRange -> All]

显示带有模拟路径的95%预测极限：

Wolfram Language code: Show[psim, pforecast, PlotRange -> All]

质数 (1)

对实际和估计的质数间的不同拟合一个时间序列模型：

Wolfram Language code: primeEstimator[n_] := n Log[n]

Wolfram Language code: primeDiff[n_] := Prime[n] - primeEstimator[n]

Wolfram Language code: diffs = Table[primeDiff[n], {n, 1, 250}];

Wolfram Language code: ListLinePlot[diffs, PlotRange -> All]

调整模型到差异：

Wolfram Language code: tsm = TimeSeriesModelFit[diffs]

显示带有95%预测极限的下一个100个不同的预测：

Wolfram Language code:

Show[Plot[tsm["PredictionLimits"][t], {t, 251, 350}, PlotRange -> {100, 400}, AxesOrigin -> {251, 100}, PlotStyle -> {Gray, Dashed}], DiscretePlot[primeDiff[n], {n, 251, 350}, Filling -> None]]

使用模型改善对第300个质数的估计：

Wolfram Language code: primeEstimator[300]//N

Wolfram Language code: primeEstimator[300] + tsm[300]

Wolfram Language code: Prime[300]

原始的和改进的估计与实际质数相比：

Wolfram Language code:

ListLinePlot[Transpose@Table[Join[{Prime[n], primeEstimator[n], primeEstimator[n] + tsm[n]}, primeEstimator[n] + tsm["PredictionLimits"][n]], {n, 251, 350}], PlotStyle -> {Automatic, Automatic, Automatic, Directive[Dashed, Gray], Directive[Dashed, Gray]}, PlotLegends -> {"primes", "original prime estimator", "improved prime estimator"}]

意外死亡 (1)

美国的意外死亡数按月记录了6年：

Wolfram Language code: deaths = ExampleData[{"Statistics", "USAccidentalDeaths"}, "EventSeries"]

Wolfram Language code: n = deaths["PathLength"]

Wolfram Language code: DateListPlot[deaths]

对数据进行 ARProcess 拟合：

Wolfram Language code: tsm1 = TimeSeriesModelFit[deaths, "AR"]

该模型忽略了数据的季节性：

Wolfram Language code: Table[Pane[tsm1[plot], ImageSize -> Medium], {plot, {"ACFPlot", "PACFPlot"}}]

诊断图建议需要一个带有12个季节性的模型：

Wolfram Language code: tsm12 = TimeSeriesModelFit[deaths, {"SARIMA", 12}]

季节性模型似乎普遍比非季节性的好：

Wolfram Language code: (#[{"AIC", "AICc", "BIC", "SBC"}]& /@ {tsm1, tsm12})//Grid

Wolfram Language code: Table[Pane[tsm12[plot], ImageSize -> Medium], {plot, {"ACFPlot", "PACFPlot"}}]

获取未来2个月的90%预报预测极限的经验估计：

Wolfram Language code: sixM = RandomFunction[tsm12, {0, 1}, 10 ^ 4];

Wolfram Language code: α = 0.9;

Wolfram Language code: Quantile[sixM["28 Feb 1979"], {(1 - α/2), (1 + α/2)}]

比较渐进估计：

Wolfram Language code: tsm12["PredictionLimits", ConfidenceLevel -> α]["28 Feb 1979"]

山猫毛皮 (1)

加拿大哈德逊湾公司在1850年到1911年每年销售的水貂皮草数：

Wolfram Language code:

sales = TemporalData[TimeSeries, {{{29619, 21151, 24859, 25152, 42375, 50839, 61581, 61951, 76231, 63264, 
    44730, 31094, 49452, 43961, 61727, 60334, 51404, 58451, 73575, 74343, 27708, 31985, 39266, 
    44740, 60429, 72273, 79214, 79060, 84244, 62590,  ... 7813, 57620, 66549, 54673, 55996, 60053, 39169, 21534, 17857, 21788, 33008}}, 
  {{1850, 1911, 1}}, 1, {"Continuous", 1}, {"Discrete", 1}, 1, 
  {ValueDimensions -> 1, ResamplingMethod -> {"Interpolation", InterpolationOrder -> 1}}}, False, 
 10.];

Wolfram Language code: ListPlot[sales, Joined -> True, PlotRange -> All]

对数据拟合模型：

Wolfram Language code: saleModel = TimeSeriesModelFit[sales]

模拟下一个10年的模型的值：

Wolfram Language code: sim = RandomFunction[saleModel, {0, 10}, 150]

模拟的值可能是负的，但是平均函数提供正的预测：

Wolfram Language code: forecast = TimeSeriesThread[Mean, sim];

Wolfram Language code: Min[forecast]

绘制由模拟给出的预测的数据：

Wolfram Language code:

Show[ListLinePlot[sales], ListLinePlot[sim, PlotStyle -> Directive[Opacity[.2]]], 
	ListLinePlot[forecast, PlotStyle -> Green], PlotRange -> All]

零售销售 (1)

美国每月的零售销售额：

Wolfram Language code: raw = WolframAlpha["usa retail sales", {{"History:RetailSales:EconomicData", 1}, "TimeSeriesData"}];

Wolfram Language code: raw[[1]]

根据选择创建 TimeSeries：

Wolfram Language code: data = TimeSeries[QuantityMagnitude[raw[[-12 * 15 ;; , 2]]], {Automatic, raw[[-1, 1]], "Month"}]

在12月尖峰时用网格线绘制销售额：

Wolfram Language code:

grids = Table[{1992, 12 i}, {i, 1, data["PathLength"]}];
DateListPlot[data, GridLines -> {grids, None}, AspectRatio -> 1 / 3]

拟合季节性模型：

Wolfram Language code: model = TimeSeriesModelFit[data, {"SARIMA", 12}]

过程参数：

Wolfram Language code: proc = model["BestFit"]

找到下一个7年的参数：

Wolfram Language code: forecast = TimeSeriesForecast[model, {0, 7 * 12}]

计算预测的95%置信带：

Wolfram Language code:

α = .95;
q = Quantile[NormalDistribution[], 1 - (1 - α) / 2];
err = forecast["MeanSquaredErrors"];
bands = TimeSeriesThread[{{1, -q}.#, {1, q}.#}&, {forecast, Sqrt[err]}]

有上下带：

Wolfram Language code: bands["ValueDimensions"]

在95%的置信区域内绘制预测：

Wolfram Language code: grids = Table[{1992, 12 i}, {i, data["PathLength"] + forecast["PathLength"]}];

Wolfram Language code:

DateListPlot[{data, forecast, bands["PathComponent", 1], bands["PathComponent", 2]}, Filling -> {3 -> {4}}, AspectRatio -> 1 / 3, PlotStyle -> {Automatic, Automatic, Gray, Gray}, GridLines -> {grids, None}]

医药销售和广告 (1)

以下的时间序列是美国医药专利所有人丽迪亚·平克汉姆的双季度的销售和广告. 平克汉姆开始制作蔬菜合剂作为家庭药物，并与她的邻居共享. 她的合剂是磨碎的药草混合，含有18%的酒精. 1875年平克汉姆家庭决定从商卖药，她声称她的药可医治从神经衰弱到子宫下垂的任何妇女疾病. 很快就获得认可，一年净收入将近39万美元. 直到20世纪20年代，当联邦药品和广告法规增加时，Lydia E. Pinkham Medicine Co. 同时降低医药的酒精含量和其疗效的声明：

Wolfram Language code:

sales = TemporalData[Automatic, {{{608, 451, 529, 543, 525, 549, 525, 578, 609, 504, 752, 613, 862, 866, 
    1016, 1360, 1482, 1608, 1800, 1941, 1229, 1373, 1611, 1568, 983, 1046, 1453, 1504, 807, 339, 
    562, 745, 749, 862, 1034, 1054, 1164, 1102, 1145 ...  domestic sales and advertising of Lydia E,Pinkham Medicine,1907 to 1960", 
     "Source" -> "http://datamarket.com/data/set/22rf/annual-domestic-sales-and-advertising-of-lydi\
a-e-pinkham-medicine-1907-to-1960#!display=line&ds=22rf"}}}, True, 9.];

Wolfram Language code: sales["Source"]

Wolfram Language code: DateListPlot[sales, Filling -> Axis]

为数据找到模型：

Wolfram Language code: salesModel = TimeSeriesModelFit[sales]

Wolfram Language code: Normal[salesModel]

预测下一个5年的值：

Wolfram Language code: forecast = TimeSeriesForecast[salesModel, {2 * 5}]

该模型预测客户对平克汉姆药物疗效的信赖的急剧下降：

Wolfram Language code: DateListPlot[{sales, forecast}, Filling -> Axis]

可能存在的问题 (2)

以下数据是每月的样本，并且季节性参数为 12：

Wolfram Language code:

data = TemporalData[TimeSeries, {{{Quantity[1.46376*^11, "USDollars"/"Months"], 
    Quantity[1.47079*^11, "USDollars"/"Months"], Quantity[1.59336*^11, "USDollars"/"Months"], 
    Quantity[1.63669*^11, "USDollars"/"Months"], Quantity[1.70068*^11, "USDolla ... 00, 3550089600, 3552768000, 3555446400, 3558038400, 3560716800, 3563308800, 
     3565987200, 3568665600, 3571084800, 3573763200, 3576355200, 3579033600, 3581625600}}}, 1, 
  {"Discrete", 1}, {"Discrete", 1}, 1, {ValueDimensions -> 1}}, True, 10.];

Wolfram Language code: data["Dates"] === TimeSeriesResample[data, "Month"]["Dates"]

Wolfram Language code: DateListPlot[data, Joined -> True]

TemporalData 不知道数据是按月等间隔的：

Wolfram Language code: RegularlySampledQ[data]

按 28 天的最小时间增量自动重采样会导致季节参数变为 13：

Wolfram Language code: MinimumTimeIncrement[data]

Wolfram Language code: TimeSeriesModelFit[data]

告诉 TemporalData 对数据按常规处理：

Wolfram Language code: dataR = TimeSeries[data, TemporalRegularity -> True];

Wolfram Language code: RegularlySampledQ[dataR]

没有必要重新采样；季节性参数被保留：

Wolfram Language code: TimeSeriesModelFit[dataR]

TimeSeriesModelFit 使用时刻方法估计候选过程的参数. 不同估计器的使用会导致不同的排名：

Wolfram Language code: data = RandomFunction[MAProcess[{4 / 5, -4 / 5}, 1], {0, 1000}];

Wolfram Language code: tsm = TimeSeriesModelFit[data, {"MA", 2}, "IncludeConstantBasis" -> False]

Wolfram Language code: tsm["BestFit"]

2阶最大似然性估计：

Wolfram Language code: mle = EstimatedProcess[data, MAProcess[{b1, b2}, v], ProcessEstimator -> "MaximumLikelihood"]

最大似然估计被每个选择标准所使用：

Wolfram Language code:

criteria = {"AIC", "BIC", "SBC", "AICc"};mleCrits = TimeSeriesModelFit[data, mle][criteria];
bestFitCrits = tsm[criteria];

Wolfram Language code:

TableForm[{Style[#, Gray]& /@ bestFitCrits, Style[#, StandardGray]& /@ mleCrits}, TableHeadings -> {{"BestFit", "MLE"}, criteria}]

Top

	Automatic	自动选择要使用的模型
	"family"	从给定系列中选择一个模型
	{"family",params}	从给定系列的子集中选择一个模型

"AR"	{p}	自回归模型系列
"MA"	{q}	移动平均模型系列
"ARMA"	{p,q}	自回归移动平均模型系列
"ARIMA"	{p,d,q}	整合 ARMA 模型系列
"SARMA"	{{p,q},{sp,sq},s}	季节性 ARMA 模型系列
"SARIMA"	{{p,d,q},{sp,sd,sq},s}	季节性 ARIMA 模型系列
"ARCH"	{q}	ARCH 模型系列
"GARCH"	{q,p}	GARCH 模型系列

	"BestFit"	拟合模型
	"BestFitParameters"	系数估计
	"ErrorVariance"	模型误差方差
	"FitResiduals"	拟合模型的残差
	"StandardizedResiduals"	标准化模型的残差
	"TemporalData"	作为 TemporalData 的输入数据

	"CovarianceMatrix"	模型系数的协方差估计
	"InformationMatrix"	模型系数的信息矩阵
	"ParameterConfidenceIntervals"	系数估计的置信区间
	"ParameterStandardErrors"	模型系数的标准误差
	"ParameterTable"	拟合系数信息表格
	"ParameterTableEntries"	参数表格中的条目

更多学习资源

技术支持

数据科学、金融与商业

工程

科学与技术

教育科技

教育举措

开始

提高你的技能

与我们合作

成人教育计划

青少年教育计划

欢迎阅读

TimeSeriesModelFit

更多信息和选项

范例

基本范例 (1)

范围 (22)

基本用途 (5)

模型规范 (6)

模型属性 (11)

选项 (9)

ConfidenceLevel (2)

IncludeConstantBasis (1)

Method (5)

WorkingPrecision (1)

应用 (8)

本地温度 (1)

飞机上的乘客 (2)

质数 (1)

意外死亡 (1)

山猫毛皮 (1)

零售销售 (1)

医药销售和广告 (1)

可能存在的问题 (2)

文本

CMS

APA

BibTeX

BibLaTeX

	"CandidateModels"	按选择标准排序的候选模型集合
	"CandidateModelSelectionValues"	每个候选模型的选择标准值
	"CandidateSelectionTable"	包含模型和选择标准值的表格
	"CandidateSelectionTableEntries"	候选选择表格的条目
	"ModelFamily"	选择的模型系列
	"SelectionCriterion"	选择最好模型的标准

	"AIC"	Akaike 信息量准则
	"AICc"	有限样本修正的 AIC
	"BIC"	Bayesian 信息量准则
	"SBC"	Schwartz–Bayes 信息量准则

	"ACFPlot"	残差自相关的图线
	"ACFValues"	"ACFPlot" 的值
	"PACFPlot"	残差偏自相关的图线
	"PACFValues"	"PACFPlot" 的值
	"LjungBoxPlot"	Ljung–Box 残差自相关检验值的图线
	"LjungBoxValues"	"LjungBoxPlot" 的值

TimeSeriesModelFit

更多信息和选项

范例

基本范例 (1)

范围 (22)

基本用途 (5)

模型规范 (6)

模型属性 (11)

选项 (9)

ConfidenceLevel (2)

IncludeConstantBasis (1)

Method (5)

WorkingPrecision (1)

应用 (8)

本地温度 (1)

飞机上的乘客 (2)

质数 (1)

意外死亡 (1)

山猫毛皮 (1)

零售销售 (1)

医药销售和广告 (1)

可能存在的问题 (2)

参见

相关指南

历史

文本

CMS

APA

BibTeX

BibLaTeX