WOLFRAM

Wolfram 语言与系统参考资料中心

"RawPointer" （编译类型）

"RawPointer"::[t]

代表一个指向类型为 t 的对象的指针，适合与外部库一起使用.

更多信息

  • "RawPointer"::[t] 等价于 C 语言中的 t*.

函数构造

  • ToRawPointer 可用于创建一个指针对象，该对象使用分配在栈上的内存，并且在封闭函数返回之前是有效的.
  • 除非使用 "Managed" 包装，否则使用 CreateTypeInstance 构造的指针对象不会自动进行内存管理，必须通过 DeleteObject 手动释放.
  • CreateTypeInstance["RawPointer"::[type]] 构造一个原始指针.
  • CreateTypeInstance["Managed"::["RawPointer"::[type]]] 构造一个内存托管的 C 原始指针.

属性

  • 类型 "RawPointer"::[t] 的 ptr 的 Information[ptr,"BaseType"] 给出 "TypeSpecifier"::[t].
  • FromRawPointer[ptr] 返回 ptr 所指向的值.

转换

    来自表达式

  • RawPointer 表达式可以在已编译代码中被转换为原始指针类型.

    • 变成表达式

  • 已编译的 "RawPointer" 元素可以被转换为 RawPointer 表达式. 注意，在已编译代码中，原始指针必须通过 CreateTypeInstance 动态分配.

    • "CArray"

  • Cast 可用于在 C 语言数组和指针之间进行相互 bitcast 转换.

    • "OpaqueRawPointer"

  • Cast 可用于在指针和不透明的指针之间进行相互 bitcast 转换.

运行时错误

  • 用 FromRawPointer 对指针解引用 (dereferencing) 是一个不安全的操作. 试图对无效指针解引用会导致崩溃.

范例

基本范例  (4)

创建 "RawPointer"::["MachineInteger"]，然后对其进行解引用：

Wolfram Language code: cf = FunctionCompile[Function[Typed[arg, "Integer64"], With[{p = ToRawPointer[arg]}, FromRawPointer[p]] ]]
Wolfram Language code: cf[4]

代表一个通过修改一个指针来返回其结果的库函数：

Wolfram Language code: funcDec = LibraryFunctionDeclaration["addonePointer", "compilerDemoBase", {"CInt", "RawPointer"::["CInt"]} -> "CInt"];

编译一个使用该函数的程序：

Wolfram Language code: cf = FunctionCompile[funcDec, Function[Typed[n, "CInt"], Module[{ptr}, ptr = Typed[ToRawPointer[], "RawPointer"::["CInt"]]; LibraryFunction["addonePointer"][n, ptr]; FromRawPointer[ptr] ]]]
Wolfram Language code: cf[12]

编译一个返回包含数值的原始指针的程序：

Wolfram Language code: cf = FunctionCompile[ Function[Typed[n, "Integer64"], Module[{ptr}, ptr = CreateTypeInstance["RawPointer"]; ToRawPointer[ptr, n]; ptr ]]]
Wolfram Language code: rp = cf[12]

接受原始指针、提取值并删除指针的编译函数：

Wolfram Language code: cf1 = FunctionCompile[ Function[Typed[rp, "RawPointer"::["Integer64"]], Module[{val}, val = FromRawPointer[rp];DeleteObject[rp];val] ]]
Wolfram Language code: cf1[rp]

编译一个返回包含值的托管原始指针的程序：

Wolfram Language code: cf = FunctionCompile[ Function[Typed[n, "Integer64"], Module[{ptr}, ptr = CreateTypeInstance["Managed"::["RawPointer"::["Integer64"]]]; ToRawPointer[ptr, n]; ptr ]]]

调用编译后的代码：

Wolfram Language code: rp = cf[12]

接受托管原始指针并提取值的编译函数：

Wolfram Language code: cf1 = FunctionCompile[ Function[Typed[rp, "Managed"::["RawPointer"::["Integer64"]]], FromRawPointer[rp] ]]

指针不应被手动释放，因为这将由 "Managed" 自动完成：

Wolfram Language code: cf1[rp]