WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

How to | 表データをフォーマットする方法

Wolfram言語は非常に複雑なデータ解析ができるばかりでなく，結果を他のドキュメントや発表でも使用できるフォーマットされた読みやすい形で表示することができる．データのフォーマットの中で非常に役に立つ方法の一つに表形式がある．

まず，使用するデータをインポートする：

Wolfram Language code: data = Import["ExampleData/classification.tsv"]

すべての情報を表に入れる：

Wolfram Language code: Grid[data]

テキストを左揃えにして，列と行の間に余分なスペースを入れる：

Wolfram Language code: Grid[data, Alignment -> Left, Spacings -> {2, 1}]

枠を加え，"Text"を各項目のスタイルとして使う：

Wolfram Language code: Grid[data, Alignment -> Left, Spacings -> {2, 1}, Frame -> All, ItemStyle -> "Text"]

異なる背景を使って行と列のヘディングを強調する：

Wolfram Language code: Grid[data, Alignment -> Left, Spacings -> {2, 1}, Frame -> All, ItemStyle -> "Text", Background -> {{Gray, None}, {LightGray, None}}]

グラフィックスを含めてどのような式でも表データの一部として現れることができる：

Wolfram Language code: Grid[{ {"Sine", Plot[Sin[x], {x, -10, 10}, ImageSize -> Small]}, {"Cosine", Plot[Cos[x], {x, -10, 10}, ImageSize -> Small]}, {"Tangent", Plot[Tan[x], {x, -10, 10}, ImageSize -> Small]}}, Frame -> All]

個々の項目はSpanFromLeft，SpanFromAbove，SpanFromBothを使うことによって，複数の行，列，あるいは行と列の両方にまたがるようにすることができる：

Wolfram Language code: Grid[{ {"Plots of Common Trigonometric Functions", SpanFromLeft}, {"Sine", Plot[Sin[x], {x, -10, 10}, ImageSize -> Small]}, {"Cosine", Plot[Cos[x], {x, -10, 10}, ImageSize -> Small]}, {"Tangent", Plot[Tan[x], {x, -10, 10}, ImageSize -> Small]}}, Frame -> All]