BoundaryUnitNormal

NDSolve`FEM`

BoundaryUnitNormal

BoundaryUnitNormal[x,y,…]

領域に対して外向きの単位法線ベクトルを表す．

詳細とオプション

BoundaryUnitNormalは，境界の単位法線ベクトルに従属する，偏微分方程式の境界条件を構築するために使える．

BoundaryUnitNormalは，NeumannValue，DirichletCondition，NIntegrateと一緒に使える．
BoundaryUnitNormalは，AcousticAbsorbingValue，HeatFluxValue，MassOutflowValue等の境界条件によって生成できる．
BoundaryUnitNormalは，境界上の接線を指定するために使える．
BoundaryUnitNormalは，境界条件が離散化される場合には，領域の埋込み次元の長さのベクトルに評価する．
境界の単位法線成分には，Indexedを使ってアクセスできる．
有限要素の近似には，偏微分方程式に検定関数が掛けられ，上で積分される．部分積分でが得られる．境界の積分における被積分関数は，NeumannValueので置き換えられる．
偏微分方程式がノイマン値をと指定する場合には，NeumannValueをと指定することによって，代りにBoundaryUnitNormalを使ってをモデル化することができる．
逆に，偏微分方程式がノイマン値をと指定する場合には，NeumannValueをと指定することによって，代りにBoundaryUnitNormalを使ってをモデル化することができる．
領域の内部境界においては，境界の単位法線成分は一意的には定義されない．
境界の単位法線の値は，領域全体で内部境界を含むすべての境界について，のディリクレ条件でを解くことによって計算される．すると，境界の単位法線成分はで正規化されたの勾配になる．

例題

すべて開くすべて閉じる

例 (1)

パッケージをロードする：

Wolfram Language code: <<NDSolve`FEM`

単位Diskについてポワソン方程式を解く：

Wolfram Language code: solution = NDSolveValue[{-Laplacian[u[x, y], {x, y}] == 1, DirichletCondition[u[x, y] == 0, True]}, u, {x, y}∈Disk[]]

解を可視化する：

Wolfram Language code: Plot3D[solution[x, y], {x, y}∈Disk[]]

領域の境界を通る流束の合計を，境界領域の二次近似で計算する：

Wolfram Language code:

NIntegrate[BoundaryUnitNormal[x, y].Grad[-solution[x, y], {x, y}], {x, y}∈ToBoundaryMesh[solution["ElementMesh"], "MeshOrder" -> 2]]

部分領域の境界を通る流束の合計を計算する：

Wolfram Language code:

NIntegrate[BoundaryUnitNormal[x, y].Grad[-solution[x, y], {x, y}], {x, y}∈RegionBoundary[Rectangle[{-1 / 2, -1 / 2}, {1 / 2, 1 / 2}]]]

スコープ (6)

単位Diskについてポワソン方程式を解く：

Wolfram Language code: solution = NDSolveValue[{-Laplacian[u[x, y], {x, y}] == 1, DirichletCondition[u[x, y] == 0, True]}, u, {x, y}∈Disk[]]

外側の境界を通る流束の合計を計算する：

Wolfram Language code: -NIntegrate[Grad[solution[x, y], {x, y}].BoundaryUnitNormal[x, y], {x, y}∈RegionBoundary[Disk[]]]

領域の境界を通る流束の合計を，境界領域の二次近似で計算する：

Wolfram Language code:

-NIntegrate[Grad[solution[x, y], {x, y}].BoundaryUnitNormal[x, y], {x, y}∈ToBoundaryMesh[solution["ElementMesh"], "MeshOrder" -> 2]]

微分方程式と領域を指定する：

Wolfram Language code:

op = Inactive[Div][-0.075*Inactive[Grad][c[x], {x}], {x}] + 1;
Ω = Line[{{0}, {1}}];

左に，境界の単位法線成分でNeumannValueを設定し，方程式を解く：

Wolfram Language code:

solution1 = NDSolveValue[{
	op == NeumannValue[BoundaryUnitNormal[x].{-c[x]}, x == 0]}, c, x∈Ω]

解を可視化する：

Wolfram Language code: Plot[solution1[x], {x}∈Ω]

この範囲について，左のBoundaryUnitNormalの等価はである：

Wolfram Language code:

solution2 = NDSolveValue[{
	op == NeumannValue[{-1}.{-c[x]}, x == 0]}, c, x∈Ω]

解が等しいことを示す：

Wolfram Language code: Plot[solution1[x] - solution2[x], {x}∈Ω]

NeumannValueについて接線成分を作成する：

Wolfram Language code:

Ω = RegionDifference[Rectangle[{0, 0}, {4, 4}], Disk[]];
solution = NDSolveValue[{Laplacian[u[x, y], {x, y}] == NeumannValue[Cross[BoundaryUnitNormal[x, y]].{1, 1}, x ^ 2 + y ^ 2 == 1], DirichletCondition[u[x, y] == 0, x == 4 && y == 0]}, u, {x, y}∈Ω];
StreamPlot[Evaluate[Grad[solution[x, y], {x, y}]], {x, y}∈Ω]

BoundaryUnitNormalのIndexed成分を利用してNeumannValueを計算する：

Wolfram Language code:

Ω = RegionDifference[Rectangle[{0, 0}, {4, 4}], Disk[]];
solution = NDSolveValue[{Laplacian[u[x, y], {x, y}] == NeumannValue[{-Indexed[BoundaryUnitNormal[x, y], 2], 0}.{1, 1}, x ^ 2 + y ^ 2 == 1], DirichletCondition[u[x, y] == 0, x == 4 && y == 0]}, u, {x, y}∈Ω];
StreamPlot[Evaluate[Grad[solution[x, y], {x, y}]], {x, y}∈Ω]

ある形状についてポワソン方程式を解く：

Wolfram Language code:

Ω = RegionDifference[RegionUnion[Disk[{0, 0}, 5], Rectangle[{0, 0}, {7, 5}]], Ellipsoid[{0, 0}, {3, 2}]];
solution = NDSolveValue[{-Laplacian[u[x, y], {x, y}] == 1, DirichletCondition[u[x, y] == 0, True]}, u, {x, y}∈Ω]

解をプロットする：

Wolfram Language code: Plot3D[solution[x, y], {x, y}∈Ω]

境界を通る流束の合計を計算する：

Wolfram Language code:

NIntegrate[BoundaryUnitNormal[x, y].Grad[-solution[x, y], {x, y}], {x, y}∈ToBoundaryMesh[solution["ElementMesh"], "MeshOrder" -> 2]]

境界の法線成分でNeumannValueを設定する：

Wolfram Language code:

op = D[c[t, x], t] + Inactive[Div][-0.075*Inactive[Grad][c[t, x], {x}], {x}];
ifunNormal = NDSolveValue[{op == NeumannValue[-BoundaryUnitNormal[x].({-1} * c[t, x]), x == 0], c[0, x] == Exp[-100 * (x - 1 / 2) ^ 2]}, c, {t, 0, 2}, x∈Line[{{0}, {1}}]]

ノイマンゼロ境界条件を使って方程式をもう一度解く：

Wolfram Language code:

ifunNeumannZero = NDSolveValue[{op == NeumannValue[0, x == 0], c[0, x] == Exp[-100 * (x - 1 / 2) ^ 2]}, c, {t, 0, 2}, x∈Line[{{0}, {1}}]]

時間の経過につれて解がどのように変わるかを調べる：

Wolfram Language code:

Manipulate[Plot[{ifunNormal[t, x], ifunNeumannZero[t, x]}, {x, 0, 1}, PlotRange -> {0, 1}], {t, 0, 2}, SaveDefinitions -> True]

この領域では，左のBoundaryUnitNormalの等価はである：

Wolfram Language code:

ifunNormal2 = NDSolveValue[{op == NeumannValue[-{-1}.({-1} * c[t, x]), x == 0], c[0, x] == Exp[-100 * (x - 1 / 2) ^ 2]}, c, {t, 0, 2}, x∈Line[{{0}, {1}}]]

解が同じであることをチェックする：

Wolfram Language code: Plot3D[ifunNormal[t, x] - ifunNormal2[t, x], {x, 0, 1}, {t, 0, 2}]

アプリケーション (1)

以下の例では，環帯領域において指定された表面力境界条件を持つストークス流を考える．辺の外側ではにおいて粘着境界条件が存在する．これらがとの方向での流速を0，つまりに設定する．内側の境界ではにおいて表面力が指定される．応力ベクトルの表面力は以下で与えられる：

ここでは，はとして与えられる動径単位ベクトルであり，はとして与えられる接線単位ベクトルである．とはそれぞれとの方向でのデカルト単位ベクトルである．この例では，表面力は法線方向には，接線成分の表面力はに設定される．言い換えれば，内側の境界では，速度は指定されず，表面力のみが指定される．

流動応力テンソルは以下で与えられる：

ストークス方程式は

と以下の連続方程式で与えられる：

パラメータ，形状，細分化されたメッシュを設定する：

Wolfram Language code:

pars = <|a -> 1 / 5, b -> 1, μ -> 1|>;
Ω = Annulus[{0, 0}, {a, b}] /. pars;
mesh = ToElementMesh[Ω, "RegionHoles" -> {0, 0}, MeshRefinementFunction -> Function[{vertices, area}, area > 0.000025 (0.1 + 20 Norm[Mean[vertices]])]];

ストークス流の演算子を設定する：

Wolfram Language code:

op = {Inactive[Div][{{-2 * μ, 0}, {0, -μ}}.Inactive[Grad][u[x, y], {x, y}], {x, y}] + 
	Inactive[Div][{{0, 0}, {-μ, 0}}.Inactive[Grad][v[x, y], {x, y}], {x, y}] + Inactive[Div][{1, 0} * p[x, y], {x, y}], 
	Inactive[Div][{{0, -μ}, {0, 0}}.Inactive[Grad][u[x, y], {x, y}], {x, y}] + 
	Inactive[Div][{{-μ, 0}, {0, -2 * μ}}.Inactive[Grad][v[x, y], {x, y}], {x, y}] + 
	Inactive[Div][{0, 1} * p[x, y], {x, y}], 
	Derivative[1, 0][u][x, y] + Derivative[0, 1][v][x, y]
	} /. pars;

外側の境界での粘着条件を設定する：

Wolfram Language code: ΓWall = DirichletCondition[{u[x, y] == 0, v[x, y] == 0}, ElementMarker == 2]

内側の表面では，外向きの単位法線とクロス積から接線単位法線を計算することができる．クロス積を使って，単位法線ベクトルから単位接線を計算する：

Wolfram Language code: Cross[{Subscript[n, x], Subscript[n, y]}]

との方向それぞれについてクロス積の第1成分と第2成分を抽出するためには，Indexedを使う．

表面力境界条件を設定する：

Wolfram Language code:

Γu = NeumannValue[Indexed[Cross[BoundaryUnitNormal[x, y]], 1] * ((x / a) ^ 2 - (y / a) ^ 2), ElementMarker == 1];
Γv = NeumannValue[Indexed[Cross[BoundaryUnitNormal[x, y]], 2] * ((x / a) ^ 2 - (y / a) ^ 2), ElementMarker == 1];

接線単位法線も同じようにとして与えられることが可能であることに注意する．内側の表面の単位法線ベクトルはであり，すると単位接線はになるからである：

Wolfram Language code:

NeumannValue[(y / a) * ((x / a) ^ 2 - (y / a) ^ 2), ElementMarker == 1];
NeumannValue[-(x / a) * ((x / a) ^ 2 - (y / a) ^ 2), ElementMarker == 1];

圧力に対する境界条件を指定しなければ，圧力値が浮いてしまい，NDSolveは十分な境界条件が指定されていないと警告を発する：

Wolfram Language code:

{ufun, vfun, pfun} = NDSolveValue[{op == {Γu, Γv, 0} /. pars, ΓWall}, {u, v, p}, {x, y}∈mesh, Method -> {"FiniteElement", "InterpolationOrder" -> {u -> 2, v -> 2, p -> 1}}, DependentVariables -> {u, v, p}]

圧力溶解と速度場を可視化する：

Wolfram Language code: Show[{DensityPlot[pfun[x, y], {x, y}∈mesh, ...], StreamPlot[{ufun[x, y], vfun[x, y]}, {x, y}∈mesh, ...]}, ...]

表面力境界条件がうまく使えることを確かめるためには，速度の動径成分と接線成分を計算し，それらをにおいてすべてのについてプロットすることができる．動径速度についてはに比例する解が期待され，接線速度についてはに比例する解が期待される．

関数を定義して，速度の動径成分と接線成分を計算する：

Wolfram Language code:

vr[x_, y_] := x / Sqrt[x ^ 2 + y ^ 2] * ufun[x, y] + y / Sqrt[x ^ 2 + y ^ 2] * vfun[x, y]
vt[x_, y_] := -(y / Sqrt[x ^ 2 + y ^ 2]) * ufun[x, y] + x / Sqrt[x ^ 2 + y ^ 2] * vfun[x, y]

速度の動径成分と，に比例する関数をプロットする：

Wolfram Language code:

Plot[Evaluate[{vr[a * Cos[θ], a * Sin[θ]], -Sin[2θ] * a / 20} /. pars], {θ, 0, 2π}, PlotLegends -> {"vr", "∝ sin(2θ)"}]

速度の接線成分と，に比例する関数をプロットする：

Wolfram Language code:

Plot[Evaluate[{vt[a * Cos[θ], a * Sin[θ]], -Cos[2θ] * a / 5} /. pars], {θ, 0, 2π}, PlotLegends -> {"vt", "∝ cos(2θ)"}]

次に内側の境界での法線応力と剪断応力を計算し，それらが指定された表面力境界条件と一致することを確かめる．応力テンソルは以下で与えられる：

表面力ベクトルの法線と接線の成分は

および

によって計算される．

応力テンソルを計算する関数を作成する：

Wolfram Language code:

gradU = Grad[{ufun[x, y], vfun[x, y]}, {x, y}];
sigma[x_, y_] := Evaluate[(μ * (gradU + Transpose[gradU]) - pfun[x, y] * IdentityMatrix[2]) /. pars];

単位法線ベクトルを計算する：

Wolfram Language code: normal = ElementMeshBoundaryUnitNormal[mesh]

接線ベクトルの関数を定義する：

Wolfram Language code: tangent[x_, y_] := Cross[normal[x, y]]

法線応力を計算する関数を定義する：

Wolfram Language code: normalStress[x_ ? NumberQ, y_ ? NumberQ] := normal[x, y].(sigma[x, y].normal[x, y]);

剪断応力を計算する関数を定義する：

Wolfram Language code: shearStress[x_ ? NumberQ, y_ ? NumberQ] := tangent[x, y].(sigma[x, y].normal[x, y]);

において計算された法線応力と剪断応力を可視化する：

Wolfram Language code:

stresses = {normalStress[a * Cos[θ], a * Sin[θ]], shearStress[a * Cos[θ], a * Sin[θ]]} /. pars;
Plot[stresses, {θ, 0, 2 Pi}, ...]

境界条件からにおける法線応力と剪断応力の境界条件との差を可視化する：

Wolfram Language code: Plot[Evaluate[stresses - {0, Cos[2θ]}], {θ, 0, 2 Pi}, ...]

特性と関係 (2)

境界単位の法線場を計算する：

Wolfram Language code: boundaryUnitNormal = ElementMeshBoundaryUnitNormal[ToElementMesh[Disk[]]]

境界単位法線を可視化する：

Wolfram Language code: VectorPlot[boundaryUnitNormal[x, y], {x, y}∈Disk[]]

境界のみにおける境界単位法線を可視化する：

Wolfram Language code: VectorPlot[boundaryUnitNormal[x, y], {x, y}∈Disk[], VectorPoints -> ToBoundaryMesh[Disk[]]["Coordinates"]]

境界単位法線は，領域上でポワソン方程式を解き，ゼロディリクレ条件を指定することによって計算される．単位Disk上でのポワソン方程式を計算する：

Wolfram Language code:

potential = NDSolveValue[{Laplacian[u[x, y], {x, y}] == 1, DirichletCondition[u[x, y] == 0, True]}, u[x, y], {x, y}∈Disk[], "ExtrapolationHandler" -> {Automatic, "WarningMessage" -> False}];

ポテンシャルの正規化された勾配を計算する：

Wolfram Language code: unitNormal = Normalize[Grad[potential, {x, y}], Sqrt[Total[# ^ 2]]&];

単位法線を可視化する：

Wolfram Language code: VectorPlot[unitNormal, {x, y}∈Disk[]]

これは，ElementMeshの境界単位法線を計算することと同じである：

Wolfram Language code:

boundaryUnitNormal = ElementMeshBoundaryUnitNormal[ToElementMesh[Disk[]]];
VectorPlot[boundaryUnitNormal[x, y], {x, y}∈Disk[]]

Top

その他のラーニングリソース

テクニカルサポート

Wolframソリューション

教育のためのWolframソリューション

使い始める

Grow Your Skills

Wolframと繋がる

大人用の教育プログラム

若者のための教育プログラム

読む

BoundaryUnitNormal

詳細とオプション

例題

例 (1)

スコープ (6)

アプリケーション (1)

特性と関係 (2)

テキスト

CMS

APA

BibTeX

BibLaTeX

BoundaryUnitNormal

詳細とオプション

例題

例 (1)

スコープ (6)

アプリケーション (1)

特性と関係 (2)

関連項目

テキスト

CMS

APA

BibTeX

BibLaTeX