WOLFRAM

Wolfram 语言与系统参考资料中心

"CString" （编译类型）

"CString"

代表一个与 C 语言兼容的字符串.

更多信息

  • "CString" 可用在 Typed 及相关构造中，用来指定类型.
  • 类型为 "CString" 的对象不是由内存自动管理的，必须手动释放.
  • "CString" 是 "CArray"::["CChar"] 的一个宏.
  • "CString" 在 C 语言中等价于 char* 或 unsigned char*.

函数构造

转换

    数组

  • 数组类型的范围包括从 Cast 到托管的 C 语言字符串. 支持的数组类型包括 "ListVector"、"NumericArray" 和 "PackedArray".

    • "String"

  • Cast 可用于将 "String" 对象转换为托管的 C 语言字符串.

    • "RawPointer" 和 "OpaqueRawPointer"

  • Cast 可用于 C 语言字符串和原始指针之间相互进行 bitcast 转换.

范例

打开所有单元 关闭所有单元

基本范例  (1)

编译一个函数，创建一个托管 C 字符串并将其传递给 C 标准库函数 strlen 以获取其长度：

Wolfram Language code: cf = FunctionCompile[Function[Typed[str, "String"], With[{cstr = CreateTypeInstance["Managed"::["CString"], str]}, LibraryFunction["strlen"][cstr] ] ]]

在字符串上运算编译后的函数：

Wolfram Language code: cf["Hello, World!"]

范围  (2)

使用 C 标准库中的 atof 库函数编译一个将 C 字符串解析为数字的函数：

Wolfram Language code: cf = FunctionCompile@Function[{}, Module[{cstr}, cstr = TypeHint["3.14", "CString"]; LibraryFunction["atof"][cstr] ] ]

运行编译好的函数：

Wolfram Language code: cf[]

将 "CInt" 转换为字符串，并将其存储在大小为 512 的托管 C 字符串中：

Wolfram Language code: libDecl = LibraryFunctionDeclaration[ "snprintf", {"CString", "CInt", "CString", "CInt"} -> "Integer32" ]; fun = Function[{Typed[n, "CInt"]}, Module[{size, cstr, fmt, err}, size = TypeHint[512, "CInt"]; cstr = CreateTypeInstance["Managed"::["CString"], size]; fmt = TypeHint["%d", "CString"]; err = LibraryFunction["snprintf"][cstr, size, fmt, n];CreateTypeInstance["String", cstr] ] ]; func = FunctionCompile[libDecl, fun]
Wolfram Language code: func[42]//InputForm

可能存在的问题  (1)

在 "Managed" 对象之外创建的 C 语言字符串不会被自动管理内存，必须手动释放. 编译一个创建非托管 C 语言字符串的函数：

Wolfram Language code: cf1 = FunctionCompile[Function[{}, With[{carr = CreateTypeInstance["CString", 100]}, Null ]]]

该函数泄漏内存：

Wolfram Language code: With[{before = MemoryInUse[]}, Do[cf1[], 10];MemoryInUse[] - before]

使用 DeleteObject 来手动释放 C 语言字符串：

Wolfram Language code: cf2 = FunctionCompile[Function[{}, With[{carr = CreateTypeInstance["CString", 100]}, DeleteObject[carr] ]]]

由此产生的函数不会泄漏内存：

Wolfram Language code: With[{before = MemoryInUse[]}, Do[cf2[], 10];MemoryInUse[] - before]