SPARQLSelect

関連項目
- 関数
- SPARQLAsk
- SPARQLConstruct
- SPARQLAggregate
- RDFStore
- SPARQLExecute
- RDFTriple
- SPARQLVariable
- SPARQLQuery
関連するガイド
- Graph Storeの概観
- SPARQLを使ってRDFストアのクエリを行う
- 関連項目
  - 関数
  - SPARQLAsk
  - SPARQLConstruct
  - SPARQLAggregate
  - RDFStore
  - SPARQLExecute
  - RDFTriple
  - SPARQLVariable
  - SPARQLQuery
- 関連するガイド
  - Graph Storeの概観
  - SPARQLを使ってRDFストアのクエリを行う

GraphStore`

SPARQLSelect

SPARQLSelect[pattern]

pattern にマッチする部分グラフ内の値に相当する変数の連想のリストを返す，RDFStoreに適用可能なクエリ演算子である．

SPARQLSelect[patternvars]

変数 vars についての値のみを返す．

詳細とオプション

SPARQLExecuteでSPARQLSelectを使ってSPARQL Endpointのクエリを行うことができる．
SPARQLSelect[pattern]を実行した結果は連想{<|var₁val_1,1,…|>,…}のリストである．ただし，var_iは pattern に現れるSPARQLVariableで各 val_i,jはマッチする部分グラフの対応する位置に現れる値である．
SPARQLSelect[pattern]の pattern は以下の任意の形式でよい．

	RDFTriple[s,p,o]	トリプルパターン
	{RDFTriple[…],RDFTriple[…],…}	基本的なグラフパターン
	{patt₁,patt₂,…}	グラフパターンのグループ化
	SPARQLFilter[expr]	expr で周囲のパターンの解にフィルタをかける
	patt/;expr	expr で解にフィルタをかける
	SPARQLOptional[patt]	任意のパターン
	patt₁\|patt₂\|...	和集合パターン
	Except[patt]	patt と互換の解を削除する
	SPARQLPropertyPath[…]	特性パスのパターン
	varexpr	式 expr と変数"var"をバインドする
	SPARQLValues[vars, values]	変数の値を指定する
	SPARQLSelect[patt]	サブクエリ
	SPARQLGraph[g,patt]	patt と名前が g のグラフをマッチさせる
	SPARQLService[url,patt]	マッチする patt を url にあるSPARQL Endpointと連携させる

トリプルパターンRDFTriple[s,p,o]のSPARQLVariableは任意の式を表す．
次は，使用可能なオプションである．

"Distinct"	False	重複する解が削除されるかどうか
"Limit"	Infinity	返す解の最大数
"Offset"	0	飛ばす解の数
"OrderBy"	None	それによって解を並べる式
"Reduced"	False	重複する解を削除してもよいかどうか

例題

すべて開くすべて閉じる

例 (2)

Wolfram Language code: Needs["GraphStore`"]

果物についてのデータ：

Wolfram Language code:

schema[s_] := URL["http://schema.org/" <> s];
ex[s_] := URL["http://example.org/" <> s];

Wolfram Language code:

fruitGraph = RDFStore[{
	RDFTriple[ex["banana"], schema["color"], "yellow"], 
	RDFTriple[ex["strawberry"], schema["color"], "red"], 
	RDFTriple[ex["strawberry"], ex["shape"], ex["round"]]
	}];

果物の色を求める：

Wolfram Language code: fruitGraph//SPARQLSelect[RDFTriple[SPARQLVariable["fruit"], schema["color"], SPARQLVariable["color"]]]

果物の色と形を求める：

Wolfram Language code:

fruitGraph//SPARQLSelect[{
	RDFTriple[SPARQLVariable["fruit"], schema["color"], SPARQLVariable["color"]], 
	RDFTriple[SPARQLVariable["fruit"], ex["shape"], SPARQLVariable["shape"]]
	}]

Wolfram Language code: Needs["GraphStore`"]

Wikidataでカルシウム(Q706)を含む(P527)化学式(P274)と薬品の和名(Q11173)を求める：

Wolfram Language code:

rdfs[s_] := URL["http://www.w3.org/2000/01/rdf-schema#" <> s];
wd[s_] := URL["http://www.wikidata.org/entity/" <> s];
wdt[s_] := URL["http://www.wikidata.org/prop/direct/" <> s];

Wolfram Language code:

SPARQLExecute[
	"https://query.wikidata.org/sparql", 
	SPARQLSelect[
	{
	RDFTriple[SPARQLVariable["chemical"], wdt["P31"], wd["Q11173"]], 
	RDFTriple[SPARQLVariable["chemical"], wdt["P274"], SPARQLVariable["formula"]], 
	RDFTriple[SPARQLVariable["chemical"], wdt["P527"], wd["Q706"]], 
	
	RDFTriple[SPARQLVariable["chemical"], rdfs["label"], SPARQLVariable["label"]] /; SPARQLEvaluation["lang"][SPARQLVariable["label"]] == "ja"
	} -> {"formula", "name" -> SPARQLEvaluation["str"][SPARQLVariable["label"]]}, 
	"Limit" -> 5
	]
	]

スコープ (9)

トリプルパターン (1)

Wolfram Language code: Needs["GraphStore`"]

データ例：

Wolfram Language code: ex[s_] := URL["http://example.org/" <> s];

Wolfram Language code:

exampleGraph = RDFStore[{
	RDFTriple[ex["s1"], ex["p"], 4], 
	RDFTriple[ex["s2"], ex["p"], 8], 
	RDFTriple[ex["s3"], ex["p"], 8]
	}];

トリプルパターンは，変数を含むことができるトリプルである：

Wolfram Language code: exampleGraph//SPARQLSelect[RDFTriple[ex["s1"], ex["p"], SPARQLVariable["x"]]]

変数はどこにでも現れることができる：

Wolfram Language code: exampleGraph//SPARQLSelect[RDFTriple[SPARQLVariable["x"], ex["p"], 8]]

トリプルパターンが変数を含む必要はない：

Wolfram Language code: exampleGraph//SPARQLAsk[RDFTriple[ex["s3"], ex["p"], 8]]

基本的なグラフパターン (1)

Wolfram Language code: Needs["GraphStore`"]

記事についてのデータ：

Wolfram Language code:

dct[s_] := URL["http://purl.org/dc/terms/" <> s];
ex[s_] := URL["http://example.org/" <> s];

Wolfram Language code:

articlesGraph = RDFStore[{
	RDFTriple[ex["article1"], dct["title"], "some title"], 
	RDFTriple[ex["article1"], dct["creator"], "Jenny"], 
	RDFTriple[ex["article1"], dct["creator"], "Oliver"], 
	RDFTriple[ex["article1"], dct["created"], 2018], 
	
	RDFTriple[ex["article2"], dct["title"], "other title"], 
	RDFTriple[ex["article2"], dct["creator"], "Jenny"], 
	RDFTriple[ex["article2"], dct["created"], 2017]
	}];

基本的なグラフパターンはトリプルパターンのリストである．すべての記事の"title"と"created"を取り出す：

Wolfram Language code:

articlesGraph//SPARQLSelect[{
	RDFTriple[SPARQLVariable["a"], dct["title"], SPARQLVariable["title"]], 
	RDFTriple[SPARQLVariable["a"], dct["created"], SPARQLVariable["created"]]
	} -> {"title", "created"}]

変数とリテラルは任意の場所に現れることができる．2018年に著された記事の著者を求める：

Wolfram Language code:

articlesGraph//SPARQLSelect[{
	RDFTriple[SPARQLVariable["a"], dct["created"], 2018], 
	RDFTriple[SPARQLVariable["a"], dct["creator"], SPARQLVariable["author"]]
	} -> "author"]

基本的なグラフにおける異なるトリプルパターンは，グラフ中の異なるトリプルと一致する必要はない．以下には"art1"と"art2"を同じ記事とバインドする解が含まれている：

Wolfram Language code:

articlesGraph//SPARQLSelect[{
	RDFTriple[SPARQLVariable["art1"], dct["creator"], SPARQLVariable["auth"]], 
	RDFTriple[SPARQLVariable["art2"], dct["creator"], SPARQLVariable["auth"]]
	}]//Take[#, 3]&

複数の記事を公開している著者を見付けるために，"art1"と"art2"は異ならなければならないとすることで解にフィルタをかける：

Wolfram Language code:

articlesGraph//SPARQLSelect[
	{
	RDFTriple[SPARQLVariable["art1"], dct["creator"], SPARQLVariable["auth"]], 
	RDFTriple[SPARQLVariable["art2"], dct["creator"], SPARQLVariable["auth"]]
	} /; SPARQLVariable["art1"] ≠ SPARQLVariable["art2"] -> "auth", 
	"Distinct" -> True
	]

フィルタ (1)

Wolfram Language code: Needs["GraphStore`"]

書籍についてのデータ：

Wolfram Language code: ex[s_] := URL["http://example.org/" <> s];

Wolfram Language code:

bookGraph = RDFStore[{
	RDFTriple[ex["faust1"], ex["yearPublished"], 1808], 
	RDFTriple[ex["faust2"], ex["yearPublished"], 1832], 
	RDFTriple[ex["RomeoAndJuliet"], ex["yearPublished"], 1597]
	}];

1820年より前に出版された書籍：

Wolfram Language code:

bookGraph//SPARQLSelect[RDFTriple[SPARQLVariable["book"], ex["yearPublished"], SPARQLVariable["year"]] /; SPARQLVariable["year"] < 1820]

任意 (1)

Wolfram Language code: Needs["GraphStore`"]

人についてのデータ：

Wolfram Language code:

foaf[s_] := URL["http://xmlns.com/foaf/0.1/" <> s];
ex[s_] := URL["http://example.org/" <> s];

Wolfram Language code:

personGraph = RDFStore[{
	RDFTriple[ex["alice"], foaf["nick"], "Alice"], 
	RDFTriple[ex["alice"], foaf["mbox"], URL["mailto:alice@example.org"]], 
	RDFTriple[ex["bob"], foaf["nick"], "Bob"]
	}];

すべての人の名前と，任意で電子メールアドレスを求める：

Wolfram Language code:

personGraph//SPARQLSelect[{
	RDFTriple[SPARQLVariable["p"], foaf["nick"], SPARQLVariable["name"]], 
	SPARQLOptional[RDFTriple[SPARQLVariable["p"], foaf["mbox"], SPARQLVariable["mail"]]]
	} -> {"name", "mail"}]

SPARQLOptionalラッパーが省略されていると，"Bob"についての解が見付からなくなる：

Wolfram Language code:

personGraph//SPARQLSelect[{
	RDFTriple[SPARQLVariable["p"], foaf["nick"], SPARQLVariable["name"]], 
	RDFTriple[SPARQLVariable["p"], foaf["mbox"], SPARQLVariable["mail"]]
	} -> {"name", "mail"}]

和集合 (1)

Wolfram Language code: Needs["GraphStore`"]

異なる"name"特性を使った物についてのデータ：

Wolfram Language code:

rdfs[s_] := URL["http://www.w3.org/2000/01/rdf-schema#" <> s];
dct[s_] := URL["http://purl.org/dc/terms/" <> s];
ex[s_] := URL["http://example.org/" <> s];

Wolfram Language code:

thingsGraph = RDFStore[{
	RDFTriple[ex["earth"], rdfs["label"], "Earth"], 
	RDFTriple[ex["rubiksCube"], rdfs["label"], "Rubik's Cube"], 
	RDFTriple[ex["guide"], dct["title"], "The Hitchhiker's Guide"]
	}];

すべての物の"name"を求める：

Wolfram Language code:

thingsGraph//SPARQLSelect[RDFTriple[SPARQLVariable["thing"], rdfs["label"], SPARQLVariable["name"]] | RDFTriple[SPARQLVariable["thing"], dct["title"], SPARQLVariable["name"]] -> "name"]

特性パスを使った同じクエリ：

Wolfram Language code:

thingsGraph//SPARQLSelect[SPARQLPropertyPath[SPARQLVariable["thing"], {rdfs["label"] | dct["title"]}, SPARQLVariable["name"]] -> "name"]

否定 (1)

Wolfram Language code: Needs["GraphStore`"]

人についてのデータ：

Wolfram Language code:

foaf[s_] := URL["http://xmlns.com/foaf/0.1/" <> s];
ex[s_] := URL["http://example.org/" <> s];

Wolfram Language code:

personGraph = RDFStore[{
	RDFTriple[ex["alice"], foaf["nick"], "Alice"], 
	RDFTriple[ex["alice"], foaf["mbox"], URL["mailto:alice@example.org"]], 
	RDFTriple[ex["bob"], foaf["nick"], "Bob"]
	}];

電子メールアドレスがない人を求める：

Wolfram Language code:

personGraph//SPARQLSelect[{
	RDFTriple[SPARQLVariable["person"], foaf["nick"], SPARQLVariable["name"]], 
	Except[RDFTriple[SPARQLVariable["person"], foaf["mbox"], SPARQLVariable["mbox"]]]
	}]

この場合，NOT EXISTSに基づいたクエリで同じ結果が得られる：

Wolfram Language code:

personGraph//SPARQLSelect[RDFTriple[SPARQLVariable["person"], foaf["nick"], SPARQLVariable["name"]] /; !SPARQLEvaluation["exists"][RDFTriple[SPARQLVariable["person"], foaf["mbox"], SPARQLVariable["mbox"]]]]

特性パス (1)

Wolfram Language code: Needs["GraphStore`"]

家族データ：

Wolfram Language code:

schema[s_] := URL["http://schema.org/" <> s];
ex[s_] := URL["http://example.org/" <> s];

Wolfram Language code:

familyGraph = RDFStore[{
	RDFTriple[ex["August"], schema["parent"], ex["Johann"]], 
	RDFTriple[ex["Alma"], schema["parent"], ex["August"]], 
	RDFTriple[ex["Wolfgang"], schema["parent"], ex["August"]], 
	RDFTriple[ex["Walther"], schema["parent"], ex["August"]]
	}];

Johannの子孫を求める：

Wolfram Language code: familyGraph//SPARQLSelect[SPARQLPropertyPath[SPARQLVariable["child"], {schema["parent"]..}, ex["Johann"]]]

孫だけを求める：

Wolfram Language code:

familyGraph//SPARQLSelect[SPARQLPropertyPath[SPARQLVariable["child"], {schema["parent"], schema["parent"]}, ex["Johann"]]]

割当て (1)

Wolfram Language code: Needs["GraphStore`"]

食品に関するデータ：

Wolfram Language code:

schema[s_] := URL["http://schema.org/" <> s];
ex[s_] := URL["http://example.org/" <> s];

Wolfram Language code:

productGraph = RDFStore[{
	RDFTriple[ex["pizza"], schema["price"], 10], 
	RDFTriple[ex["pizza"], ex["commission"], .20], 
	RDFTriple[ex["pasta"], schema["price"], 8], 
	RDFTriple[ex["pasta"], ex["commission"], .25], 
	RDFTriple[ex["friedRice"], schema["price"], 10], 
	RDFTriple[ex["friedRice"], ex["commission"], .20]
	}];

配達料を含む価格を調べる：

Wolfram Language code:

productGraph//SPARQLSelect[{
	RDFTriple[SPARQLVariable["food"], schema["price"], SPARQLVariable["price"]], 
	RDFTriple[SPARQLVariable["food"], ex["commission"], SPARQLVariable["c"]], 
	"totalPrice" -> SPARQLVariable["price"](1 + SPARQLVariable["c"])
	} -> {"food", "totalPrice"}]

"select expression"を使った同じクエリ：

Wolfram Language code:

productGraph//SPARQLSelect[{
	RDFTriple[SPARQLVariable["food"], schema["price"], SPARQLVariable["price"]], 
	RDFTriple[SPARQLVariable["food"], ex["commission"], SPARQLVariable["c"]]
	} -> {"food", "totalPrice" -> SPARQLVariable["price"](1 + SPARQLVariable["c"])}]

合計価格で製品にフィルタをかける：

Wolfram Language code:

productGraph//SPARQLSelect[{
	RDFTriple[SPARQLVariable["food"], schema["price"], SPARQLVariable["price"]], 
	RDFTriple[SPARQLVariable["food"], ex["commission"], SPARQLVariable["c"]], 
	"totalPrice" -> SPARQLVariable["price"](1 + SPARQLVariable["c"])
	} /; SPARQLVariable["totalPrice"] < 11 -> {"food", "totalPrice"}]

特定の製品の価格を調べる：

Wolfram Language code:

productGraph//SPARQLSelect[{
	SPARQLValues["food", {ex["pizza"], ex["pasta"]}], 
	RDFTriple[SPARQLVariable["food"], schema["price"], SPARQLVariable["price"]]
	}]

集約 (1)

Wolfram Language code: Needs["GraphStore`"]

給与についてのデータ：

Wolfram Language code:

salaryGraph = ImportString["
base <http://example.org/>

<bob> <department> <physics>; <salary> 3000 .
<anna> <department> <physics>; <salary> 2000 .
<tom> <department> <math>; <salary> 5000 .
<helga> <department> <it>; <salary> 3000 .
<carl> <department> <it>; <salary> 1000 .
", "Turtle"];

平均給与を求める：

Wolfram Language code: ex[s_] := URL["http://example.org/" <> s];

Wolfram Language code:

salaryGraph//SPARQLQuery[
	SPARQLSelect[RDFTriple[SPARQLVariable["person"], ex["salary"], SPARQLVariable["salary"]]] /* SPARQLAggregate["avgSalary" -> SPARQLEvaluation["avg"][SPARQLVariable["salary"]]]
	]

部署ごとの平均給与：

Wolfram Language code:

salaryGraph//SPARQLQuery[
	SPARQLSelect[{
	RDFTriple[SPARQLVariable["person"], ex["salary"], SPARQLVariable["salary"]], 
	RDFTriple[SPARQLVariable["person"], ex["department"], SPARQLVariable["dept"]]
	}] /* SPARQLAggregate[
	{
	"dept", 
	"avgSalary" -> SPARQLEvaluation["avg"][SPARQLVariable["salary"]]
	}, 
	SPARQLVariable["dept"]
	]
	]

部署の給与合計でグループにフィルタをかける：

Wolfram Language code:

salaryGraph//SPARQLQuery[
	SPARQLSelect[{
	RDFTriple[SPARQLVariable["person"], ex["salary"], SPARQLVariable["salary"]], 
	RDFTriple[SPARQLVariable["person"], ex["department"], SPARQLVariable["dept"]]
	}] /* SPARQLAggregate[
	{
	"dept", 
	"avgSalary" -> SPARQLEvaluation["avg"][SPARQLVariable["salary"]]
	}, 
	SPARQLVariable["dept"], 
	SPARQLEvaluation["sum"][SPARQLVariable["salary"]] > 4000
	]
	]

平均給与の降順で順序付ける：

Wolfram Language code:

salaryGraph//SPARQLQuery[
	SPARQLSelect[{
	RDFTriple[SPARQLVariable["person"], ex["salary"], SPARQLVariable["salary"]], 
	RDFTriple[SPARQLVariable["person"], ex["department"], SPARQLVariable["dept"]]
	}] /* SPARQLAggregate[
	{
	"dept", 
	"avgSalary" -> SPARQLEvaluation["avg"][SPARQLVariable["salary"]]
	}, 
	SPARQLVariable["dept"], 
	SPARQLEvaluation["sum"][SPARQLVariable["salary"]] > 4000, 
	SPARQLEvaluation["avg"][SPARQLVariable["salary"]] -> "Descending"
	]
	]

おもしろい例題 (1)

Wolfram Language code: Needs["GraphStore`"]

Wikidataを使ってクジラ(Q42196)の分類ツリー(P171)のGraphを作る：

Wolfram Language code:

wikibase[s_] := URL["http://wikiba.se/ontology#" <> s];
bd[s_] := URL["http://www.bigdata.com/rdf#" <> s];
wd[s_] := URL["http://www.wikidata.org/entity/" <> s];
wdt[s_] := URL["http://www.wikidata.org/prop/direct/" <> s];

Wolfram Language code:

SPARQLExecute[
	"https://query.wikidata.org/sparql", 
	SPARQLSelect[{
	SPARQLPropertyPath[wd["Q42196"], {wdt["P171"]...}, SPARQLVariable["taxon"]], 
	SPARQLOptional[RDFTriple[SPARQLVariable["taxon"], wdt["P171"], SPARQLVariable["parentTaxon"]]], 
	SPARQLService[wikibase["label"], RDFTriple[bd["serviceParam"], wikibase["language"], "en"]]
	} -> {"taxon", "taxonLabel", "parentTaxon"}]
	]//Function[whaleTaxons, 
	Graph[
	Labeled[#taxon, First[#taxonLabel]]& /@ whaleTaxons, 
	If[KeyExistsQ[#, "parentTaxon"], #taxon -> #["parentTaxon"], Nothing]& /@ whaleTaxons
	]
	]

Top

その他のラーニングリソース

テクニカルサポート

Wolframソリューション

教育のためのWolframソリューション

使い始める

Grow Your Skills

Wolframと繋がる

大人用の教育プログラム

若者のための教育プログラム

読む

SPARQLSelect

詳細とオプション

例題

例 (2)

スコープ (9)

トリプルパターン (1)

基本的なグラフパターン (1)

フィルタ (1)

任意 (1)

和集合 (1)

否定 (1)

特性パス (1)

割当て (1)

集約 (1)

おもしろい例題 (1)

テキスト

CMS

APA

BibTeX

BibLaTeX

SPARQLSelect

詳細とオプション

例題

例 (2)

スコープ (9)

トリプルパターン (1)

基本的なグラフパターン (1)

フィルタ (1)

任意 (1)

和集合 (1)

否定 (1)

特性パス (1)

割当て (1)

集約 (1)

おもしろい例題 (1)

関連項目

関連するガイド

テキスト

CMS

APA

BibTeX

BibLaTeX