WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター
補助的なWolframシステムプロセスを呼び出す

補助的なWolframシステムプロセスを呼び出す

LinkLaunch["prog"]
外部プログラムを開始させ，そのプログラムとの接続を開く
WSTPを使って補助的プログラムと接続する
利用中のコンピュータで補助的Wolframシステムプロセスを開始させる：
Wolfram Language code: link = LinkLaunch["math -mathlink"]
補助的Wolframシステムプロセスからの最初の入力プロンプトを表すパケット：
Wolfram Language code: LinkRead[link]
補助的プロセスの入力となるテキストを表すパケットを書き込む：
Wolfram Language code: LinkWrite[link, EnterTextPacket["10!"]]
補助的プロセスからの出力プロンプトを表すパケット：
Wolfram Language code: LinkRead[link]
これが実際に計算した結果である：
Wolfram Language code: LinkRead[link]
Wolfram Symbolic Transfer Protocol (WSTP)パケットは，Wolframシステムセッションにかかわるさまざまなオブジェクトを系統立てて管理するために使用されている．WSTPパケットは簡単に言えばパケットの役目や意味を示す一定の頭部を持った式である．
EnterTextPacket["input"]
入力行に対応するテキスト
ReturnTextPacket["output"]
出力行に対応して返されるテキスト
InputNamePacket["name"]
入力行の名前として返されるテキスト
OutputNamePacket["name"]
出力行の名前として返されるテキスト
Wolframシステムセッションの基本パケット
LinkReadがInputNamePacketを返すため，もうひとつのWolframシステムセッションが入力待ちであることが分かる：
Wolfram Language code: LinkRead[link]
入力にPrintコマンドを2つ与える：
Wolfram Language code: LinkWrite[link, EnterTextPacket["Print[a]; Print[b];"]]
1番目のPrintが返したテキスト：
Wolfram Language code: LinkRead[link]
2番目のPrintが返したテキスト：
Wolfram Language code: LinkRead[link]
出力行は生成されず，次のパケットはInputNamePacketとなる：
Wolfram Language code: LinkRead[link]
TextPacket["string"]
Printその他が返すテキスト
MessagePacket[symb,"tag"]
メッセージ名
DisplayPacket["string"]
PostScriptグラフィックスの一部
DisplayEndPacket["string"]
PostScriptグラフィックスの末尾
Wolframシステムセッション中に使用されるパケットの一部
EnterTextPacket["input"]でWolfram言語へ入力するとき，Wolfram言語はその出力を自動的に文字列に変換し，ReturnTextPacket["output"]で応える．それとは別に，EnterExpressionPacket[expr]で入力を与えると，Wolfram言語はReturnExpressionPacket[expr]で応え，出力を文字列に変換することはしない．
EnterExpressionPacket[expr]
入力行に相当する式
ReturnExpressionPacket[expr]
出力行に相当する式
式を使って入出力するためのパケット
補助的Wolframシステムセッションに式を評価することなく入力する：
Wolfram Language code: LinkWrite[link, Unevaluated[EnterExpressionPacket[Factor[x ^ 6 - 1]]]]
補助的Wolframシステムセッションからは3つのパケットが返ってくる：
Wolfram Language code: Table[LinkRead[link], {3}]
InputNamePacketとOutputNamePacketは補助的Wolframシステムセッションの現在の状態を知りたいときに利用することができる．補助的Wolframシステムセッションを"math -mathlink -batchoutput"で起動すれば，それらのパケットの生成を抑制することができる．
InputNamePacketパケットとOutputNamePacketパケットの明示的な生成を抑制していても，Wolframシステムは，EnterTextPacketあるいはEnterExpressionPacketの入力を，あたかも入力行があるかのように処理する．つまり，Wolframシステムは$Preと$Postを呼んでIn[$Line]とOut[$Line]の値を代入する．
EvaluatePacket[expr]
評価のために送信される式
ReturnPacket[expr]
評価によって返信される式
明示的な入力行・出力行なしで評価を実行する
EvaluatePacketを送信する．Unevaluatedはパケットが送信される前に評価されることを抑止する：
Wolfram Language code: LinkWrite[link, Unevaluated[EvaluatePacket[10!]]]
結果は純粋なReturnPacketである：
Wolfram Language code: LinkRead[link]
EvaluatePacketの評価を要求するPrint[x]を送る：
Wolfram Language code: LinkWrite[link, Unevaluated[EvaluatePacket[Print[x]]]]
最初に返ってくるのはTextPacketであり，Printが生成するテキストを表している：
Wolfram Language code: LinkRead[link]
その後，Printの結果が返ってくる：
Wolfram Language code: LinkRead[link]
ほとんどの場合，EvaluatePacketを送信することによって，Wolframシステムは計算を実行し，ReturnPacketで終るさまざまなパケットを返してくると思っていいだろう．しかし，実行すべき計算がInputのような関数を含んでいる場合，Wolframシステムは計算を続ける前にさらに入力を要求してくる．
Input関数の評価を含むパケットを送信する：
Wolfram Language code: LinkWrite[link, Unevaluated[EvaluatePacket[2 + Input["data ="]]]]
返ってくるパケットはInputPacketであり，入力が必要なことを示している：
Wolfram Language code: LinkRead[link]
リンクには読むべきパケットが残っていない：
Wolfram Language code: LinkReadyQ[link]
入力を与える：
Wolfram Language code: LinkWrite[link, EnterTextPacket["x + y"]]
Input関数が評価され，ReturnPacketが生成された：
Wolfram Language code: LinkRead[link]
LinkInterrupt[link]
WSTP適合プログラムに割込み信号を送る
WSTP適合プログラムへの割込み
非常に時間のかかる計算を補助的プロセスに送る：
Wolfram Language code: LinkWrite[link, EnterTextPacket["FactorInteger[2^777-1]"]]
まだ計算中である：
Wolfram Language code: LinkReadyQ[link]
割込み信号を送る：
Wolfram Language code: LinkInterrupt[link]
補助的なプロセスは中断し，割込みメニューを返してくる：
Wolfram Language code: LinkRead[link]
以下でリンクを閉じる：
Wolfram Language code: LinkClose[link]