WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

"CString" （コンパイルタイプ）

"CString"

C言語と互換の文字列を表す．

詳細

  • "CString"はTypedおよび型を指定する関連した構造で使うことができる．
  • 型"CString"を持つオブジェクトは自動的にはメモリ管理されないので，手動で解放する必要がある．
  • "CString"は"CArray"::["CChar"]のマクロである．
  • "CString"はC言語のchar*またはunsigned char*に等しい．

コンストラクタ

  • "Managed"でラップされていない限り，CreateTypeInstanceで構築されたC文字列は自動的にメモリ管理されず，DeleteObjectを使って手動で解放されなければならない． »
  • CreateTypeInstance["CString",str]は"String" str からC文字列を構築する．
  • CreateTypeInstance["CString",len]は長さ len のC文字列を構築する．
  • CreateTypeInstance["CString",cstr,len]は長さ len の cstr のコピーを構築する．cstr が len より短いと，クラッシュする可能性がある．
  • CreateTypeInstance["CString",cstr]はヌル終端文字列 cstr のコピーを拘置する．cstr がヌル終端文字列でないと，クラッシュする可能性がある．

変換

    配列

  • 配列型は管理されたC文字列にCastすることができる．サポートされる配列型には"ListVector"，"NumericArray"，"PackedArray"がある．

    • "String"

  • Castは"String"オブジェクトを管理されたC文字列に変換するために使うことができる．

    • "RawPointer"および"OpaqueRawPointer"

  • CastはC文字列を未加工のポインタにビットキャストしたり未加工のポインタからビットキャストするために使うことができる．

例題

すべて開く すべて閉じる

例  (1)

管理されたC文字列を作成し，それをC標準ライブラリ関数のstrlenに渡して長さを得る関数をコンパイルする：

Wolfram Language code: cf = FunctionCompile[Function[Typed[str, "String"], With[{cstr = CreateTypeInstance["Managed"::["CString"], str]}, LibraryFunction["strlen"][cstr] ] ]]

文字列でコンパイルされた関数を評価する：

Wolfram Language code: cf["Hello, World!"]

Scope  (2)

C標準のatofライブラリを使ってC文字列を数字にパースする関数をコンパイルする：

Wolfram Language code: cf = FunctionCompile@Function[{}, Module[{cstr}, cstr = TypeHint["3.14", "CString"]; LibraryFunction["atof"][cstr] ] ]

Evaluate the compiled function:

Wolfram Language code: cf[]

"CInt"を文字列に変換し，それをサイズ512の管理されたC文字列に保存する：

Wolfram Language code: libDecl = LibraryFunctionDeclaration[ "snprintf", {"CString", "CInt", "CString", "CInt"} -> "Integer32" ]; fun = Function[{Typed[n, "CInt"]}, Module[{size, cstr, fmt, err}, size = TypeHint[512, "CInt"]; cstr = CreateTypeInstance["Managed"::["CString"], size]; fmt = TypeHint["%d", "CString"]; err = LibraryFunction["snprintf"][cstr, size, fmt, n];CreateTypeInstance["String", cstr] ] ]; func = FunctionCompile[libDecl, fun]
Wolfram Language code: func[42]//InputForm

Possible Issues  (1)

"Managed"オブジェクトの外部で生成されたC文字列は自動的にメモリ管理されないので，手動で解放しなければならない．管理されないC文字列を作成する関数をコンパイルする：

Wolfram Language code: cf1 = FunctionCompile[Function[{}, With[{carr = CreateTypeInstance["CString", 100]}, Null ]]]

この関数はメモリをリークする：

Wolfram Language code: With[{before = MemoryInUse[]}, Do[cf1[], 10];MemoryInUse[] - before]

DeleteObjectを使って手動でC文字列を解放する：

Wolfram Language code: cf2 = FunctionCompile[Function[{}, With[{carr = CreateTypeInstance["CString", 100]}, DeleteObject[carr] ]]]

結果の関数はメモリをリークしない：

Wolfram Language code: With[{before = MemoryInUse[]}, Do[cf2[], 10];MemoryInUse[] - before]