InitializePDECoefficients

関連項目
- 関数
- Laplacian
- D
- 関数
- PDECoefficientData
- InitializePDEMethodData
- InitializeBoundaryConditions
- DiscretizePDE
- DeployBoundaryConditions
- ToNumericalRegion
- ToElementMesh
- ElementMeshInterpolation
関連するガイド
- 有限要素法
テクニカルノート
- 有限要素プログラミング
- 有限要素のためのNDSolveオプション

NDSolve`FEM`

InitializePDECoefficients

InitializePDECoefficients[vd,sd,rules]

変数データ vd と解データ sd に従った規則によって指定された係数を初期化し，PDECoefficientDataオブジェクトを生成する．

詳細とオプション

係数は，以下の形式の個の空間次数における個の二階偏微分方程式の系からのものであると想定される．

InitializePDECoefficients[vd,sd,rules]では，rules は name->coefficient の形式のものでなければならない．可能な係数名は以下の通りである．

"LoadCoefficients"	{{f₁},{f₂},…}	はスカラーである
"LoadDerivativeCoefficients"	{{γ₁},{γ₂},…}	は長さのベクトルである
"DiffusionCoefficients"	{{-c₁₁,-c₁₂,…},{-c₂₁,-c₂₂,…},…}	は，スカラー，長さの対角ベクトル，× の行列のいずれかとして指定することができる
"ConservativeConvectionCoefficients"	{{-α₁₁,-α₁₂,…},{-α₂₁,-α₂₂,…},…}	は長さのベクトルである
"ConvectionCoefficients"	{{β₁₁,β₁₂,…},{β₂₁,β₂₂,…},…}	は長さのベクトルである
"ReactionCoefficients"	{{a₁₁,a₁₂,…},{a₂₁,a₂₂,…},…}	はスカラーである

規則がこれらの係数名について指定されていない場合には，そのタイプの係数はすべて0であると想定される．
DiscretizePDEは一般化されたPDECoefficientDataオブジェクトを取り，以下のような系の行列を提供する．

このときは剛性行列であり，は荷重ベクトルである．
偏微分方程式の定常系はが一階の時間導関数，が二階の時間導関数として，二階まで指定することができる．
定常係数形式は以下である．

DiscretizePDEは一般化されたPDECoefficientDataオブジェクトを取り，以下のような系の行列を提供する．

このときは質量行列，は減衰行列，は剛性行列，は荷重ベクトルである．
可能な減衰係数名は以下の通りである．

"DampingDiffusionCoefficients"	{{-dc₁₁,-dc₁₂,…},{-dc₂₁,-dc₂₂,…},…}	はスカラー，長さの対角ベクトル，× 行列のいずれかとして指定できる．
"DampingConservativeConvectionCoefficients"	{{-dα₁₁,-dα₁₂,…},{-dα₂₁,-dα₂₂,…},…}	は長さのベクトルである
"DampingConvectionCoefficients"	{{dβ₁₁,dβ₁₂,…},{dβ₂₁,dβ₂₂,…},…}	は長さのベクトルである
"DampingReactionCoefficients"	{{dα₁₁,dα₁₂,…},{dα₂₁,dα₂₂,…},…}	はスカラーである

可能な質量係数名は以下の通りである．

"MassDiffusionCoefficients"	{{-mc₁₁,-mc₁₂,…},{-mc₂₁,-mc₂₂,…},…}	はスカラー，長さの対角ベクトル，× 行列のいずれかとして指定できる．
"MassConservativeConvectionCoefficients"	{{-mα₁₁,-mα₁₂,…},{-mα₂₁,-mα₂₂,…},…}	は長さのベクトルである
"MassConvectionCoefficients"	{{mβ₁₁,mβ₁₂,…},{mβ₂₁,mβ₂₂,…},…}	は長さのベクトルである
"MassReactionCoefficients"	{{mα₁₁,mα₁₂,…},{mα₂₁,mα₂₂,…},…}	はスカラーである

"Mass"係数は質量行列，"Damping"係数は減衰行列，残りの係数は剛性行列と荷重ベクトルに貢献する．
NDSolveは，非定常系を簡約し，時間において一階であるようにする．
係数は，空間関数，時間関数，パラメータ関数，従属変数関数，従属変数の一次微分の関数のいずれでもよい．
変数データ vd と解データ sd は，変数と値の対応するリストである．vd と sd のテンプレートは，NDSolve`VariableDataとNDSolve`SolutionDataを使って生成することができ，成分は，NDSolve`SetSolutionDataComponentを使って設定できる．
InitializePDECoefficientsは，変数データ vd と解データ sd に従って，係数を確かめ最適化する．
vd と sd の"Space"成分は，それぞれNumericalRegionオブジェクトとして表された空間変数と空間メッシュに設定されなければならない．
vd の"DependentVariables"成分は，引数を持たない従属変数名のシンボルのリストでなければならない．
時間依存問題については，vd と sd の"Time"成分は，それぞれ時間変数と初期時間に設定されなければならない．
非線形問題については，sd の"DependentVariables"成分は，従属変数の初期シード値に設定されなければならない．
パラメトリック問題については，vd と sd の"Parameters"成分は，それぞれパラメトリック変数と初期パラメトリック値に設定されなければならない．
InitializePDECoefficientsには以下のオプションがある．
"VerificationData" Automatic 偏微分方程式の係数検証データを指定する
InitializePDECoefficientsに与えられるオプションは，"InitializePDECoefficientsOptions"を指定することによってNDSolveに与えることができる． »
NDSolveおよび関連の関数からオプションを設定することについては，有限要素のためのNDSolveオプションに説明がある．

例題

すべて開くすべて閉じる

例 (2)

有限要素法パッケージをロードする：

Wolfram Language code: Needs["NDSolve`FEM`"]

NumericalRegionを設定する：

Wolfram Language code: nr = ToNumericalRegion[Disk[]]

変数と解のデータを設定する：

Wolfram Language code:

vd = NDSolve`VariableData[{"DependentVariables", "Space"} -> {{u}, {x, y}}];
sd = NDSolve`SolutionData["Space" -> nr];

ラプラス(Laplace)方程式を係数に変換する：

Wolfram Language code: InitializePDECoefficients[vd, sd, "DiffusionCoefficients" -> {{-IdentityMatrix[2]}}]

ポアソン(Poisson)方程式を係数に変換する：

Wolfram Language code: InitializePDECoefficients[vd, sd, "DiffusionCoefficients" -> {{-IdentityMatrix[2]}}, "LoadCoefficients" -> {{1}}]

スコープ (6)

係数は関数でもよい：

Wolfram Language code: f[x_, y_] := {{x ^ 2, 0}, {x + y, y ^ 2}}

Wolfram Language code: InitializePDECoefficients[vd, sd, "DiffusionCoefficients" -> {{-f[x, y]}}]

係数は補間関数でもよい：

Wolfram Language code: ifun = Interpolation[Flatten[Table[Evaluate[{{x, y}, Sin[x y]}], {x, 0, 1, 0.2}, {y, 0, 1 / 2, 0.1}], 1]]

Wolfram Language code: InitializePDECoefficients[vd, sd, "LoadCoefficients" -> {{-ifun[x, y]}}]

係数は非線形でもよい：

Wolfram Language code:

sdnonlinear = sd;
NDSolve`SetSolutionDataComponent[sdnonlinear, "DependentVariables", {0.}];
InitializePDECoefficients[vd, sdnonlinear, "DiffusionCoefficients" -> {{{{-u[x, y], 0}, {0, -Derivative[1, 0][u][x, y]}}}}]

"DiffusionCoefficient"の入力がベクトルである場合には，これは要求された入力行列の対角要素として解釈される：

Wolfram Language code:

InitializePDECoefficients[vd, sd, "DiffusionCoefficients" -> {{-{1, 1}}}] === InitializePDECoefficients[vd, sd, "DiffusionCoefficients" -> {{-IdentityMatrix[2]}}]

"DiffusionCoefficient"の入力がスカラーである場合には，スカラーは，要求された行列の対角要素の場所すべてに置かれる：

Wolfram Language code:

InitializePDECoefficients[vd, sd, "DiffusionCoefficients" -> {{-1}}] === InitializePDECoefficients[vd, sd, "DiffusionCoefficients" -> {{-IdentityMatrix[2]}}]

偏微分方程式系を初期化する：

Wolfram Language code:

vd2 = vd;
NDSolve`SetSolutionDataComponent[vd2, "DependentVariables", {u, v}];
InitializePDECoefficients[vd2, sd, "DiffusionCoefficients" -> -{{{{(100000/91), 0}, {0, (5000/13)}}, {{0, (30000/91)}, {(5000/13), 0}}}, {{{0, (5000/13)}, {(30000/91), 0}}, {{(5000/13), 0}, {0, (100000/91)}}}}]

オプション (1)

"VerificationData" (1)

InitializePDECoefficientsに与えられる偏微分方程式の係数は，評価すると数値入力になるように検証される：

Wolfram Language code: rc[x_ ? NumericQ, y_ ? NumericQ] := (Print["Test Coordinate: ", {x, y}];1)

Wolfram Language code: InitializePDECoefficients[vd, sd, "ReactionCoefficients" -> {{-rc[x, y]}}]

検証は，NumericalRegion内に存在する検定座標を求めることによって行われる．しかし，自動的に選ばれた検定座標あるいは検定のElementMarkerが特異点にある場合もある．

Wolfram Language code: rc[x_ ? NumericQ, y_ ? NumericQ] := (Print["Test Coordinate: ", {x, y}];1 / (x + 0.5 + y + 0.5))

Wolfram Language code: InitializePDECoefficients[vd, sd, "ReactionCoefficients" -> {{-rc[x, y]}}]

検証データから自動的に求められるものを上書きすることは，"VerificationData"オプションを使って行うことができる：

Wolfram Language code:

InitializePDECoefficients[vd, sd, "ReactionCoefficients" -> {{-rc[x, y]}}, "VerificationData" -> {"Coordinate" -> {0, 0}}]

加えて，自動のElementMarkerも変更することができる：

Wolfram Language code:

InitializePDECoefficients[vd, sd, "ReactionCoefficients" -> {{-rc[x, y]}}, "VerificationData" -> {"Coordinate" -> {0, 0}, "ElementMarker" -> 1}]

非線形問題では，従属変数と従属変数の微分についての検証データは，それぞれ"DependentVariables"と "DependentVariablesDerivative"を使って変更することができる：

Wolfram Language code:

sdnonlinear = sd;
NDSolve`SetSolutionDataComponent[sdnonlinear, "DependentVariables", {0.}];
InitializePDECoefficients[vd, sdnonlinear, "ReactionCoefficients" -> {{-1 / u[x, y]}}]

従属変数の検証値を初期条件の0から1に変更する：

Wolfram Language code:

InitializePDECoefficients[vd, sdnonlinear, "ReactionCoefficients" -> {{-1 / u[x, y]}}, "VerificationData" -> {"DependentVariables" -> {1}}]

従属変数の微分係数の値をベクトル{1,1}に変更する．ベクトルの成分は，それぞれの空間方向での微分係数の値である．同時にデフォルトの0.1が使われる：

Wolfram Language code:

InitializePDECoefficients[vd, sdnonlinear, "ReactionCoefficients" -> {{-1 / (0.1 - Derivative[1, 0][u][x, y])}}, "VerificationData" -> {"DependentVariablesDerivatives" -> {{1, 1}}}]

アプリケーション (6)

ラプラス方程式をのときにであるディリクレ条件と，のときにであるノイマン条件を持つ円板上で指定する：

Wolfram Language code:

pded = InitializePDECoefficients[vd, sd, "DiffusionCoefficients" -> {{-IdentityMatrix[2]}}];
bcd = InitializeBoundaryConditions[vd, sd, {{DirichletCondition[u[x, y] == 0, x ≤ -0.3], NeumannValue[1., x ≥ 0.35]}}];
md = InitializePDEMethodData[vd, sd];

拡散係数を調べる：

Wolfram Language code: pded["DiffusionCoefficients"]

離散化して解き，補間してから解を可視化する：

Wolfram Language code:

dpde = DiscretizePDE[pded, md, sd];
dbc = DiscretizeBoundaryConditions[bcd, md, sd];
{l, s, d, m} = dpde["SystemMatrices"];
DeployBoundaryConditions[{l, s, d, m}, dbc];
res = LinearSolve[s, l];
efun = ElementMeshInterpolation[{nr["ElementMesh"]}, res];
Plot3D[efun[x, y], {x, y}∈nr["ElementMesh"]]

"LoadCoefficients"係数をNIntegrateで使って，ある領域上で積分する：

Wolfram Language code:

ipde = InitializePDECoefficients[vd, sd, "LoadCoefficients" -> {{1}}];
md = InitializePDEMethodData[vd, sd];
dpde = DiscretizePDE[ipde, md, sd];
Total[dpde["LoadVector"], 2]

NIntegrateを使って結果を確かめる：

Wolfram Language code: NIntegrate[1, {x, y}∈Disk[]]

"ReactionCoefficients"をとし，例として関数を評価することができる：

Wolfram Language code:

ipde = InitializePDECoefficients[vd, sd, "ReactionCoefficients" -> {{1}}, "LoadCoefficients" -> {{x ^ 2 + y ^ 2}}];
md = InitializePDEMethodData[vd, sd];
dpde = DiscretizePDE[ipde, md, sd];
sol = LinearSolve[dpde["StiffnessMatrix"], dpde["LoadVector"]];
if = ElementMeshInterpolation[{md["ElementMesh"]}, sol]

評価された関数を可視化する：

Wolfram Language code: Plot3D[if[x, y], {x, y}∈Disk[]]

"LoadCoefficients"と組み合せたの"ReactionCoefficients"を使って関数をスケールすることができる．例えば，が領域上で倍にスケールできる：

Wolfram Language code:

ipde = InitializePDECoefficients[vd, sd, "ReactionCoefficients" -> {{10}}, "LoadCoefficients" -> {{x ^ 2 + y ^ 2}}];
md = InitializePDEMethodData[vd, sd];
dpde = DiscretizePDE[ipde, md, sd];
sol = LinearSolve[dpde["StiffnessMatrix"], dpde["LoadVector"]];
if = ElementMeshInterpolation[{md["ElementMesh"]}, sol]

スケールされ評価された関数を可視化する：

Wolfram Language code: Plot3D[if[x, y], {x, y}∈Disk[], PlotRange -> All]

"ReactionCoefficients"を"LoadDerivativeCoefficients"と組み合せて使い，領域上で関数の導関数を補間することができる：

Wolfram Language code:

uExact[x_] := Cos[x] + 1
vd1D = NDSolve`VariableData[{"DependentVariables", "Space"} -> {{u}, {x}}];
sd1D = NDSolve`SolutionData["Space" -> ToNumericalRegion[Line[{{0}, {π}}]]];
ipde = InitializePDECoefficients[vd1D, sd1D, "ReactionCoefficients" -> {{-1}}, 
	"LoadDerivativeCoefficients" -> {{{uExact[x]}}}];
ibcd = InitializeBoundaryConditions[vd1D, sd1D, {{DirichletCondition[u[x] == (D[uExact[x], x] /. x -> 0), x == 0], DirichletCondition[u[x] == (D[uExact[x], x] /. x -> π), x == π]}}];
md = InitializePDEMethodData[vd1D, sd1D];
dpde = DiscretizePDE[ipde, md, sd1D];
dbcd = DiscretizeBoundaryConditions[ibcd, md, sd1D, "Stationary"];
{s, l} = {dpde["StiffnessMatrix"], dpde["LoadVector"]};
DeployBoundaryConditions[{l, s}, dbcd];
sol = LinearSolve[s, l];
if = ElementMeshInterpolation[{md["ElementMesh"]}, sol]

数値近似と厳密な導関数の差異を可視化する：

Wolfram Language code: Plot[Evaluate[{if[x] - Div[{uExact[x]}, {x}]}], {x, 0, π}, PlotRange -> All]

領域内の空間導関数と時間導関数を含む方程式を指定する：

Wolfram Language code: aeqn = -Derivative[0, 2][V][t, x] - Derivative[1, 2][V][t, x]

ディリクレ条件と，および初期条件を指定する：

Wolfram Language code:

ic = V[0, x] == 0;
bcRight = V[t, 1] == 0;
bcLeftValue = Sin[2 * π * t];
bcLeft = V[t, 0] == bcLeftValue;
tEnd = 3;

変数と解のデータを設定する：

Wolfram Language code:

vd1D = NDSolve`VariableData[{"DependentVariables" -> {u}, "Space" -> {x}, "Time" -> t}];
nr1D = ToNumericalRegion[FullRegion[1], {{0, 1}}];
sd1D = NDSolve`SolutionData[{"Space" -> nr1D, "Time" -> 0.}];

係数を初期化する：

Wolfram Language code:

initCoeffs = InitializePDECoefficients[vd1D, sd1D, 
	"DiffusionCoefficients" -> {{-IdentityMatrix[1]}}, 
	"DampingDiffusionCoefficients" -> {{-IdentityMatrix[1]}}
	]

境界条件を初期化する：

Wolfram Language code:

initBCs = InitializeBoundaryConditions[vd1D, sd1D, {{DirichletCondition[u[t, x] == bcLeftValue, x == 0], DirichletCondition[u[t, x] == 0, x == 1]}}]

メソッドデータを初期化する：

Wolfram Language code: md = InitializePDEMethodData[vd1D, sd1D]

偏微分方程式係数を離散化する．この場合，すべての偏微分方程式係数が時間非依存である：

Wolfram Language code: sdpde = DiscretizePDE[initCoeffs, md, sd1D, "Stationary"];

剛性行列を調べる：

Wolfram Language code: sdpde["StiffnessMatrix"]

減衰行列を調べる：

Wolfram Language code: sdpde["DampingMatrix"]

境界条件を離散化する：

Wolfram Language code: sbcs = DiscretizeBoundaryConditions[initBCs, md, sd1D]

偏微分方程式の剰余を計算する関数を書く：

Wolfram Language code:

discretizePDEResidual[t_ ? NumericQ, u_ ? VectorQ, dudt_ ? VectorQ] := 
	Module[{l, s, d, tdpde, tbcs, nldpde, nlbcs}, 
	NDSolve`SetSolutionDataComponent[sd1D, "Time", t];
	NDSolve`SetSolutionDataComponent[sd1D, "DependentVariables", u];
	l = sdpde["LoadVector"];
	s = sdpde["StiffnessMatrix"];
	d = sdpde["DampingMatrix"];
	tbcs = DiscretizeBoundaryConditions[initBCs, md, sd1D, "Transient"];
	DeployBoundaryConditions[{l, s, d}, tbcs];
	DeployBoundaryConditions[{l, s, d}, sbcs];
	d.dudt + s.u - l
	]

初期条件を評価する：

Wolfram Language code: init = EvaluateOnElementMesh[{x}, 0, md["ElementMesh"]]["ValuesOnGrid"];

系の行列の疎なパターンの関数を設定する：

Wolfram Language code:

sparsityPatterns[t_, u_ ? VectorQ] := Module[
	{s, d, tdpde, nldpde}, 
	NDSolve`SetSolutionDataComponent[sd1D, "Time", t];
	NDSolve`SetSolutionDataComponent[sd1D, "DependentVariables", u];
	s = sdpde["StiffnessMatrix"];
	d = sdpde["DampingMatrix"];
	{s["PatternArray"], d["PatternArray"]}
	]

疎なパターンを計算する：

Wolfram Language code: {stiffnessSparsity, dampingSparsity} = sparsityPatterns[10 ^ -6, init]

方程式を解く：

Wolfram Language code:

ufun = NDSolveValue[{discretizePDEResidual[t, U[t], U'[t]] == 0, U[0] == init}, U, {t, 0, tEnd}, Method -> {"EquationSimplification" -> "Residual"}, Jacobian -> {"X" -> {Automatic, Sparse -> stiffnessSparsity}, "XP" -> {Automatic, Sparse -> dampingSparsity}}]

統合補間関数を作成する：

Wolfram Language code:

femSolution = ElementMeshInterpolation[{ufun["Coordinates"][[1]], md["ElementMesh"]}, Partition[ufun["ValuesOnGrid"], 1]]

比較のために，テンソル積格子法で解を計算する：

Wolfram Language code: tpgSolution = NDSolveValue[{aeqn == 0, bcLeft, bcRight, ic}, V, {x, 0, 1}, {t, 0, tEnd}]

テンソル積格子法と有限要素法の差をプロットする：

Wolfram Language code: Plot3D[tpgSolution[t, x] - femSolution[t, x], {t, 0, tEnd}, {x, 0., 1.}]

特性と関係 (2)

InitializePDECoefficientsに与えられるオプションは，"InitializePDECoefficientsOptions"を指定することによってNDSolveに与えることができる：

Wolfram Language code:

NDSolve[{Laplacian[u[x, y], {x, y}] == 1 / (x + 1 / 2 + y + 1 / 2), DirichletCondition[u[x, y] == 0, True]}, u, {x, y}∈Disk[]]

"VerificationData"を指定して，特異点にない座標を渡す：

Wolfram Language code:

NDSolve[{Laplacian[u[x, y], {x, y}] == 1 / (x + 1 / 2 + y + 1 / 2), DirichletCondition[u[x, y] == 0, True]}, u, {x, y}∈Disk[], Method -> {"FiniteElement", "InitializePDECoefficientsOptions" -> {"VerificationData" -> {"Coordinate" -> {0, 0}}}}]

ポワソン方程式を係数に変換する：

Wolfram Language code: pdec = InitializePDECoefficients[vd, sd, "DiffusionCoefficients" -> {{-IdentityMatrix[2]}}, "LoadCoefficients" -> {{1}}]

GetInactivePDEを使って，非アクティブなバージョンの入力を作成する：

Wolfram Language code: GetInactivePDE[pdec, vd]

考えられる問題 (1)

通常NDSolveは，係数を評価したときに正しい次元の数量にならない場合に，これを検知して警告を発する：

Wolfram Language code:

NDSolveValue[{D[u[t, x], {t, 1}] - D[u[t, x], {x, 2}] == k Sin[x], u[0, x] == 0, DirichletCondition[u[t, x] == 0, True]}, u, {t, 0, π}, {x, -π, π}, Method -> {"PDEDiscretization" -> {"MethodOfLines"}}]

それぞれの演算子について与えられた係数が適切であるかどうかを確かめるために，この係数は時間の初期点と領域からの座標を使って評価を試行する．係数と使用された値が相殺される場合には，NDSolveは係数が指定されていないのかどうかを検知することができない．その場合NDSolveは，特定の演算子による要素を計算できなかったというメッセージを返す：

Wolfram Language code:

NDSolveValue[{D[u[t, x], {t, 1}] - D[u[t, x], {x, 2}] == Cos[t] Sin[x] + k Sin[t] Sin[x], u[0, x] == 0, DirichletCondition[u[t, x] == 0, True]}, u, {t, 0, π}, {x, -π, π}, Method -> {"PDEDiscretization" -> {"MethodOfLines"}}]

上の例では，t=0と x=-π で負荷演算子を評価することによって，負荷演算子が消え，NDSolveは k が指定されていないことを検知することができない：

Wolfram Language code: (Cos[t] * Sin[x] + k * Sin[t] * Sin[x]) /. {t -> 0., x -> -π}

Top

その他のラーニングリソース

テクニカルサポート

Wolframソリューション

教育のためのWolframソリューション

使い始める

Grow Your Skills

Wolframと繋がる

大人用の教育プログラム

若者のための教育プログラム

読む

InitializePDECoefficients

詳細とオプション

例題

例 (2)

スコープ (6)

オプション (1)

"VerificationData" (1)

アプリケーション (6)

特性と関係 (2)

考えられる問題 (1)

テキスト

CMS

APA

BibTeX

BibLaTeX

InitializePDECoefficients

詳細とオプション

例題

例 (2)

スコープ (6)

オプション (1)

"VerificationData" (1)

アプリケーション (6)

特性と関係 (2)

考えられる問題 (1)

関連項目

テクニカルノート

関連するガイド

テキスト

CMS

APA

BibTeX

BibLaTeX