WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

WordData["word","property"]

英単語"word"の指定された特性を返す．

WordData["word"]

"word"の可能な意味と使用法を表す完全な語の仕様のリストを返す．

WordData[wordspec,"property"]

特定の語の仕様に関する特性を返す．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
語の識別  
結果の構造  
意味関連特性  
Show More Show More
使用法の特徴  
語彙および 形態学上の特性  
他の語からの派生語  
語のクラス  
一般化と拡張  
アプリケーション  
特性と関係  
考えられる問題  
おもしろい例題  
関連項目
テクニカルノート
関連するガイド
関連リンク
履歴
引用書式

WordData

WordData["word","property"]

英単語"word"の指定された特性を返す．

WordData["word"]

"word"の可能な意味と使用法を表す完全な語の仕様のリストを返す．

WordData[wordspec,"property"]

特定の語の仕様に関する特性を返す．

詳細

  • 語の特定の用法や意味は{"word","part","sense"}の形式の語の仕様で表すことができる．ここで，"part"は品詞，"sense"は意味のタグである．
  • 1つの意味でしか使われない語は単に"word"として指定できる．特定の品詞では1つの意味でしか使われない語は{"word","part"}で指定できる．
  • WordDataでは，通常の語の大文字化は文中と同じように行われる（例："word"や"America"）．
  • 複数の語からなる語句（"a priori"等）も使うことができ，これらは1語として扱われる．
  • 品詞名には"Noun"，"Verb"，"Adjective"，"Adverb"，"Preposition"，"Determiner"等がある．
  • 意味のタグはWolfram言語の名前のように大文字化される．
  • WordData[]は，WordDataで使用可能なすべての語および語句のリストを返す．
  • 語の用法や意味に依存する特性については，WordData[wordspec,"property"]は wordspec に矛盾しない語の各用法と意味に関する規則のリストを返す．
  • WordData[wordspec,"property","form"]は結果を次の形式で返す．
  • "List"すべての語の仕様に対する結果の単一リスト
    "Rules"個々の語の仕様についての語の仕様のリスト
    "ShortRules"各語の仕様の結果の語のリスト
  • 語の基本文法特性
  • "PartsOfSpeech"語の可能な品詞
  • WordData[All,"part"]は指定された品詞のすべての語を返す．WordData[All,"Stopwords"]は一般にテキスト比較で無視される語のリストを返す．WordData[All,"PartsOfSpeech"]は品詞のリストを返す．
  • WordData[patt,"Lookup"]は，文字列パターン patt にマッチする使用可能なすべての語のリストを返す．
  • 語の基本的な意味関連特性
  • "Antonyms"反意語（例："small"に対する"large"）
    "BroaderTerms"語の一般化（例："circle"からの"shape"）
    "Definitions"当該語の定義
    "Examples"当該語の用例
    "NarrowerTerms"語の特殊化（例："shape"に対する"circle"）
    "Synonyms"同意語（例："large" と"big"）
  • 単語の用法の特徴を説明する特性
  • "ConceptWeight"意味的重要性の大まかな評価
    "GeographicDomain"語が関係する地理的範囲（例："India"）
    "UsageField"語が使用される分野（例："Law"）
    "UsageType"語の使用タイプ（例："Slang"や"Archaism"）
  • 単語の語彙特性
  • "Hyphenation"語のハイフン付けの際のまとまり
    "PhoneticForm"IPA音声表記
  • 単語の形態特性
  • "BaseForm"当該語の語幹（例："larger"の"large"）
    "InflectedForms"当該語の語形変化した形（例："go"からの"went"）
    "MorphologicalDerivatives"形態的派生語
    "MorphologicalSource"当該語の形態論的にもとになっている語
    "PorterStem"ポーターアルゴリズムを使ってステミングされた形の語
  • 名詞の特別特性
  • "CompositeTerms"物質からなる要素（例："copper"と"brass"）
    "DerivedAdjectives"派生形容詞（例："America"から"American" ）
    "MaterialTerms"構成物質の語（例："brass"と"copper"）
    "PartTerms"部分を表す語（例："hand"から"finger"）
    "SubsetTerms"部分集合の語（例："Animalia"と"Arthropoda"）
    "SupersetTerms"上位集合の語（例："Animalia"と"Arthropoda"）
    "WholeTerms"全体を表す語（例："finger"から"hand"）
  • 動詞の特別特性
  • "CausesTerms"原因を表す動詞（例："die"に対する"kill"）
    "ConsequencesTerms"結果を表す動詞（例："kill"に対する"die"）
    "EntailedTerms"動作を伴う動詞（例："walk"に対する"step"）
    "SentenceFrames"句の中での動詞の使われ方
  • 形容詞の特別特性
  • "BaseNoun"形容詞が派生したもとの名詞（例："hand"から"handy"）
    "DerivedAdverb"派生した副詞（例："quick"から"quickly" ）
  • 副詞の特別特性
  • "BaseAdjective"副詞が派生した形容詞（例："quickly"に対する"quick"）
  • 語のラベル特性
  • "WordNetID"語のWordNet体系構成認識番号
  • WordData[All,"Properties"]は，WordDataによってサポートされている全特性を返す．
  • WordDataの使用にはインターネット接続が必要な場合がある．

例題

すべて開く すべて閉じる

例  (6)

"fish"という語のいくつかの意味：

Wolfram Language code: WordData["fish"]

品詞：

Wolfram Language code: WordData["fish", "PartsOfSpeech"]

定義：

Wolfram Language code: WordData["fish", "Definitions"]

同意語：

Wolfram Language code: WordData["fish", "Synonyms"]

より広義の語：

Wolfram Language code: WordData["fish", "BroaderTerms"]

活用形：

Wolfram Language code: WordData["fish", "InflectedForms"]

スコープ  (29)

語の識別  (5)

活用形は標準化される：

Wolfram Language code: WordData["fishes"]

"fish"のすべて意味を見る：

Wolfram Language code: WordData["fish"]

名詞としての"fish"のすべての意味：

Wolfram Language code: WordData[{"fish", "Noun"}]

食物としての"fish"の狭義の意味：

Wolfram Language code: WordData[{"fish", "Noun", "Food"}, "NarrowerTerms"]

"fishe"で始まる語を検索する：

Wolfram Language code: WordData["fishe" ~~ ___, "Lookup"]

結果の構造  (3)

"group" の意味を同意語とともに返す：

Wolfram Language code: WordData["group", "Synonyms"]

"group"の意味を指定せずに同意語のリストを返す：

Wolfram Language code: WordData["group", "Synonyms", "List"]

各同意語の意味を返す：

Wolfram Language code: WordData["group", "Synonyms", "Rules"]

意味関連特性  (6)

単語の定義を与える：

Wolfram Language code: WordData["grateful", "Definitions"]

単語の使用例を与える：

Wolfram Language code: WordData["grateful", "Examples"]

単語の同意語を与える：

Wolfram Language code: WordData["grateful", "Synonyms"]

単語の反意語を与える：

Wolfram Language code: WordData["grateful", "Antonyms"]

より狭いスコープでの概念を与える：

Wolfram Language code: WordData["galaxy", "NarrowerTerms"]

より広いスコープでの概念を与える：

Wolfram Language code: WordData["galaxy", "BroaderTerms"]

使用法の特徴  (2)

"fish"の異なる意味を求める可能性の大雑把な「先験的」推定：

Wolfram Language code: WordData["fish", "ConceptWeight"]

英国式から米国式のスペリングに，またはその逆に変換する：

Wolfram Language code: WordData["color", "BritishSpelling"]
Wolfram Language code: WordData[%, "AmericanSpelling"]

語彙および 形態学上の特性  (4)

"parallelogram"の音節：

Wolfram Language code: WordData["parallelogram", "Hyphenation"]

parallelの音声形式：

Wolfram Language code: WordData["parallel", "PhoneticForm"]

語の語幹：

Wolfram Language code: WordData["running", "PorterStem"]

"be"の活用形：

Wolfram Language code: WordData["be", "InflectedForms", "List"]

他の語からの派生語  (5)

「tail」を含むもの：

Wolfram Language code: WordData["tail", "WholeTerms", "List"]

「tail」の部分：

Wolfram Language code: WordData["tail", "PartTerms", "List"]

「tail」の意味から派生した形容詞：

Wolfram Language code: WordData["tail", "DerivedAdjectives", "List"]

「water」の構成要素の用語：

Wolfram Language code: WordData["water", "MaterialTerms", "List"]

厳密な下位語と上位語：

Wolfram Language code: WordData["Reptilia", "SubsetTerms", "List"]
Wolfram Language code: WordData["Reptilia", "SupersetTerms", "List"]

語のクラス  (4)

WordDataに含まれる語と語句の総数：

Wolfram Language code: Length[WordData[All]]

サポートされている全品詞：

Wolfram Language code: WordData[All, "PartsOfSpeech"]

WordDataに含まれる動詞数：

Wolfram Language code: Length[WordData[All, "Verb"]]

WordDataに含まれる接続詞のリスト：

Wolfram Language code: WordData[All, "Conjunction"]//Short

一般化と拡張  (1)

英語にはない「語」の語幹でさえも求めることができる：

Wolfram Language code: WordData["baaabanizing", "PorterStem"]

アプリケーション  (14)

語の意味をリストする：

Wolfram Language code: Text[Column[Row[#, ":"]& /@ WordData["fish"]]]

文中の語がどの品詞でありうるかを求める：

Wolfram Language code: WordData[#, "PartsOfSpeech"]& /@ StringSplit["it rains on the plains"]

"head"を部分に持つ語を求める：

Wolfram Language code: WordData["head", "WholeTerms", "List"]

"fish"からの3ステップの同意語参照で辿り着ける語を求める：

Wolfram Language code: NestList[Union[Flatten[WordData[#, "Synonyms", "List"]& /@ #]]&, {"fish"}, 2]

辿り着いた語の数の増加を計算する：

Wolfram Language code: Length /@ NestList[Union[Flatten[WordData[#, "Synonyms", "List"]& /@ #]]&, {"fish"}, 10]
Wolfram Language code: ListLogPlot[%]

語の中には固定点に達するものもある：

Wolfram Language code: Length /@ NestList[Union[Flatten[WordData[#, "Synonyms", "List"]& /@ #]]&, {"frog"}, 10]

徐々に意味が広くなる語を求める：

Wolfram Language code: NestList[Flatten[WordData[#, "BroaderTerms", "List"]& /@ #]&, {"toad"}, 2]

求められた語ではっきり区別できる語の数の増加を求める：

Wolfram Language code: Length /@ NestList[Union[Flatten[WordData[#, "BroaderTerms", "List"]& /@ #]]&, {"toad"}, 10]

"ough"で終る語を求める：

Wolfram Language code: DictionaryLookup[__ ~~ "ough"]//Short

それぞれの発音を求める：

Wolfram Language code: WordData[#, "PhoneticForm"]& /@ %//Short

英単語のハイフン付けのまとまり（ほぼ音節に相当する）の数の分布を求める：

Wolfram Language code: d = Sort[Tally[Length /@ DeleteCases[(WordData[#1, "Hyphenation"]&) /@ DictionaryLookup[], _Missing]]]
Wolfram Language code: ListLogPlot[d, Joined -> True, Filling -> Axis]

語の定義の表を作る：

Wolfram Language code: Column[Text /@ WordData["fish", "Definitions", "List"], ItemSize -> {30, Automatic}, Frame -> All, Spacings -> 1.5, Background -> DarkYellow]

「tree」という語の2ステップの同意語ネットワークを作成する：

Wolfram Language code: GraphPlot[Flatten[Rest[NestList[Union[Flatten[Thread[# -> WordData[#, "Synonyms", "List"]]& /@ Last /@ #]]&, {"" -> "tree"}, 2]]] , DirectedEdges -> True, VertexLabels -> Automatic, ImageSize -> Medium]

「tree」の5ステップの同意語ネットワークを作成する：

Wolfram Language code: GraphPlot[Flatten[Rest[NestList[Union[Flatten[Thread[# -> WordData[#, "Synonyms", "List"]]& /@ Last /@ #]]&, {"" -> "tree"}, 5]]]]

ある語の成員について，その同意語に基づいた語句のうち最短のものを求める：

Wolfram Language code: StringSplit["operational fracture conceptualization"]
Wolfram Language code: Take[SortBy[StringJoin[Riffle[#, " "]]& /@ Tuples[WordData[#, "Synonyms", "List"]& /@ %], StringLength], 4]

文を英国式から米国式のスペリングに変換する：

Wolfram Language code: StringReplace["The centre was modelled with customised colours", w : (WordCharacter..) :> WordData[w, "AmericanSpelling"]]

両方が4文字未満の長さの英語の反意語のペアを求める：

Wolfram Language code: Select[{#, With[{w = WordData[#, "Antonyms", "List"]}, If[Length[w] > 0, First[SortBy[w, StringLength]], w]]}& /@ WordData[], (#[[2]] =!= {} && Max[StringLength /@ #] < 4)&]

10個のランダムにサンプルされた英語の形容詞：

Wolfram Language code: RandomSample[WordData[All, "Adjective"], 10]

特性と関係  (2)

現在WordDataに含まれている語の総数：

Wolfram Language code: Length[WordData[]]

ある特定の意味についての同意語は可換である：

Wolfram Language code: WordData["reptile", "Synonyms"]
Wolfram Language code: WordData["reptilian", "Synonyms"]

考えられる問題  (2)

WordDataはDictionaryLookupには含まれない語や語句をカバーする：

Wolfram Language code: WordData["every last"]
Wolfram Language code: DictionaryLookup["every last"]

WordDataには，DictionaryLookupにあまり使われることがないとして含まれていないような語も含まれている：

Wolfram Language code: WordData["ret", "Definitions"]
Wolfram Language code: DictionaryLookup["ret"]

おもしろい例題  (7)

WordData中の特定の数の意味を持つ語の数の分布を求める：

Wolfram Language code: ListLogPlot[Sort[Tally[Length[WordData[#]]& /@ WordData[]]]]

一つの大文字に帰属する意味の数を求める：

Wolfram Language code: CharacterRange["A", "Z"]
Wolfram Language code: # -> Length[WordData[#]]& /@ %
Wolfram Language code: ListPlot[Last /@ %, PlotRange -> {0, All}, Filling -> 0]

WordData集合内で最も多くの意味を持つ語を求める：

Wolfram Language code: WordData[][[Ordering[Length[WordData[#]]& /@ WordData[], -10]]]

各語の意味数を求める：

Wolfram Language code: Length[WordData[#]]& /@ %

WordData集合内のいくつの語がそれぞれの品詞として使えるかを求める：

Wolfram Language code: {#, Length[WordData[All, #]]}& /@ WordData[All, "PartsOfSpeech"]

最も多くの異なる品詞として使われる単語を求める：

Wolfram Language code: WordData[][[Ordering[Length[WordData[#, "PartsOfSpeech"]]& /@ WordData[], -5]]]
Wolfram Language code: # -> WordData[#, "PartsOfSpeech"]& /@ %

アメリカ合衆国の独立宣言に含まれる語の意味の移動平均を求める：

Wolfram Language code: ListLinePlot[MovingAverage[Length[WordData[ToLowerCase[#]]]& /@ Flatten[StringCases[ExampleData[{"Text", "DeclarationOfIndependence"}, "Words"], LetterCharacter..]], 20], Filling -> Axis, PlotRange -> {0, All}, Frame -> True]

動詞間の因果関係のネットワークを構築する：

Wolfram Language code: GraphPlot[Flatten[(Thread[#1 -> WordData[#1, "ConsequencesTerms", "List"]]&) /@ WordData[All, "Verb"]]]
Wolfram Research (2007), WordData, Wolfram言語関数， https://reference.wolfram.com/language/ref/WordData.html.

テキスト

Wolfram Research (2007), WordData, Wolfram言語関数， https://reference.wolfram.com/language/ref/WordData.html.

CMS

Wolfram Language. 2007. "WordData." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/WordData.html.

APA

Wolfram Language. (2007). WordData. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/WordData.html

BibTeX

@misc{reference.wolfram_2026_worddata, author="Wolfram Research", title="{WordData}", year="2007", howpublished="\url{https://reference.wolfram.com/language/ref/WordData.html}", note=[Accessed: 09-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_worddata, organization={Wolfram Research}, title={WordData}, year={2007}, url={https://reference.wolfram.com/language/ref/WordData.html}, note=[Accessed: 09-November-2026]}