WOLFRAM

Wolfram 语言与系统参考资料中心

"FixedArray" （数据结构）

"FixedArray"

表示一个固定长度的数组，其中的元素是普通表达式.

更多信息

  • 固定长度的数组可用于有效地提取和更新元素：
  • CreateDataStructure[ "FixedArray",n]创建新的有 n 个元素的空 "FixedArray"
    CreateDataStructure[ "FixedArray",x,n]创建一个长度为 n 的新 "FixedArray"，初始化为 x
    CreateDataStructure[ "FixedArray",elems]创建一个包含 elems 的新 "FixedArray"
    Typed[x,"FixedArray"]指定 x 的类型为 "FixedArray"
  • 对于类型为 "FixedArray" 的数据结构，可进行以下操作：
  • ds["Copy"]返回 ds 的副本时间: O(n)
    ds["Elements"]返回 ds 的参数列表时间: O(n)
    ds["EmptyQ"]如果 ds 中没有元素则返回 True时间: O(1)
    		ds["Fold",fun]将 fun 应用于 ds 的元素，并累计结果时间：O(n)
    ds["Fold",fun,init]将 fun 应用于 ds 的以 init 开始的元素，并累计结果时间：O(n)
    ds["Length"]存储在 ds 中的元素的数量时间: O(1)
    ds["Part",i]给出 ds 中的第 i 个元素时间: O(1)
    ds["SetPart",i,elem]更新 ds 的第 i 个元素时间: O(1)
    ds["SwapPart",i,j]将 ds 的第 i 个元素和第 j 个元素互换时间: O(1)
    ds["Visualization"]返回 ds 的可视化时间: O(n)
  • 还支持以下函数：
  • dsi===dsj如果 dsi 等于 dsj 则为 True
    ds["Part",i]=val将 ds 的第 i 个元素设为 val
    FullForm[ds]ds 的完全形式
    Information[ds]关于 ds 的信息
    InputForm[ds]ds 的输入形式
    Length[ds]ds 中的元素个数
    Normal[ds]将 ds 转换成普通表达式

范例

打开所有单元 关闭所有单元

基本范例  (2)

可用 CreateDataStructure 创建新的 "FixedArray"：

Wolfram Language code: ds = CreateDataStructure["FixedArray", 8]

返回总长度：

Wolfram Language code: ds["Length"]

这些元素被初始化为 Null：

Wolfram Language code: ds["Elements"]

改变元素：

Wolfram Language code: ds["Part", 1] = f[2]

该元素已被更新：

Wolfram Language code: ds["Part", 1]

表达式形式的 ds：

Wolfram Language code: Normal[ds]

快速更新元素：

Wolfram Language code: ds = CreateDataStructure["FixedArray", 1000]; Do[ds["SetPart", i, i], {i, 1000}]

可以生成该数组的可视化效果：

Wolfram Language code: ds["Visualization"]

求所有元素的和：

Wolfram Language code: ds["Fold", Plus]

范围  (13)

创建  (3)

创建一个包含 12 个元素的 "FixedArray"：

Wolfram Language code: ds = CreateDataStructure["FixedArray", 12]

默认情况下，所有元素都初始化为 Null：

Wolfram Language code: ds["Elements"]

创建一个包含 12 个元素并指定默认初始值的 "FixedArray"：

Wolfram Language code: ds = CreateDataStructure["FixedArray", -1, 12]

获取数组的内容：

Wolfram Language code: ds["Elements"]

用一个数组的内容初始化 "FixedArray"：

Wolfram Language code: ds = CreateDataStructure["FixedArray", {x, y, z}]

获取数组的内容：

Wolfram Language code: ds["Elements"]

信息  (1)

可用 CreateDataStructure 创建新的 "FixedArray"：

Wolfram Language code: ds = CreateDataStructure["FixedArray", 8]

数据结构 ds 的信息：

Wolfram Language code: Information[ds]

操作  (9)

"Copy"  (1)

创建一个带有初始值的 "FixedArray"：

Wolfram Language code: ds = CreateDataStructure["FixedArray", {1, 2, 3}]

获取数组的一个副本：

Wolfram Language code: ds1 = ds["Copy"]

两个数组的内容相同：

Wolfram Language code: {Normal[ds], Normal[ds1]}

修改副本不会影响原始数组：

Wolfram Language code: ds1["SetPart", 2, 42]; {Normal[ds], Normal[ds1]}

"Elements"  (1)

创建一个带有初始值的 "FixedArray"：

Wolfram Language code: ds = CreateDataStructure["FixedArray", Range[10]]; ds["Visualization"]

将内容以列表形式返回：

Wolfram Language code: ds["Elements"]

Normal 返回相同的列表：

Wolfram Language code: Normal[ds]

"EmptyQ"  (1)

测试 "FixedArray" 是否为空：

Wolfram Language code: ds = CreateDataStructure["FixedArray", 0]; ds["EmptyQ"]

"Fold"  (1)

创建一个带有初始值的 "FixedArray"：

Wolfram Language code: ds = CreateDataStructure["FixedArray", Range[10]]

使用 Plus 组合数组的所有元素，产生它们的总和：

Wolfram Language code: ds["Fold", Plus]

你也可以指定一个初始值来开始累积：

Wolfram Language code: ds["Fold", Plus, 42]

"Length"  (1)

创建一个带有初始值的 "FixedArray"：

Wolfram Language code: ds = CreateDataStructure["FixedArray", Range[5]]

获取数组中元素的数量：

Wolfram Language code: ds["Length"]

Length 函数给出相同的值：

Wolfram Language code: Length[ds]

"Part"  (1)

创建一个带有初始值的 "FixedArray"：

Wolfram Language code: ds = CreateDataStructure["FixedArray", Range[10]]

获取数组的第五个元素：

Wolfram Language code: ds["Part", 5]

"SetPart"  (1)

创建一个带有初始值的"FixedArray"：

Wolfram Language code: ds = CreateDataStructure["FixedArray", Range[10]]

将数组的第五个元素设置为另一个值：

Wolfram Language code: ds["SetPart", 5, x]

可视化数组：

Wolfram Language code: ds["Visualization"]

以下语法同样有效：

Wolfram Language code: ds["Part", 6] = y; ds["Visualization"]

"SwapPart"  (1)

创建一个带有初始值的 "FixedArray"：

Wolfram Language code: ds = CreateDataStructure["FixedArray", Range[10]]

交换第五个和第六个位置上的元素值：

Wolfram Language code: ds["SwapPart", 5, 6]

可视化数组：

Wolfram Language code: ds["Visualization"]

"Visualization"  (1)

创建一个带有初始值的 "FixedArray"：

Wolfram Language code: ds = CreateDataStructure["FixedArray", Range[10]]

可视化数组的内容：

Wolfram Language code: ds["Visualization"]

属性和关系  (1)

滑动窗口计算  (1)

使用 "FixedArray" 维护流数据上的滑动窗口：

Wolfram Language code: buffer = CreateDataStructure["FixedArray", ConstantArray[0, 5]]

通过移位和覆盖插入新元素：

Wolfram Language code: push[array : DataStructure["FixedArray", _], x_] := With[{len = Length[array]}, Do[array["SetPart", i, array["Part", i + 1]], {i, 1, len - 1}]; array["SetPart", len, x] ]

处理传入的值：

Wolfram Language code: Scan[push[buffer, #]&, Range[8]]; buffer["Elements"]

属性和关系  (5)

InputForm  (1)

InputForm 返回 "FixedArray" 的序列化内容：

Wolfram Language code: InputForm[CreateDataStructure["FixedArray", Range[10]]]

该序列化形式可用于重新创建数据结构：

Wolfram Language code: DataStructure["FixedArray", {"Data" -> {1, 2, 3, 4, 5, 6, 7, 8, 9, 10}}]

Length  (1)

可以使用 Length 获取 "FixedArray" 中的元素数量：

Wolfram Language code: ds = CreateDataStructure["FixedArray", Range[10]]; Length[ds]

通过 "Length" 操作也能达到同样的效果：

Wolfram Language code: ds["Length"]

Normal  (1)

Normal 可用于获取 "FixedArray" 的元素：

Wolfram Language code: ds = CreateDataStructure["FixedArray", Range[10]]; Normal[ds]

通过 "Elements" 操作也能达到同样的效果：

Wolfram Language code: ds["Elements"]

SameQ  (1)

SameQ 可用于测试两个数组是否包含相同顺序的相同元素：

Wolfram Language code: ds1 = CreateDataStructure["FixedArray", Range[10]]; ds2 = CreateDataStructure["FixedArray", Range[10]]; ds1 === ds2

如果更改了一个元素，数组就不再相同：

Wolfram Language code: ds1["SetPart", 5, 42]; ds1 === ds2

"DynamicArray"  (1)

许多适用于 "DynamicArray" 的算法也同样适用于 "FixedArray".

与 "DynamicArray" 不同，"FixedArray" 的大小无法修改.

可能存在的问题  (2)

需使用正整数指定数组中元素的个数：

Wolfram Language code: ds = CreateDataStructure["FixedArray", 1.2]

不能设置数组中不存在的元素的值：

Wolfram Language code: ds = CreateDataStructure["FixedArray", 16]
Wolfram Language code: ds["SetPart", 17, "test"]

互动范例  (1)

计算并保存数据结构中的个别绘图，然后使用 Manipulate 交互式显示这些绘图：

Wolfram Language code: ds = CreateDataStructure["FixedArray", 16]
Wolfram Language code: Do[ds["SetPart", i, Plot[Sin[i x] / x, {x, 0, 10}, Filling -> Axis, PlotRange -> 1]], {i, ds["Length"]}]
Wolfram Language code: Manipulate[ds["Part", i], {i, 1, ds["Length"], 1}]

巧妙范例  (2)

斐波那契  (1)

计算斐波那契序列的前 16 个元素：

Wolfram Language code: ds = CreateDataStructure["FixedArray", 16]

将前两个元素设为 1，然后计算剩下的元素：

Wolfram Language code: ds["SetPart", 1, 1]; ds["SetPart", 2, 1]; Do[ds["SetPart", i, ds["Part", i - 2] + ds["Part", i - 1]], {i, 3, ds["Length"]}]

显示结果：

Wolfram Language code: ds["Visualization"]

直方图  (1)

下面的函数计算图像中不同颜色值的直方图：

Wolfram Language code: redBin = CreateDataStructure["FixedArray", ConstantArray[0, 256]]; greenBin = CreateDataStructure["FixedArray", ConstantArray[0, 256]]; blueBin = CreateDataStructure["FixedArray", ConstantArray[0, 256]]; indexOf[x_] := Floor[255 x] + 1 computeHistogram[{r_, g_, b_}] := Module[{}, redBin["SetPart", indexOf[r], redBin["Part", indexOf[r]] + 1]; greenBin["SetPart", indexOf[b], greenBin["Part", indexOf[b]] + 1]; blueBin["SetPart", indexOf[g], blueBin["Part", indexOf[g]] + 1]; ]

对图像的像素应用该函数：

Wolfram Language code: ImageScan[computeHistogram, [image]]

显示结果：

Wolfram Language code: BarChart[Transpose[Normal /@ {redBin, greenBin, blueBin}], PlotRange -> All, ChartStyle -> {Red, Green, Blue}, BarSpacing -> None]