WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター
音声の合成

音声の合成

振動過程と時系列
ノイズ生成高度な合成
Wolfram言語は，Wolfram言語のパワフルな数学およびアルゴリズム機能と完全に統合した，音声データの生成，解析，操作に対する広範なサポートを提供している．
音声合成に使う最初の関数としてAudioGeneratorがある．
AudioGenerator[model]
指定された model の1秒の音声を生成する
AudioGenerator[model,t]
t 秒の音声を生成する
音声の生成
振動
信号を生成する最も簡単な方法は，AudioGeneratorでサポートされるネイティブの振動の一つを使うことである．
正弦波信号を生成する：
Wolfram Language code: AudioGenerator["Sin"]
指定した周波数の正弦波信号を生成する：
Wolfram Language code: AudioGenerator[{"Sin", 1000}]
振動モデルによって，調和性も異なる：
Wolfram Language code: oscillators = {"Sin", "Sawtooth", "Square"}; Panel@TableForm[{ AudioGenerator[#, Appearance -> "Minimal"], AudioPlot[AudioGenerator[#], PlotRange -> .01, PlotTheme -> "Minimal"], Periodogram[AudioGenerator[#], 2000, PlotRange -> {{0, 2000}, All}, Ticks -> {True, False}] }& /@ oscillators, TableHeadings -> {oscillators, {"Audio", "Waveform", "Spectrum"}}, TableSpacing -> {2, 2}]
振動モデルはすべて周波数と位相に対する，時間依存のパラメータを取る．入力には，TimeSeries，他のAudioオブジェクト，純関数が取れる．
音声信号を使って周波数を制御する：
Wolfram Language code: vib = AudioGenerator[{"Sin", Quantity[6, "Hertz"], Pi}, 4]; AudioGenerator[{"Sin", 440 + 10vib}]
純関数を使って周波数を制御する：
Wolfram Language code: AudioGenerator[{"Sin", 440 + 10Sin[2Pi 6#]&}, 4]
時系列を使って周波数を制御する：
Wolfram Language code: vib = TimeSeries[Table[{t, Sin[2Pi 6t]}, {t, 0, 4, 1 / 200}]]; AudioGenerator[{"Sin", 440 + 10vib}]
ノイズ生成
AudioGeneratorは，振動器の他，異なる種類のノイズ信号の生成を可能にする．
ピンクのイズを1秒生成する：
Wolfram Language code: AudioGenerator["Pink"]
ノイズのタイプによってスペクトルコンテンツも異なる：
Wolfram Language code: noises = {"White", "PeriodicRandomNoise", "Pink", "Brown", "Blue", {"Color", 1.5}}; Periodogram[AudioGenerator /@ noises, 2000, ScalingFunctions -> {"Log10", "dB"}, PlotStyle -> {RGBColor[0.7777777777777778, 0.7777777777777778, 0.7777777777777778], RGBColor[0.8518518518518519, 0.8518518518518519, 0.8518518518518519], RGBColor[1, 0.5, 0.5], RGBColor[0.6, 0.4, 0.2], RGBColor[5/9, 5/9, 1], RGBColor[1, 0, 0]}, PlotLegends -> Placed[noises, Right]]
ホワイトのイズは，平坦なスペクトルが特徴である．デフォルトではサンプル値は一様分布から選ばれるが，スペクトルに影響を及ぼさずに変更することができる．
正規分布からサンプルされた，振幅のあるホワイトノイズ：
Wolfram Language code: white = AudioGenerator[{"White", NormalDistribution[]}]//AudioNormalize
信号のヒストグラムとピリオドグラムをプロットする：
Wolfram Language code: histogram = Histogram[AudioData@white]
Wolfram Language code: Periodogram[white, 2000, PlotRange -> {All, {-40, 10}}, ScalingFunctions -> {"Log10", "dB"}]
{"Color",α}を使うと，f-α 分布に従うスペクトルを持つ，色付きのノイズ信号を生成することができる．色付きのノイズには"Pink"，"Brown"，"Blue"があり，ここで α は1，2，のいずれかである．
ノイズの「色」を変更する：
Wolfram Language code: Manipulate[Periodogram[AudioGenerator[{"Color", α}], 2000, ScalingFunctions -> {"Log10", "dB"}, PlotRange -> {All, {-40, 10}}], {α, -2, 2}]
過程と時系列
AudioGeneratorを使うと，ランダム過程をサンプルすることで信号を生成することができる．
離散時間および連続時間の過程から音声信号を生成する：
Wolfram Language code: AudioGenerator[FractionalBrownianMotionProcess[.5]]//AudioNormalize
Wolfram Language code: (AudioGenerator[TelegraphProcess[2], 5] + 1).5AudioGenerator["Sin", 5]
AudioGeneratorはTimeSeriesからAudioオブジェクトを生成するためにも使うことができる．
TimeSeriesから始まる音声信号を生成する：
Wolfram Language code: windData = TimeSeriesRescale[WindSpeedData["KJFK", {DateObject[{2010, 1, 1}], DateObject[{2014, 1, 8}]}], {0, 1}]; ts = QuantityMagnitude@TimeSeries[windData, MissingDataMethod -> {"Interpolation", InterpolationOrder -> 0}]; AudioGenerator[Standardize@ts]//AudioNormalize
高度な合成

減算合成

音声オブジェクトを1つ以上の周波数選択フィルタで処理することにより，その調和性を操作することができるため，音色が変わる．この方法は，もとの音声オブジェクトが調和的に豊かな場合に効果的である．
のこぎり波のフィルタを適用する：
Wolfram Language code: LowpassFilter[AudioGenerator["Sawtooth"], Quantity[1000, "Hertz"]]
2つの異なるフィルタを使って，矩形波形を生成する：
Wolfram Language code: Manipulate[ lpFiltered = filter[AudioGenerator["Square", Appearance -> "Minimal"], Quantity[f, "Hertz"], 101, Padding -> "Periodic"]; TableForm[{{lpFiltered, AudioPlot[lpFiltered, PlotRange -> .01, PlotTheme -> "Minimal", ImageSize -> Small], Periodogram[lpFiltered, 1000, PlotRange -> {{0, 5000}, All}, Ticks -> {True, False}, ImageSize -> Small]}}], {{f, 600, "Cutoff Frequency"}, 200, 4000}, {filter, {LowpassFilter, HighpassFilter}}, ContinuousAction -> False]

加算合成

フィルタに使用で調和が減衰する減算合成とは対照的に，加算合成は調波を加えることに基づいている．その効果は，異なる周波数における正弦波の線形結合により得られる．ユーザは線形結合の係数を制御することができる．
基音200 Hzの最初の8個の調音の振幅を制御する：
Wolfram Language code: Manipulate[ sineBank = Table[AudioGenerator[{"Sin", 200i}], {i, 8}]; amps = {a1, a2, a3, a4, a5, a6, a7, a8}; as = Mean[amps sineBank]; TableForm@{{as, Periodogram[as, 4000, PlotRange -> {{0, 2000}, All}, Ticks -> {True, False}, ImageSize -> Small]}}, {{a1, .5}, 0, 1}, {{a2, .5}, 0, 1}, {{a3, .5}, 0, 1}, {{a4, .5}, 0, 1}, {{a5, .5}, 0, 1}, {{a6, .5}, 0, 1}, {{a7, .5}, 0, 1}, {{a8, .5}, 0, 1}, ContinuousAction -> False, ControlPlacement -> Top]

振幅変調

振幅変調は，複雑な調和性を持つ信号を生成する一般的な手法である．
振幅変調では，carrier（搬送波）とmodulator（変調波）の2つの信号が使われる．結果は carrier(1+μmodulator)で計算される．ここでスケール係数 μ は変調度と呼ばれる．
変調波が正弦波の場合は，周波数 f の搬送波の各コンポーネントについて，1対の側波帯が周波数 f±m で生成され，その振幅は変調度によって制御される．
三角波の振幅変調：
Wolfram Language code: carrier = AudioGenerator[{"Triangle", 200}, 2]; modulator = AudioGenerator[{"Sin", 100}, 2]; modIndex = .8; am = carrier * (1 + modIndex * modulator)//AudioNormalize
信号のピリオドグラムをプロットする：
Wolfram Language code: Periodogram[am, 8000, PlotRange -> {{0, 2000}, All}, GridLines -> {Table[f, {f, 200, 2000, 400}], None}]

周波数変調

よく使われる別の方法として，1970年代の初期に発見された周波数変調というものがある．
周波数変調の場合，搬送波の周波数は変調波および変調度によって制御される．変調度が増加するにつれて，変調周波数の区間における搬送波周波数の上か下で周波数が発生する．
基本的な周波数変調：
Wolfram Language code: cf = 500; mf = 200; modulator = mf * AudioGenerator[{"Sin", mf}]; modIndex = 1; fm = AudioGenerator[{"Sin", cf + modIndex * modulator}]
信号のピリオドグラムをプロットする：
Wolfram Language code: Periodogram[fm, 8000, ScalingFunctions -> "Absolute", PlotRange -> {{0, 1100}, {0, 800}}, GridLines -> Automatic]
これらの追加的な側波帯の数と強さは，変調度が関連している．
変調指数の大きさを上げると，側波帯の大きさが増加する：
Wolfram Language code: cf = 500; mf = 100; modIndex = {1, 2, 3}; fm = Table[AudioGenerator[{"Sin", cf + mIndex mf Sin[2 Pi mf #]&}], {mIndex, modIndex}]; periodograms = Table[Periodogram[fm[[i]], 20000, ScalingFunctions -> "Absolute", ImageSize -> Small, PlotRange -> {{0, 1000}, All}, GridLines -> Automatic, PlotLabel -> "Modulation Index: = " <> ToString[modIndex[[i]]]], {i, Length@modIndex}]; Grid[{fm, periodograms}]
側波帯の位置は搬送波と変調周波数の間の割合で決まる．この割合を変更することで， 調和スペクトル（音程のある楽器に特有）と非調和スペクトル（打楽器に特有）の両方を得ることができる．
調和信号と非調和信号を生成する：
Wolfram Language code: cf = 500; ratios = {3 / 2, Sqrt[2], Pi}; fm = Table[mf = cf / r; AudioGenerator[{"Sin", cf + 3.2 mf Sin[2 Pi mf #]&}], {r, ratios}]; periodograms = Table[Periodogram[fm[[i]], 20000, ScalingFunctions -> "Absolute", ImageSize -> Small, PlotRange -> {{0, 1000}, All}, GridLines -> Automatic, PlotLabel -> "FractionBox[SubscriptBox[c, f], SubscriptBox[m, f]] = " <> ToString[ratios[[i]], FormatType -> StandardForm]], {i, Length@ratios}]; Grid[{fm, periodograms}]
変調度が時間依存の引数になると，調和性が時間とともに進化する信号が簡単に生成できるようになる．
変調度を大きくして，信号のバンド幅を増加させる：
Wolfram Language code: cf = 500; mf = cf / 6; modulator = mf AudioGenerator[{"Sin", mf}, 5]; modIndex = 3AudioGenerator[{"Sawtooth", .1}, 5]; fm = AudioGenerator[{"Sin", cf + modIndex modulator}]
結果のスペクトログラムをプロットする：
Wolfram Language code: Spectrogram[fm, 4096, 4096, HannWindow, PlotRange -> {All, {0, 1200}}]
変調周波数は時間依存のパラメータでもよい．
変調周波数を変化させて，側波帯の位置を変更する：
Wolfram Language code: cf = 500; mf = 100 + 400AudioGenerator[{"Sawtooth", .1}, 5]; modulator = mf AudioGenerator[{"Sin", mf}]; fm = AudioGenerator[{"Sin", cf + 3 modulator}]
結果のスペクトログラムをプロットする：
Wolfram Language code: Spectrogram[fm, 4096, 4096, HannWindow, PlotRange -> {All, {0, 3000}}]