WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

"SparseArray" （コンパイルタイプ）

"SparseArray"::[type,rank]

指定された型とランクの要素を持つ，疎配列型を表す．

詳細

  • "SparseArray"はTypedおよび型を指定する関連した構造で使うことができる．
  • "SparseArray"オブジェクトは自動的にメモリ管理される．

特性

  • "SparseArray"::[type, rank]では，指定されていない値は常に0となり，rank は1か2のいずれかとなる．

変換

    式から

  • SparseArray式は，"SparseArray"で生成された型のコンパイルコード要素に変換することができる．

    • 式へ

  • "SparseArray"で生成された型のコンパイルコード要素はSparseArray式に変換することができる．

例題

すべて開く すべて閉じる

例  (1)

"SparseArray"はCompiledCodeFunctionの入力および出力として使うことができる：

Wolfram Language code: cf = FunctionCompile[Function[Typed[arg, "SparseArray"::["Integer64", 2]], arg]]
Wolfram Language code: cf[SparseArray[{{1, 0, 2}, {0, 3, 0}}]]
Wolfram Language code: MatrixForm[%]

スコープ  (1)

SparseArray特性はCompiledCodeFunction内で使える場合がある：

Wolfram Language code: cf = FunctionCompile[Function[Typed[arg, "SparseArray"::["MachineReal", 2]], Module[{nz, dims, nelems }, nz = arg["ExplicitLength"]; dims = Dimensions[arg]; nelems = Typed[1., "MachineReal"]; Do[nelems *= dims[[i]], {i, Length[dims]}]; Cast[nz, "MachineReal"] / nelems ]]]
Wolfram Language code: cf[SparseArray[{{1., 0, 2.}, {0, 3., 0}}]]

これは"Density"特性に等しい：

Wolfram Language code: SparseArray[{{1., 0, 2.}, {0, 3., 0}}]["Density"]

この関数は実数演算を使うので，要素の合計数が機械サイズの整数にとって大きすぎるときでも対応する：

Wolfram Language code: cf[SparseArray[{{1, 1} -> 1.}, {10 ^ 6, 10 ^ 16}]]

Neat Examples  (1)

疎行列のベキ級数を計算する：

Wolfram Language code: cf = FunctionCompile[Function[{ Typed[coeffs, "PackedArray"::["MachineReal", 1]], Typed[a, "SparseArray"::["MachineReal", 2]]}, Module[{res, len, n}, n = Length[a]; len = Length[coeffs]; res = DiagonalMatrix[coeffs[[len]], 0, n, SparseArray]; Do[ res = res.a + DiagonalMatrix[coeffs[[i]], 0, n, SparseArray], {i, len - 1, 1, -1} ]; res ] ]]

これは行列の平方を計算することに等しい：

Wolfram Language code: sp = SparseArray[{{1, 1} -> 1., {2, 2} -> 2., {3, 3} -> 3., {1, 3} -> 4.}]; cf[{0, 0, 1}, sp]//Normal

指数関数の係数を生成し，それを使って行列の指数関数を計算する：

Wolfram Language code: coeffs = CoefficientList[ Normal[ Series[Exp[x], {x, 0, 16}]], x]; cf[N[coeffs], sp]//Normal

指数関数を計算するにはMatrixExp関数を使った方がよいが，ベキ級数の結果は近かった：

Wolfram Language code: MatrixExp[sp]//Normal