WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

"Counter" (データ構造)

"Counter"

可変整数カウンタを表す．

詳細

  • 可変整数カウンタは，プログラムの任意部分に含まれる要素の数を数えるのに使うことができる．
  • CreateDataStructure[ "Counter",i]指定の初期値 i を持つ新しい"Counter"を作成する
    Typed[x,"Counter"]x に"Counter"型を与える
  • "Counter"型のデータ構造には，以下の演算が使える．
  • ds["AddTo",n]n をカウンタに加え，新しい値を返すtime: O(1)
    ds["Copy"]ds のコピーを返すtime: O(1)
    ds["Decrement"]カウンタを減少させ，古い値を返すtime: O(1)
    ds["Get"]ds に保存されたカウンタの値を得るtime: O(1)
    ds["Increment"]カウンタを増加させ，古い値を返すtime: O(1)
    ds["PreDecrement"]カウンタを減少させ，新しい値を返すtime: O(1)
    ds["PreIncrement"]カウンタを増加させ，新しい値を返すtime: O(1)
    ds["Set",i]ds に保存されたカウンタが i となるように設定するtime: O(1)
    ds["SubtractFrom",n]n をカウンタから引き，新しい値を返すtime: O(1)
    ds["Visualization"]ds の可視化を返すtime: O(1)
  • 以下の関数もサポートする．
  • dsi===dsjdsi が dsj に等しい場合はTrue
    FullForm[ds]ds の完全形
    Information[ds]ds についての情報
    InputForm[ds]ds の入力形
    Normal[ds]ds を通常の式に変換する

例題

すべて開く すべて閉じる

例  (1)

新しい"Counter"は，CreateDataStructureを使って作成できる：

Wolfram Language code: ds = CreateDataStructure["Counter", 1]

保存された値を抽出する：

Wolfram Language code: ds["Get"]

カウンタに保存された値を増加させる：

Wolfram Language code: ds["Increment"]

値が更新されたことを確かめる：

Wolfram Language code: ds["Get"]

式バージョンの ds を返す：

Wolfram Language code: Normal[ds]

データ構造の可視化を生成することができる：

Wolfram Language code: ds["Visualization"]

スコープ  (13)

可変性  (2)

新しい"Counter"のデータ構造を作成し，それを初期化する：

Wolfram Language code: ds = CreateDataStructure["Counter", 0]

引数が偶数である場合にカウンタをインクリメントする関数を定義する：

Wolfram Language code: f = Function[{arg}, If[EvenQ[arg], ds["Increment"]]];

式の全要素について関数をスキャンする：

Wolfram Language code: Scan[f, {1, 2, {6, 7, 2, {6, 1}}}, {-1}]

式に含まれる偶数要素の数：

Wolfram Language code: ds["Get"]

新しい"Counter"データ構造を作成し，それを初期化する：

Wolfram Language code: ds = CreateDataStructure["Counter", 0]

カウンタを増分させると，古いカウンタ値が返される：

Wolfram Language code: ds["Increment"] === ds["Get"]

カウンタを前置増分させると，現在のカウンタ値が返される：

Wolfram Language code: ds["PreIncrement"] === ds["Get"]

カウンタを設定すると，現在のカウンタ値が返される：

Wolfram Language code: ds["Set", 100] === ds["Get"]

カウンタに加えると，新しい値が返される：

Wolfram Language code: {ds["AddTo", 20], ds["Get"]}

カウンタから引いた場合にも，新しい値が返される：

Wolfram Language code: {ds["SubtractFrom", 40], ds["Get"]}

情報  (1)

新しい"Counter"は，CreateDataStructureを使って作成することができる：

Wolfram Language code: ds = CreateDataStructure["Counter", 1]

データ構造 ds についての情報：

Wolfram Language code: Information[ds]

演算  (10)

"AddTo"  (1)

1に初期化された新しい"Counter"を作成する：

Wolfram Language code: ds = CreateDataStructure["Counter", 1]

カウンタに整数を加え，新しい値を返す：

Wolfram Language code: ds["AddTo", 10]

保存された値を得る：

Wolfram Language code: ds["Get"]

"Copy"  (1)

1に初期化された新しい"Counter"を作成する：

Wolfram Language code: ds = CreateDataStructure["Counter", 1]

カウンタのコピーを得る：

Wolfram Language code: ds1 = ds["Copy"]

両方のカウンタのコンテンツは同じである：

Wolfram Language code: {Normal[ds], Normal[ds1]}

コピーを変更してももとのカウンタには影響しない：

Wolfram Language code: ds1["Increment"]; {Normal[ds], Normal[ds1]}

"Decrement"  (1)

1に初期化された新しい"Counter"を作成する：

Wolfram Language code: ds = CreateDataStructure["Counter", 1]

カウンタを減少させ，古い値を返す：

Wolfram Language code: ds["Decrement"]

保存された値を得る：

Wolfram Language code: ds["Get"]

"Get"  (1)

1に初期化された新しい"Counter"を作成する：

Wolfram Language code: ds = CreateDataStructure["Counter", 1]

保存された値を得る：

Wolfram Language code: ds["Get"]

"Increment"  (1)

1に初期化された新しい"Counter"を作成する：

Wolfram Language code: ds = CreateDataStructure["Counter", 1]

カウンタを増分させ，古い値を返す：

Wolfram Language code: ds["Increment"]

保存された値を得る：

Wolfram Language code: ds["Get"]

"PreDecrement"  (1)

1に初期化された新しい"Counter"を作成する：

Wolfram Language code: ds = CreateDataStructure["Counter", 1]

カウンタを減少させ，新しい値を得る：

Wolfram Language code: ds["PreDecrement"]

保存された値を得る：

Wolfram Language code: ds["Get"]

"PreIncrement"  (1)

1に初期化された新しい"Counter"を作成する：

Wolfram Language code: ds = CreateDataStructure["Counter", 1]

カウンタを増分させ，新しい値を返す：

Wolfram Language code: ds["PreIncrement"]

保存された値を得る：

Wolfram Language code: ds["Get"]

"Set"  (1)

1に初期化された新しい"Counter"を作成する：

Wolfram Language code: ds = CreateDataStructure["Counter", 1]

カウンタを新しい整数に設定する：

Wolfram Language code: ds["Set", 5]

保存された値を得る：

Wolfram Language code: ds["Get"]

"SubtractFrom"  (1)

52に初期化された新しい"Counter"を作成する：

Wolfram Language code: ds = CreateDataStructure["Counter", 52]

カウンタから整数を引き，新しい値を返す：

Wolfram Language code: ds["SubtractFrom", 10]

保存された値を得る：

Wolfram Language code: ds["Get"]

"Visualization"  (1)

42に初期化された新しい"Counter"を作成する：

Wolfram Language code: ds = CreateDataStructure["Counter", 42]

コンテンツを可視化する：

Wolfram Language code: ds["Visualization"]

アプリケーション  (3)

一意的なIDを生成する  (1)

"Counter"を使って，評価中に連続する一意的な識別子を生成する：

Wolfram Language code: id = CreateDataStructure["Counter", 0]; newID[] := id["PreIncrement"];
Wolfram Language code: Table[newID[], 5]

再帰呼出しを数える  (1)

評価中になされた再帰呼出しの数を数える：

Wolfram Language code: counter = CreateDataStructure["Counter", 0]; fib[0 | 1] := 1; fib[n_] := (counter["Increment"];fib[n - 1] + fib[n - 2]);
Wolfram Language code: fib[6]; counter["Get"]

可変状態を関数に渡す  (1)

"Counter"を関数に渡し，評価中にそれを変化させる：

Wolfram Language code: countPrimes[data_, counter_] := Scan[If[PrimeQ[#], counter["Increment"]]&, data];

カウンタを作成し，関数を呼び出す：

Wolfram Language code: counter = CreateDataStructure["Counter", 0]; countPrimes[Range[1000], counter]; counter["Get"]

関数をもう一度呼び出すと，同じカウンタが引き続き変更される：

Wolfram Language code: countPrimes[Range[1001, 10000], counter]; counter["Get"]

特性と関係  (4)

InputForm  (1)

InputFormは，"Counter"の連続番号付きのコンテンツを返す：

Wolfram Language code: InputForm[CreateDataStructure["Counter", 42]]

連続番号付きの形式を使ってデータ構造を再作成することができる：

Wolfram Language code: DataStructure["Counter", {"Data" -> 42}]

Normal  (1)

Normalを使って"Counter"のコンテンツを得ることができる：

Wolfram Language code: ds = CreateDataStructure["Counter", 42]; Normal[ds]

"Get"演算を使っても同じものが得られる：

Wolfram Language code: ds["Get"]

SameQ  (1)

SameQを使って，2つのカウンタんひ同じ値が含まれるかどうかをテストすることができる：

Wolfram Language code: ds1 = CreateDataStructure["Counter", 42]; ds2 = CreateDataStructure["Counter", 42]; ds1 === ds2

1つの要素が変更されると，カウンタはもはや同じではない：

Wolfram Language code: ds1["Increment"]; ds1 === ds2

"Value"  (1)

"Counter"データ構造は，"Value"データ構造の整数の特定化されたバージョンであると考えることができる．

考えられる問題  (1)

"Counter"のデータ構造は，64ビットの整数でしか初期化されないことがある：

Wolfram Language code: CreateDataStructure["Counter", 1.2]