WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

"NearestNeighbors" (機械学習メソッド)

  • ClassifyおよびPredictのためのメソッドである．
  • 特徴空間の最近傍を分析することで，新たな例のクラスまたは値を推測する．

詳細とサブオプション

  • 最近傍は例に基づく学習である．その最も単純な形では，最頻クラスを取るか k 最近傍の値を平均するかする．
  • 次は，使用可能なオプションである．
  • "NeighborsNumber" Automatic考慮する近傍数 (k)
    "DistributionSmoothing" 0.5パラメータの正規化
    "NearestMethod" Automatick 近傍例の計算に使うメソッド
  • 次は，"NearestMethod"の可能な設定である．
  • "KDtree"データの保存にk分木データ構造を使う
    "Octree"データの保存に八分木データ構造を使う
    "Scan"データ集合全体の徹底検索

例題

すべて開く すべて閉じる

例  (2)

ラベル付きの例で分類器関数を訓練する：

Wolfram Language code: c = Classify[{1, 2, 3, 4} -> {1, 1, 2, 2}, Method -> "NearestNeighbors"]

分類器についての情報を得る：

Wolfram Language code: Information[c]

新たな例を分類する：

Wolfram Language code: c[1.3]

データを生成し，可視化する：

Wolfram Language code: data = Table[x -> x + RandomVariate[NormalDistribution[0, 2]], {x, RandomReal[{-10, 10}, 40]}]; ListPlot[List@@@data]

このデータで予測器関数を訓練する：

Wolfram Language code: p = Predict[data, Method -> "NearestNeighbors"]

このデータを予測された値と比較し，標準偏差を見る：

Wolfram Language code: Show[Plot[{p[x], p[x] + StandardDeviation[p[x, "Distribution"]], p[x] - StandardDeviation[p[x, "Distribution"]]}, {x, -2, 6}, PlotStyle -> {Blue, Gray, Gray}, Filling -> {2 -> {3}}, Exclusions -> False, PerformanceGoal -> "Speed", PlotLegends -> {"Prediction", "Confidence Interval"}], ListPlot[List@@@data, PlotStyle -> Red, PlotLegends -> {"Data"}]]

オプション  (6)

"DistributionSmoothing"  (2)

"DistributionSmoothing"サブオプションを使って分類器を訓練する：

Wolfram Language code: Classify[{1.98, 3.83, 1.69, 0.04, 2.48, 1.66} -> {"a", "a", "b", "b", "a", "b"}, Method -> {"NearestNeighbors", "DistributionSmoothing" -> 2}]

"DistributionSmoothing"の値を変えた不均衡なデータ集合で2つの分類器を訓練する：

Wolfram Language code: data = {1 -> True, 2 -> True, 3 -> True, 4 -> True, 5 -> False, 6 -> True};
Wolfram Language code: c1 = Classify[data, Method -> {"NearestNeighbors", "DistributionSmoothing" -> .1}]
Wolfram Language code: c2 = Classify[data, Method -> {"NearestNeighbors", "DistributionSmoothing" -> 10}]

この2つの分類器の確率を見る：

Wolfram Language code: c1[5, "Probabilities"]
Wolfram Language code: c2[5, "Probabilities"]

"NearestMethod"  (2)

特定の"NearestMethod"を使って分類器を訓練する：

Wolfram Language code: Classify[{1.98, 3.83, 1.69, 0.04, 2.48, 1.66} -> {"a", "a", "b", "b", "a", "b"}, Method -> {"NearestNeighbors", "NearestMethod" -> "Scan"}]

大きいデータ集合を生成し，可視化する：

Wolfram Language code: gaussian[μ_, σ_, n_] := RandomVariate[MultinormalDistribution[μ, {{σ, 0}, {0, σ}}], n]; positions = {{4, 2}, {-2, 2}, {0, -3}, {3, 0}}; sizes = {2, 1, 5, 0.5}; colors = {RGBColor[1, 0, 0], RGBColor[0, 0, 1], RGBColor[0, 1, 0], RGBColor[1., 0.77, 0.]}; nums = {10000, 10000, 50000, 20000};
Wolfram Language code: clusters = MapThread[gaussian, {positions, sizes, nums}]; trainigset = AssociationThread[colors, clusters]; plot = ListPlot[clusters, PlotStyle -> Darker[colors, 0.1], ImageSize -> 200, PlotRange -> {{-5, 5}, {-5, 5}}, Frame -> True, AspectRatio -> 1, PlotLabel -> "data"]

異なるメソッドを使っていくつかの分類器を訓練し，訓練時間を比較する：

Wolfram Language code: classifiers = Classify[trainigset, Method -> {"NearestNeighbors", "NearestMethod" -> #}]& /@ {"Octree", "KDtree", "Scan"};

それぞれの訓練時間を比較する：

Wolfram Language code: Information[#, "TrainingTime"]& /@ classifiers

"NeighborsNumber"  (2)

特定の"NeighborsNumber"を使って予測器関数を訓練する：

Wolfram Language code: Predict[{1.98, 3.83, 1.69, 0.04, 2.48, 1.66} -> {-1.41, -0.71, -0.701, -0.4, -1.91, -1.6}, Method -> {"NearestNeighbors", "NeighborsNumber" -> 2}]

ラベル付きの訓練集合を生成し，可視化する：

Wolfram Language code: trainingset = Table[x -> Sin[4x] + RandomReal[.4], {x, RandomReal[{0, 6}, 30]}]; ListPlot[List@@@trainingset]

小さい"NeighborsNumber"を使って予測器を訓練する：

Wolfram Language code: p2 = Predict[trainingset, Method -> {"NearestNeighbors", "NeighborsNumber" -> 2}];

大きい"NeighborsNumber"を使って予測器を訓練する：

Wolfram Language code: p10 = Predict[trainingset, Method -> {"NearestNeighbors", "NeighborsNumber" -> 10}];

2つの予測を比較する：

Wolfram Language code: Plot[{p2[x], p10[x]}, {x, 0, 6}]