WOLFRAM

Wolfram 语言与系统参考资料中心

How to| 为图形添加透明度

当您需要得到一幅图形多个组件的无阻视图时，或简单地想使白色背景下的一个单一图形组件更明亮时，透明度是非常有用的. Wolfram 语言使用图形指令 Opacity 将透明度应用于图形对象. Opacity 可以与大多数可视化函数结合使用.

这是一个二维图形：

Wolfram Language code: Plot[x ^ 2, {x, -2, 2}]

使用选项 PlotStyle 与 Opacity 使图形透明度为 70%：

Wolfram Language code: Plot[x ^ 2, {x, -2, 2}, PlotStyle -> Opacity[0.3]]

这是一个三维图形：

Wolfram Language code: Plot3D[x ^ 4 + y ^ 4 - 5 x ^ 2 * y ^ 2, {x, -3, 3}, {y, -3, 3}]

使图形透明度为 60%：

Wolfram Language code: Plot3D[x ^ 4 + y ^ 4 - 5 x ^ 2 * y ^ 2, {x, -3, 3}, {y, -3, 3}, PlotStyle -> Opacity[0.4]]

为多个函数图形设置不同的透明度：

Wolfram Language code: Plot3D[{x ^ 4 - 15 x ^ 2 * y ^ 2 + 20 Sin[y], -100 - x ^ 4 - y ^ 4 + 5 x ^ 2 * y ^ 2}, {x, -3, 3}, {y, -3, 3}, PlotStyle -> {{Blue, Opacity[0.5]}, {Yellow, Opacity[0.2]}}, Mesh -> None]

这是由两个不等式确定的一个二维区域：

Wolfram Language code: RegionPlot[{Sin[x]Cos[y] + 1 / 16 ≥ 0, Sin[x]Sin[y] + 1 / 16 ≥ 0}, {x, -3 Pi, 3Pi}, {y, -3Pi, 3Pi}, PlotStyle -> {Red, Blue}]

使图形 50% 透明：

Wolfram Language code: RegionPlot[{Sin[x]Cos[y] + 1 / 16 ≥ 0, Sin[x]Sin[y] + 1 / 16 ≥ 0}, {x, -3 Pi, 3Pi}, {y, -3Pi, 3Pi}, PlotStyle -> {{Red, Opacity[0.5]}, {Blue, Opacity[0.5]}} ]
    

使用 Opacity 观察图形的内部：

Wolfram Language code: SphericalPlot3D[{1, 2, 3}, {θ, 0, Pi}, {ϕ, 0, 7Pi / 4}, PlotStyle -> Opacity[0.4]]

使用 ContourPlot3D 的 ContourStyle 选项与 Opacity：

Wolfram Language code: ContourPlot3D[x ^ 4 + y ^ 4 + z ^ 4 - (x ^ 2 + y ^ 2 + z ^ 2) ^ 2 + 3(x ^ 2 + y ^ 2 + z ^ 2) == 3, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, Mesh -> None, ContourStyle -> {Orange, Opacity[0.5]} ]
    

您也可以为图形添加透明度.

制作一个 75% 透明的圆盘：

Wolfram Language code: Graphics[{Opacity[0.25], Disk[{0, 0}, 1]}]

Opacity 的值在0到1之间，0对应于完全透明：

Wolfram Language code: Graphics[{Opacity[1], Disk[{0, 0}, 1], Opacity[0.5], Disk[{.5, 0}, 1], Opacity[0.1], Disk[{1, 0}, 1]}]

将 Opacity 与一种颜色并用：

Wolfram Language code: Graphics[{Red, Opacity[1], Disk[{0, 0}, 1], Opacity[0.5], Disk[{.5, 0}, 1], Opacity[0.1], Disk[{1, 0}, 1]}]
    

Opacity 与其他 Wolfram 语言函数能够良好地交互：

Wolfram Language code: Manipulate[RegionPlot[{x - y ≥ t, x + y ≥ s}, {x, -3 Pi, 3 Pi}, {y, -3 Pi, 3 Pi}, PlotPoints -> 30, PlotStyle -> {Directive[Red], Directive[Blue, Opacity[0.5]]}], Style["Solving the system of inequalities: x-y ≥ t and x +y ≥ s", Bold, 12], {{s, 0}, -20, 20}, {{t, 0}, -20, 20}]